Clever-Excel-Forum

Liebe Excelexperten!

Ich suche nach einer Lösung zur Ermittlung der Anzahl ob Einträge pro Datum vorhanden sind.

Liste besteht aus einer Spalte mit dem Datum - weitere Spalten mit "Teilnehmern"
pro Datumszeile können Einträge für div. TN vorkommen
je Datum (evtl. mehrere Zeilen pro Datum) werden Einträge f. jeweiligen TN vorgenommen
Die Aufgabenstellung besteht darin, die Anzahl von Tagen an welchen ein TN mindestens einen Eintrag zu verzeichnen hat, zu Summieren.

Datum           TN 1      TN 2       TN 3     TN 4     TN 5    TN 6    usw.

1. Tag                          5            1 
1. Tag                          3                        2
2. Tag              5          1                                    2
2. Tag              8                                                7
2. Tag                                                    1
3. Tag                          5                                     

... d.h.           TN 1      TN 2       TN 3      TN 4       TN 5     TN 6
Anz. Tage          1          3          4           2          1          0

Hoffe auf Eure Unterstützung ... habe bereits mit Summenprodukt u. Zählenwenn diverses versucht - leider keinen Lösungsansatz gefunden
Vorweg schon einmal herzlichen Dank

Moin

Wie immer ist es eine Frage der richtigen Datenstruktur.
Auswertung mit Pivot und Datenmodell.

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H
1	Datum	TN	Wert				TN	Anzahl verschiedene Datum
2	1	TN2	5				TN1	1
3	1	TN3	1				TN2	3
4	1	TN2	3				TN3	1
5	1	TN4	2				TN4	2
6	2	TN1	5				TN5	1
7	2	TN2	1
8	2	TN5	2
9	2	TN1	8
10	2	TN5	7
11	3	TN4	1
12	3	TN2	5

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

PS: Funktioniert ab Excel 2013.

---

Für deine Version mit Hilfsspalte.

Arbeitsblatt mit dem Namen 'Tabelle2 (2)'
	A	B	C	D	E	F	G	H
1	Datum	TN	Wert	Hilfsspalte			TN	Summe von Hilfsspalte
2	1	TN2	5	0,5			TN1	1
3	1	TN3	1	1			TN2	3
4	1	TN2	3	0,5			TN3	1
5	1	TN4	2	1			TN4	2
6	2	TN1	5	0,5			TN5	1
7	2	TN2	1	1
8	2	TN5	2	0,5
9	2	TN1	8	0,5
10	2	TN5	7	0,5
11	3	TN4	1	1
12	3	TN2	5	1

Zelle	Formel
D2	=1/ZÄHLENWENNS($A$2:$A$12;$A$2:$A$12;$B$2:$B$12;$B$2:$B$12)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

Hallo H...,

zB. so (bis auf TN3):

=ANZAHL2(EINDEUTIG(WENN(B2:B8>0;$A$2:$A$8;42)))-1

ps. Sorry, hatte nicht auf deine Excel-Version geachtet.

Hallo Helho58,

oder so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1		TN1	TN2	TN3	TN4	TN5	TN6
2	Tag1		5	1
3	Tag1		3		2
4	Tag2	5	1			2
5	Tag2	8				7
6	Tag2				1
7	Tag3		2
8	Anz Tage	1	3	1	2	1	0

Zelle	Formel
B8	{=SUMME(N(WENN(B$2:B$7<>"";VERGLEICH(WENN(B$2:B$7<>"";$A$2:$A$7);WENN(B$2:B$7<>"";$A$2:$A$7);0)=(ZEILE($A$2:$A$7)-1))))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Die Formel stammt von hier:
https://www.computerwissen.de/office/exc...ehlen.html

Die -1 am Ende ist in meinem Beispiel notwendig, weil der eigentliche Datenbereich in Zeile 2 beginnt (Zeile 1 sind die Spaltenüberschriften)

Stichwort für Internet-Recherche:
Anzahl unterschiedlicher Werte zählen mit Bedingung


Gruß
Fred

Vielen Dank für Eure Bemühungen.
Lösung von Fred11 ist für meine Zwecke die beste Lösung   

l.G Helmut