Clever-Excel-Forum

Guten Tag alle zusammen. 

Ich sitze vor folgendem Problem und hoffe, dass mir hier jemand helfen kann und einen Lösungsvorschlag für mich hat.

Es geht um einen fortlaufende Tabelle mit Daten.
Hier soll mittels eines Barcode Scanners automatisch ein Satz(Zeile) aus dem bestehenden Datensatz markiert, ausgeschnitten und in ein neues Arbeitsblatt kopiert werden.

Ich versuche dies hier einmal zu beschreiben:

Ein Datensatz besteht aus einer Zeile mit 9 Spalten

Mittels eines Barcode Scanners (Tera Barcode Scanner) wird im original der gescannte Barcode gesucht (z.B. in Zeile 2, Spalte B)

der Datensatz ( gesamte Zeile) in der sich der gesuchte Barcode befindet wird durch das scannen und suchen automatisch ausgeschnitten und in ein neues Arbeitsblatt kopiert.

Eventuell stand hier bereits jemand vor einem ähnlichen Problem. 

Es geht hier speziell um Lagerhaltung und das umbuchen von Waren.

vielen Dank an alle.

beste Grüße
Johannes Werner

Hallo

wenn das ein Scanner ist, der parallel zur Tastatur angesteuert wird, ist es kein Unterschied, ob du scannst oder die Daten von Hand eingibst.

---

Wohin sollen denn die Daten kopiert werden ?
Immer unten anhängen oder soll die Zeile dort auch erst gesucht werden und dann dort ein update erfolgen?


Eine kurze Musterdatei wäre nicht schlecht.

LG UweD

Hallo UweD,

vielen Dank für die schnelle Reaktion.

Ich habe nun eine Musterdatei hier dazu gepackt.
Der Scanner wird parallel über Bluetooth genutzt. 

Das Setup sieht so aus, dass ein Rechner mit angeschlossenem Scanner im Lager steht.

Die Ware die unser Lager verlässt, wird gescannt. 
Dadurch soll der gescannte Datensatz auf das nächste Arbeitsblatt ausgeschnitten werden. 

Hierdurch erhalte ich eine Liste mit allen Seriennummern und Datensätzen, die ich gescannt habe (bzw. die das Lager verlassen)

mit freundlichen Grüßen
Johannes

Hallo

- lege ein neues Blatt an.
- A1 auswählen
- Rechtsclick, Zellen formatieren, Schutz, den Haken bei gesperrt rausnehmen, OK

- Rechtsklick auf den Tabellenblattreiter des Neuen Blattes
- Blatt schützen, bei "gesperrte Zellen" den Haken raus

- Rechtsklick auf den Tabellenblattreiter des neuen Blattes
- Code anzeigen
- Code dort reinkopieren

Zitat:Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim SP As Integer, TB1 As Worksheet, TB2 As Worksheet
    Dim Zeile As Long, LR2 As Long
   
    Set TB1 = Sheets("Tabelle1")
    Set TB2 = Sheets("Tabelle2")
    SP = 2
   
    If Not Intersect(Target, Range("A1")) Is Nothing And Target <> "" Then
        'Scan vorhanden ???
        If WorksheetFunction.CountIf(TB1.Columns(SP), Target) > 0 Then
            Zeile = WorksheetFunction.Match(Target, TB1.Columns(SP), 0)
           
            'Nächste freie Zeile
            LR2 = TB2.Cells(TB2.Rows.Count, 1).End(xlUp).Row + 1
   
            'kopieren
            TB1.Rows(Zeile).Copy TB2.Rows(LR2)
           
            'löschen
            TB1.Rows(Zeile).Delete xlUp
        Else
            'not found
            MsgBox Target & ":  nicht gefunden"
       
        End If
   
    End If

End Sub

Wird in der Zelle ( es ist die Einzige, die offen ist ) eine Änderung durchgeführt wird; also per Scan oder Handeingabe,
dann wird der Scanwert in Tab 1 gesucht, die Zeile verschoben ans Ende von Tab 2


LG UweD