Clever-Excel-Forum

Hallo,

ich habe eine Tabelle mit Datumsangaben in einer Spalte.
Ziel ist es zu berechnen, ob das Datum im Zeitraum zwischen 01.04 bis 30.09 (Sommersemster) oder 01.10 bis 31.03 (Wintersemester) liegt. Je nachdem soll dann der letzte Tag des entsprechenden Semesters ausgegeben werden (30.09. oder 31.03.).

Problem: Es muss nicht nur Tag und Monat ausgegeben werden, sondern auch das entsprechende Jahr (im Falle des Wintersemesters ggf. das darauffolgende Jahr).

Beispiel:

30.01.2021 --> 31.03.2021
01.10.2020 --> 31.03.2021
04.05.2019 --> 30.09.2019
30.09.2017 --> 30.09.2017

Hat jemand eine Idee, wie ich das mit einer Formel in Excel 2016 hinbekomme?

Danke schonmal für eure Antworten.

Viele Grüße

Moin

Startdaten muss aufsteigend sortiert sein.

Antwort an den freundlichen "Hallo",
hallo SimWa.

Nimm diese Formel:

=WENN(MONAT(A3)<=3;"31.03."&JAHR(A3);WENN(MONAT(A3)<=9;"30.09."&JAHR(A3);"31.03."&JAHR(A3)+1))

wobei die Daten in der Spalte A sind.
Anmerkung: Es gibt bestimmt noch bessere Lösungsansätze.

Gruß Rudi

Hallo Rudi,

wow, super vielen Dan. Es funktioniert! Ich bin begeistert und froh, dass ich den Datensatz so in sekundenschnelle berechnen kann. Tausend Dank!!!

Viele Grüße

Moin!
Eine Alternative, die ausschließlich aus "sportlichen" Gründen erstellt wurde:

	A	B
1	Datum	Semesterende
2	30.01.2021	31.03.2021
3	01.10.2020	31.03.2021
4	04.05.2019	30.09.2019
5	30.09.2017	30.09.2017

Zelle	Formel
B2	=MONATSENDE(A2;VERWEIS(MONAT(A2);ZEILE(Z$1:Z$12);{2.1.0.5.4.3.2.1.0.5.4.3}))

In einem aktuellen Excel kann man statt ZEILE(Z$1:Z$12) auch SEQUENZ(12) nehmen.

@Rudi:
Du solltest noch ein -- vor WENN stellen, damit das Ergebnis ein echtes Datum wird.

… und mit einer Hilfsspalte wird es gleich richtig schlank:

	A	B	C	D
1	Datum	Semesterende		2
2	30.01.2021	31.03.2021		1
3	01.10.2020	31.03.2021		0
4	04.05.2019	30.09.2019		5
5	30.09.2017	30.09.2017		4
6				3
7				2
8				1
9				0
10				5
11				4
12				3

Zelle	Formel
B2	=MONATSENDE(A2;INDEX(D:D;MONAT(A2)))

Diese Idee ohne Hilfsspalte wäre dann:
=MONATSENDE(A2;INDEX({2.1.0.5.4.3.2.1.0.5.4.3};MONAT(A2)))

Gruß Ralf

=DATUM(JAHR(A1);OBERGRENZE(MONAT(A1)+3;6)-2;)