Clever-Excel-Forum

Hallo zusammen,
 
ich hätte da mal wieder eine Frage und hoffe auf Hilfe

Folgendes Szenario:

Ich habe aktuell ein Tabellenblatt „Summary“ und ein Tabellenblatt „Program Data“.
Im Tabellenblatt „Program Data“ steht im Zellbereich Q6:V25 ein Wort in jeder Zelle.
Im Tabellenblatt „Summary“ steht im Zellbereich F28:J47 ebenfalls ein Wort in jeder Zelle.
Excel soll nun abgleichen, ob die Wörter in den einzelnen Zellen übereinstimmen, und falls nicht, diese im Tabellenblatt „Summary“ rot markieren.
 
Das Ganze funktioniert auch mit der nachfolgenden Bedingten Formatierung:
= SVERWEIS($E28;'Program Data'!$Q$6:$V$25;SPALTE(B1);0)<>F28
 
Jetzt möchte ich aber noch einen Schritt weiter gehen. Aktuell vergleicht er immer eine Zelle aus dem einen Tabellenblatt mit einer Zelle aus dem anderen Tabellenblatt und markiert diese rot wenn sie nicht übereinstimmen. Ich möchte aber, dass er die Wörter einer Zeile nicht rot markiert, wenn sie übereinstimmen, sondern lediglich in unterschiedlicher Reihenfolge stehen.

Ist das noch mit der bedingten Formatierung zu lösen? Oder benötige ich hier ein Makro? Falls es nur mit einem Makro zu lösen ist, kann mir da jemand ein paar Tipps geben wie ich es angehen kann? Ich habe schon ein paar einfache Makros erstellt, wüsste aber auf Anhieb nicht, wie ich das am besten anstelle.

Zum besseren Verständnis habe ich mal eine Beispieldatei angehängt.

Danke und Gruß
Sebbo

Hallöchen,

Du kannst z.B. mit der Funktion VERGLEICH die Zeilennummer eines Eintrags feststellen. Nun kommt es darauf an, was Du mit der Reihenfolge meinst. Wenn es nun darauf ankommt, dass bei der Reihenfolge nur das Wort davor oder danach übereinstimmt dann, wie gesagt, mit VERGLEICH. Hier mal ein Ansatz

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
2	OTTO	4	WAHR	BALD
3	KAR	5	WAHR	WILLI
4	WILLI	2	FALSCH	Gerd
5	BALD	1	FALSCH	OTTO
6				KAR

Zelle	Formel
B2	=VERGLEICH(A2;$D$2:D6;0)
C2	=ODER(B2=B3-1;B2=B1+1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

Wenn es reicht, dass z.B. die Wörter in der gleichen Zelle stehen, reicht als Bedingung schon im Prinzip =A1=Tabelle2!A1

Hallo Sebbo,

wenn die Reihenfolge von 
Stadt
Land
Fluß
in deinen beiden Tabellen immer gleich ist, funktioniert es z. B. mit ZÄHLENWENN(...)

Arbeitsblatt mit dem Namen 'Tabelle1'
	J	K	L	M	N	O
4	Datenblatt "Summary"
5
6	…	E	F	G	H	…
7	28	Stadt	Italien	Österreich	Berlin	…
8	29	Land	Deutschland	Rom	Salzburg	…
9	30	Fluss	Isar	Reno	Lech	…
10	…	…	…	…	…	…
11
12
13
14
15	Datenblatt "Program Data"
16
17	…	P	Q	R	S	…
18	6	Stadt	Berlin	Italien	Österreich	…
19	7	Land	Deutschland	Rom	Wien	…
20	8	Fluss	Isar	Tiber	Lech	…
21	…	…	…	…	…	…

Zelle	bedingte Formatierung...	Format
L7	1: ZÄHLENWENN($L18:$N18;L7)=0	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

(Dollarzeichen beachten !)

Siehe Beispieldatei

Gruß
Fred

Einen schönen guten Morgen euch beiden und vielen Dank für eure Hilfe bzw. Lösungsansätze

Es tut mir leid, ich hätte mich noch etwas präziser ausdrücken müssen.

Die beispielhaften Wörter "Stadt, Land, Fluss" können leider ebenfalls variieren und stehen nicht zwangsläufig im Tabellenblatt "Summary" und im Tabellenblatt "Program Data" in derselben Reihenfolge.
Deswegen auch der Ansatz über den "SVERWEIS", dass er mir die entsprechend zugehörigen Zeilen sucht und findet.

Die zu vergleichenden Wörter, welche er dann bei Abweichung rot markieren soll, können in ihrer Anordnugn ebenfalls beliebig in jeder Zeile variieren.

Das mit ZÄHLENWENN funktioniert ja schon super, ich müsste es jetzt nur noch irgendwie mit dem SVERWEIS verheiraten. Geht das irgendwie? Meine Versuche das zu kombinieren sind bis jetzt gescheitert :(

Viele Grüße
Sebbo

Hallöchen,

statt "L7" dann den SVERWEIS?

ZÄHLENWENN($L18:$N18;SVERWEIS(...))=0

Hallo Sebbo,

meiner Meinung nach funktioniert das was du möchtest nicht mit SVERWEIS.

Wenn die Anordnung der Zeilen in den beiden Tabellen unterschiedlich ist, musst du den Bereich für ZÄHLENWENN dynamisch ermitteln, und zwar mit INDEX/VERGLEICH.

Arbeitsblatt mit dem Namen 'Tabelle1'
	J	K	L	M	N	O
4	Datenblatt "Summary"
5
6	…	E	F	G	H	…
7	28	Stadt	Italienxx	Österreich	Berlin	…
8	29	Land	Deutschland	Rom	Salzburg	…
9	30	Fluss	Isar	Reno	Lech	…
10	…	…	…	…	…	…
11
12
13
14
15	Datenblatt "Program Data"
16
17	…	P	Q	R	S	…
18	6	Stadt	Berlin	Italien	Österreich	…
19	7	Fluss	Isar	Tiber	Lech	…
20	8	Land	Deutschland	Rom	Wien	…
21	…	…	…	…	…	…

Zelle	bedingte Formatierung...	Format
L7	1: ZÄHLENWENN(INDEX($L$18:$N$20;VERGLEICH($K7;$K$18:$K$20;0);0);L7)=0	abc

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Zusammenspiel von relativen und absoluten Bezügen (=> Dollarzeichen) beachten !

Siehe angehängte Beispieldatei

Gruß
Fred

Hallo ihr beiden,

ich muss mich bei euch herzlich bedanken! Es funktioniert! Ich bin so happy

Ich habe es jetzt nicht weiter mit dem SVERWEIS probiert, sondern mir Fred`s Beispieldatei mit INDEX/VERGLEICH zu Gemüte gezogen und sie entsprechend angepasst.
Läuft einwandfrei! Excel erkennt wie gewünscht die Namen (hier Stadt/Land/Fluss) und prüft entsprechend die Wörter. Die Reihenfolge spielt dabei wie erhofft keine Rolle mehr.

Ich kann nur nochmal vielen Dank sagen! Es ist toll wie einem hier im Forum geholfen wird. Das hätte ich alleine niemals hinbekommen.

Ich wünsche euch noch einen schönen Abend!

Viele Grüße
Sebbo