Clever-Excel-Forum

Hallo zusammen,
ich versuch mal mein Problem zu schildern:

Ich habe eine Excel-Tabelle mit klassischen Personenbezogenen Daten (Vorname, Name, Straße, etc.). Diese Tabelle ist später für den Import gedacht um eine Datenbank zu füttern.
Nun habe ich zu jeder Person eine Bilddatei, die in einem Ordner abgespeicht ist, doch der Dateiname keinem einheitlichen Standard entspricht. Was aber jeder Dateiname enthält, ist der Name und Vorname.

Wir bekomme ich es hin, dass excel unter den ganzen Dateinamen die gewünschte Person (Vorname und Name) findet und mir den Dateinamen an die richtige Stelle kopiert?

Verdeutlicht habe ich das mal mit Bildern
Bild 1 zeigt die einzelnen Datensätze
Bild 2 zeigt die verschiedenen Dateinamen, wo aber der Vorname und der Name immer auftaucht

Habt ihr eine Idee? Ich muss ca. 6000 Datensätze bearbeiten und möchte dies sicherlich nicht händisch tun.

Liebe Grüße
razzo

Hallo razzo,

z.B. so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	Vorname	Name	Bild			Dateiname
2	Hanna	Müller				1-Gustav-Gans
3	Hugo	Habicht	_Hugo_Habicht_xx			Excel_Egon_xxx
4	Gustav	Gans	1-Gustav-Gans			Hanna_Mülle
5	Max	Mustermann	Max-----Mustermann			_Hugo_Habicht_xx
6	Kurt	Kantig	KurtttttKantig			Max-----Mustermann
7	Peter	Pan				KurtttttKantig
8	Egon	Excel	Excel_Egon_xxx

Zelle	Formel
C2	=WENN(SUMMENPRODUKT(ISTZAHL(SUCHEN(A2;$F$2:$F$7))*ISTZAHL(SUCHEN(B2;$F$2:$F$7)))>0;INDEX($F$2:$F$7;AGGREGAT(14;6;ISTZAHL(SUCHEN(A2;$F$2:$F$7))*ISTZAHL(SUCHEN(B2;$F$2:$F$7))*ZEILE($F$2:$F$7);1)-ZEILE($F$1));"")
C3	=WENN(SUMMENPRODUKT(ISTZAHL(SUCHEN(A3;$F$2:$F$7))*ISTZAHL(SUCHEN(B3;$F$2:$F$7)))>0;INDEX($F$2:$F$7;AGGREGAT(14;6;ISTZAHL(SUCHEN(A3;$F$2:$F$7))*ISTZAHL(SUCHEN(B3;$F$2:$F$7))*ZEILE($F$2:$F$7);1)-ZEILE($F$1));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß
Fred

...oder kürzer so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	Vorname	Name	Bild			Dateiname
2	Hanna	Müller				1-Gustav-Gans
3	Hugo	Habicht	_Hugo_Habicht_xx			Excel_Egon_xxx
4	Gustav	Gans	1-Gustav-Gans			Hanna_Mülle
5	Max	Mustermann	Max-----Mustermann			_Hugo_Habicht_xx
6	Kurt	Kantig	KurtttttKantig			Max-----Mustermann
7	Peter	Pan				KurtttttKantig
8	Egon	Excel	Excel_Egon_xxx

Zelle	Formel
C2	=WENNFEHLER(WENNFEHLER(SVERWEIS("*"&A2&"*"&B2&"*";$F$1:$F$7;1;0);SVERWEIS("*"&B2&"*"&A2&"*";$F$1:$F$7;1;0));"")
C3	=WENNFEHLER(WENNFEHLER(SVERWEIS("*"&A3&"*"&B3&"*";$F$1:$F$7;1;0);SVERWEIS("*"&B3&"*"&A3&"*";$F$1:$F$7;1;0));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Gruß
Fred

Vielen lieben Dank für die tolle Hilfe!
Die Formel tut genau dass, was Sie sollte!

Bin begeistert!
:87: