Hallo zusammen,
ich hoffe, jemand von euch kann mir helfen.
Ich habe folgende Formel, welche ich erweitern soll und einfach keine Lösung finde (ich verstehe die Formel an sich schon nicht 100%):
=WENN(SUMMENPRODUKT(LÄNGE(T4:FV4)-LÄNGE(WECHSELN(KLEIN(T4:FV4);"?";)))>0;"?";"")
Nun ist es so das in dem Wertebereich nicht nur ein "?" auftauchen kann, sondern auch "i" und natürlich dann dementsprechend ein "i" ausgegeben werden soll anstelle eines "?". Das bekomme ich aber nicht hin.
Diese Ursprungsformel ist nicht von mir, soll aber nach Möglichkeit erhalten bleiben.
Ich von meiner Seite aus hätte einfach eine geschachtelte Wenn-Funktion erstellt, aber kennt vielleicht jemand eine Lösung bei der die Ursprungsformel erhalten bleiben kann?
Vielen Dank schonmal für eure Hilfe.
Hallöchen,
dann mache das selbe nochmal mit dem i, statt des "" am jetzigen Ende
hallo
du könntest die Formel erneut anwenden und dabei beide Prüfungen mit einem kaufmännischen & verbinden:
=WENN(SUMMENPRODUKT(LÄNGE(T4:FV4)-LÄNGE(WECHSELN(KLEIN(T4:FV4);"?";)))>0;"?";"")&WENN(SUMMENPRODUKT(LÄNGE(T4:FV4)-LÄNGE(WECHSELN(KLEIN(T4:FV4);"I";)))>0;"I";"")
Das gleiche Prinzip etwas kürzer:
=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"I"&"*"));"I";"")
Gruß Holger
Hi Holger,
entweder ? oder i
An sich funktionieren alle vorgeschlagenen Varianten, vielen Dank aber...
Die Tabelle besteht natürlich auch aus vielen Zeilen und ich möchte natürlich in allen Zeilen für diese Spalte die Formel anwenden.
Jedoch funktioniert die Formel nur in 1/4 der Zeilen, in den restlichen Zeilen wird mir direkt ein "I" angezeigt obwohl keine Werte in der Zeile vorhanden sind.
Formatiert sind die Zellen alle gleich und die Formel ist natürlich immer an die entsprechende Zeile angepasst.
Eine Idee was der Fehler sein könnte?
Ich kann die Tabelle leider nicht zur Verfügung stellen und hoffe auf euer Talent zur Ferndiagnose :32:
Hallöchen,
wenn nix weiter in der Zeile steht siehst Du auch nix:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A |
| 4 | |
| Zelle | Formel |
| A4 | =WENN(SUMMENPRODUKT(LÄNGE(T4:FV4)-LÄNGE(WECHSELN(KLEIN(T4:FV4);"?";)))>0;"?";"")&WENN(SUMMENPRODUKT(LÄNGE(T4:FV4)-LÄNGE(WECHSELN(KLEIN(T4:FV4);"I";)))>0;"I";"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Ansonsten steht eventuell doch was drin. Gehe mal in die Zellen und drücke ENTF ...
Hallo sakl.
bei Verwendung dieser Formel
=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"I"&"*"));"I";"")
und du Platz in deiner Datei hast, kannst du bei Ersatz für zB. T4:FV4 INDIREKT(Zelle):INDIREKT(Zelle) verwenden, wobei Zelle:Zelle zB: A1:B1 sein kann, also Zellen wo du deine Suchbereiche einträgst.
Allerdings würde sich bei der Vielzahl der Zeilen ein kleines Makro zur Suche empfehlen.
Gruß Rudi
Hallo schauan,
ich habe das Problem gefunden. :33:
Mit der Formel wird "i" angezeigt egal ob sie als Einzelwert in einer Zelle vorkommen oder innerhalb eines Wortes wie z.B. invalid. Deshalb habe ich in 3/4 der Zeilen schon ein "i" im Formelfeld angezeigt. Ich habe natürlich die Zeilen nur nach meinen gesuchten Werten "?" und "i" geschaut und die waren nicht vorhanden.
Da muss ich mir jetzt mal was basteln, das nur die Zellen mit einem einzelnen "I" zählen und nicht die in Worten enthaltenen.
Vielen Dank für all eure Hilfe
=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"I"&"*"));"I";"")
=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"I"));"I";"")
Hallo
bei meiner verkürzten Variante hilft vielleicht schon, die Platzhalter "*" weg zu lassen.
Dann beschränkt sich die Suche exakt auf I. Sobald in der Zelle irgendein ein Leerzeichen / Buchstabe / Zahl dazu kommt wird die Zelle ignoriert
https://www.online-excel.de/excel/singsel.php?f=73
Gruß Holger
(14.08.2020, 08:27)echo schrieb: [ -> ]=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"I"&"*"));"I";"")
=WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"*"&"~?"&"*"));"?";"")&WENN(SUMMENPRODUKT(ZÄHLENWENN(T4:FV4;"I"));"I";"")
Hallo
bei meiner verkürzten Variante hilft vielleicht schon, die Platzhalter "*" weg zu lassen.
Dann beschränkt sich die Suche exakt auf I. Sobald in der Zelle irgendein ein Leerzeichen / Buchstabe / Zahl dazu kommt wird die Zelle ignoriert
https://www.online-excel.de/excel/singsel.php?f=73
Gruß Holger
Funktioniert einwandfrei.
Vielen vielen Dank.