Hallo Zusammen,
ich habe einen CRM Ecpprt eine Excel Tabelle in der in einer Liste aufgeführt ist,
welcher Mitarbeiter an welchen Tagen welche Rufnummern gewählt hat.
Über die ZÄHLENWENNS FUNKTION kann ich problemlos zählen, wieviele Anrufe jeder Mitarbeiter je Tag durchgeführt hat.
Allerdings würde ich auch gerne auswerten, wieviele verschiedene Rufnummern ein Mitarbeiter an einem bestimmten Tag angewählt hat.
So ist die Liste aufgebaut...
Datum - Mitarbeiter - gewählte Rufnummer
Hat jemand einen Tipp für mich, wie ich das machen kann?
Besten Dank schonmal :)
Hallo,
nimm SUMMENPRODUKT().
Danke dir!
Allerdings habe ich zwei Bedingungen, die zutreffen müssen:
Es sollen alle unterschiedlichen Eintragungen in Spalte C gezählt werden, die in Spalte A den Wert X haben und in Spalte B den Wert Y.
Das haut mit der Formel aus deinem Link nicht hin, oder?
Hola,
doch, auch das haut hin. In der Summenprodukt-Formel
Code:
=SUMMENPRODUKT((VERGLEICH(A1:A10&B1:B10;A1:A10&B1:B10;0)=ZEILE(X1:X10))*(A1:A10=4)*(B1:B10<>""))
kommt der zusätzliche Bereich in den Vergleich-Teil und die Bedingung ebenso.
Code:
=SUMMENPRODUKT((VERGLEICH(A1:A10&B1:B10&C1:C10;A1:A10&B1:B10&C1:C10;0)=ZEILE(X1:X10))*(A1:A10="x")*(C1:C10="y")*(B1:B10<>""))
Gruß,
steve1da
Ok, ich probiere es gleich mal aus, danke nochmal :)
(28.07.2020, 15:33)WillWissen schrieb: [ -> ]Hallo,
deine Frage sagt mir, dass du angebotene Lösungen gar nicht ausprobierst. Und: mit einer Beispieldatei, die vom Aufbau her deinem Original entsprechen muss, können die Helfer gezielter antworten. https://www.clever-excel-forum.de/Thread...ng-stellen
hey, danke für den Hinweis.
meine o,g, Antwort war eher nochmal als Verständnisfrage gemeint und auch nicht auf deine erste Antwort bezogen.
ich probiere mich jetzt mal aus und komme im Zweifel nochmal mit einem Beispieldokument im die Ecke, falls ich es nicht hinbekomme.
danke auf jeden Fall für den Support
Habs leider nicht hinbekommen :(:(
Ich habe jetzt mal eine Beispieltabelle angelegt und Screenshots von den betroffenen Reitern gemacht.
In Reiter 1 sind die Rohdaten.
In Reiter 2 die Auswertung.
--> Hier soll das Datumsfeld manuell geändert werden können.
--> Zeile 4: Hier sollen die Anzahl der verschiedenen Rufnummern stehen, die der Mitarbeiter (Zeile 2) an dem jeweiligen Tag (Zeile 1) angewählt hat (Informationen stehen im Reiter 1)
Vielen Dank für die Unterstützung, bin schon für die ersten Antworten sehr dankbar und hätte nicht gedacht, dass das hier so schnell geht :)
Hi,
mal ein Vorschlag mit einer (ausblendbaren) Hilfsspalte im Blatt Anruflisten:
Arbeitsblatt mit dem Namen 'Anruflisten' |
| A | B | C | D |
1 | Datum | Mitarbeiter | Telefonnummer | HS |
2 | 27.07.2020 | Hans | +4912372 | 1 |
3 | 27.07.2020 | Peter | +4193839 | 1 |
4 | 27.07.2020 | Julia | +499826733 | 1 |
5 | 27.07.2020 | Hans | +4912372 | 2 |
6 | 27.07.2020 | Hans | +4987387849 | 1 |
7 | 27.07.2020 | Julia | +4993444 | 1 |
8 | 27.07.2020 | Hans | +43434343 | 1 |
9 | 27.07.2020 | Julia | +8379283 | 1 |
10 | 27.07.2020 | Peter | +4993444 | 2 |
Zelle | Formel |
D2 | =ZÄHLENWENN($C$2:$C2;$C2) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Arbeitsblatt mit dem Namen 'Auswertung' |
| A | B | C | D |
1 | Datum | 27.07.2020 | 28.07.2020 | 28.07.2020 |
2 | Mitarbeiter | Hans | Peter | Julia |
3 | Anzahl Anrufe | 4 | 0 | 0 |
4 | Anzahl versch. Rufnummern | 3 | 0 | 0 |
Zelle | Formel |
B3 | =ZÄHLENWENNS(Anruflisten!$B$1:$B$20;B$2;Anruflisten!$A$1:$A$20;B$1) |
B4 | =ZÄHLENWENNS(Anruflisten!$D$1:$D$20;1;Anruflisten!$B$1:$B$20;B$2;Anruflisten!$A$1:$A$20;B$1) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hola,
die Formel aus dem Link, angepasst auf deine Datei:
Code:
=SUMMENPRODUKT((VERGLEICH(Anruflisten!$A$2:$A$10&Anruflisten!$C$2:$C$10&Anruflisten!$B$2:$B$10;Anruflisten!$A$2:$A$10&Anruflisten!$C$2:$C$10&Anruflisten!$B$2:$B$10;0)=ZEILE($X$2:$X$10)-1)*(Anruflisten!$A$2:$A$10=B1)*(Anruflisten!$B$2:$B$10=B2)*(Anruflisten!$C$2:$C$10<>""))
Wird aber überall 0 ergeben weil das Datum nicht passt. Außerdem hat Hans nicht 4 unterschiedliche Nummern gewählt, sondern nur 3.
Gruß,
steve1da