Hallo zusammen,
ich habe ein excel problem, was ein Wunder :D
ich hab Kunden sagen wir x,y je Umsatz.
jetzt möchte ich das eine liste erstellt wird mit den Kunden ab 50 EUR Umsatz.
ich habe es mit kkleinste bzw. Kgrößte versucht , das problem ist das die Formel mir auf den ersten platz dann die 50 ausgeben soll und auf den 2 platz zum beispiel die 51 und nicht immer direkt den kleinsten oder größte wert.
Rang Kunde Umsatz
1 a 50
2 b 51
3 g usw
4 f
5 g
ich hoffe ihr könnt mir helfen.
Viele Grüße
Crank15
Hallo,
falls ich dich richtig verstanden habe:
| Arbeitsblatt mit dem Namen 'Tabelle2' |
| A | B |
| 1 | 27 | 50 |
| 2 | 45 | 51 |
| 3 | 50 | 52 |
| 4 | 51 | 53 |
| 5 | 12 | 66 |
| 6 | 15 | |
| 7 | 53 | |
| 8 | 66 | |
| 9 | 16 | |
| 10 | 52 | |
| Zelle | Formel |
| B1 | =WENNFEHLER(KKLEINSTE(WENN($A$1:$A$10>=50;$A$1:$A$10);ZEILE(A1));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
wooow das ist Super!!!!!!!!!!!!!!!!!!!
Vielen Dank!!!
ich hab noch eine andere Frage :D
ich möchte jetzt auch den jeweiligen namen des Kunden in der neben Spalte aufgelistet bekommen. Also einmal 50Euro und dann dazu noch den jeweiligen Kundennamen.
=INDEX(Sheet1!$U:$U;VERGLEICH(KGRÖSSTE(Sheet1!$L:$L;ZEILE(A1));Sheet1!L:L;0);SPALTE(A1))
mit der Formel gibt er mir schon mal den größten Wert aus aus der Liste aus. jedoch hab ich es nicht Geschaft die Formel da einzubauen, damit er mir auch noch in der neben Spalte den Namen ausgibt.
Hallo,
falls mit Version 2006 im Profil Office 365 gemeint ist:
Tabelle1 | A | B | C | D | E |
| 2 | 50 | Name A | | 50 | Name A |
| 3 | 45 | Name B | | 50 | Name c |
| 4 | 50 | Name c | | 51 | Name d |
| 5 | 51 | Name d | | 52 | Name K |
| 6 | 12 | Name e | | 53 | Name g |
| 7 | 15 | Name F | | 66 | Name h |
| 8 | 53 | Name g | | | |
| 9 | 66 | Name h | | | |
| 10 | 16 | Name I | | | |
| 11 | 52 | Name K | | | |
| verwendete Formeln | |
| Zelle | Formel | Bereich | N/A |
| D2 | =SORTIEREN(FILTER(A2:B11;A2:A11>=50);1;1) | | |
Hi,
für die Nicht-365-er:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D |
| 1 | 27 | Berta | 50 | Agnes |
| 2 | 45 | Robert | 51 | Arthur |
| 3 | 50 | Agnes | 52 | Helene |
| 4 | 51 | Arthur | 53 | Berta |
| 5 | 12 | Arthur | 66 | Helene |
| 6 | 15 | Robert | | |
| 7 | 53 | Berta | | |
| 8 | 66 | Helene | | |
| 9 | 16 | Johann | | |
| 10 | 52 | Helene | | |
| Zelle | Formel |
| C1 | =WENNFEHLER(KKLEINSTE(WENN($A$1:$A$10>=50;$A$1:$A$10);ZEILE(A1));"") |
| D1 | =WENNFEHLER(INDEX(B:B;VERGLEICH(C1;$A$1:$A$10;0));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Index vergleich funktioniert leider nicht, da ich mehrere Doppelte Werte habe mit verschiedenen Name :/
gibt es da noch eine andere Formel?
Prima, dass wir das jetzt schon erfahren. Welche Excel-Version besitzt du nun? 2006 ist mir nicht bekannt.
Hier mal ein Vorschlag mit 2 Hilfsspalten (farbig hinterlegt), die du einfach ausblenden kannst:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F |
| 1 | 27 | Berta | | 3 | 50 | Agnes |
| 2 | 45 | Robert | | 4 | 50 | Arthur |
| 3 | 50 | Agnes | 3 | 7 | 53 | Berta |
| 4 | 50 | Arthur | 4 | 8 | 66 | Helene |
| 5 | 12 | Arthur | | 10 | 66 | Petra |
| 6 | 15 | Robert | | #### | | |
| 7 | 53 | Berta | 7 | #### | | |
| 8 | 66 | Helene | 8 | #### | | |
| 9 | 16 | Johann | | #### | | |
| 10 | 66 | Petra | 10 | #### | | |
| Zelle | Formel |
| C1 | =WENN(A1>=50;ZEILE();"") |
| D1 | =KKLEINSTE($C$1:$C$10;ZEILE(A1)) |
| F1 | =WENNFEHLER(INDEX(B:B;D1);"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Danke für eure Hilfe!
ich habe Version 2005.
Hi,
2005? Wieso steht "2006" im Profil? Dies war aber nicht gemeint. Unter welcher Bezeichnung wurde diese gekauft?
Office 2007, 2013, 2016, 2019 oder Office 365 als Abo?
Hi Crank,
weil ich vorhin weg musste, hatte ich völlig übersehen, dass eine Hilfsspalte ausreicht (Spalte C). Du musst die Formel nur abändern:
Code:
=WENNFEHLER(INDEX(B:B;KKLEINSTE($C$1:$C$10;ZEILE(A1)));"")