Clever-Excel-Forum

Normale Version: Text suchen, ausschneiden und in neue Spalte
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hi, 
Erstmal muss ich zugeben das ich absolut keine Ahnung von Excel habe. Ich weiß wie man Texte schreibt sachen farbig macht und sachen addiert... Das wars dann aber auch schon. 

Jetzt hab ich das Problem das ich eine liste mit über zweitausend Einträgen habe mit denen ich direkt aber nicht arbeiten kann. 
Momentan hab ich z. B. In Spalte A "VW Golf 9n grau" stehen. 
Also Hersteller abkürzung und Produkt text. 

Jetzt möchte ich hingehen und sagen such mir alle Einträge wo am Anfang "VW" steht raus. Schneide das VW aus und füge es in Spalte B ein. Zusätzlich will ich ihm sachen das er mir dann dieses "VW" mit "Volkswagen" ersetzen soll. 

Jetzt hab ich schon alle möglichen foren durchgeschaut und so sachen gefunden wie nimm von allen spalten die ersten 2 zeichen etc aber das bringt mir nichts da es unterschiedlich lange abkürzungen gibt. 

Wie stelle ich sowas am besten an??
Moin,

so?
Arbeitsblatt mit dem Namen 'Tabelle1'
AB
1VW Golf 9n grauVolkswagen
2VW Pass 5 xx weißVolkswagen

ZelleFormel
B1=WECHSELN(LINKS(A1;2);"VW";"Volkswagen")
B2=WECHSELN(LINKS(A2;2);"VW";"Volkswagen")
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

oder:
Code:
=ERSETZEN(LINKS(A1;2);1;2;"Volkswagen")
Vorbemerkung: Möglicherweise bin ich am Thema vorbei.

Da Du die neueste XL-Version hast:

X2: =LINKS(FILTER(WECHSELN(A2:B6;"VW";"Volkswagen");LINKS(A2:A6;2)="VW");{10.99})

A2:B6 sind exemplarisch hier 2 von beliebig vielen Spalten. Bei mehr Spalten musst Du {10.99} erweitern. Komplett-Rückgabe als Text.

Code:
VW Golf    WAHR
ldjv       23
skjdfh     4
VW Passat  221
VW T-Roc   Juhu
wird zu
Code:
Volkswagen    WAHR
Volkswagen    221
Volkswagen    Juhu

Ich habe mindestens eine zweite Spalte ausgegeben, da ich, statt 3 x "Volkswagen" untereinander zu schreiben, auch einfach 3 zählen könnte. Denn die Daten-Unterscheidbarkeit ginge verloren, und somit relevante Information.

Verbesserung 1, da alle Spalten ihre Typen behalten:

X2: =FILTER(WAHL(SPALTE(A2:B6);WECHSELN(LINKS(A2:B6;2);"VW";"Volkswagen");A2:B6);LINKS(A2:A6;2)="VW")

Verbesserung 2: Die Spalte 1 wird in 2 Spalten aufgeteilt (mit Rettung der Modellbezeichnung), Spalte 2 wird zu Spalte 3:

X2: =FILTER(WAHL(SPALTE(A2:C6);WECHSELN(LINKS(A2:B6;2);"VW";"Volkswagen");TEIL(A2:A6;4;99);B2:B6);LINKS(A2:A6;2)="VW")

Mithin schon ziemlich entfernt von dem, was ein Filter eigentlich nur ist!

Da nun aber klar ist, dass der Filter in der ersten Spalte immer "Volkswagen" enthält, kann das auch noch weg, weil man "Volkswagen" statt dessen auch einmal über das ganze schreiben könnte:

X2: =FILTER(WAHL(SPALTE(A2:B6);TEIL(A2:A6;4;99);B2:B6);LINKS(A2:A6;2)="VW")

Code:
Golf     WAHR
Passat   221
T-Roc    Juhu

Somit sind wir beim Filtrat ohne Filterkriteriumswiedergabe angekommen.
Moin,

woher weißt du, dass der TE die neueste Version besitzt?  [attachment=32630]
Ist eine Annahme  :) , die ohne Klarstellung öfters so getroffen wird.

Er hat es mir nicht vorher per PN gesagt. Isch schwör.

Falls unzutreffend war es ein Beitrag für die neue Welt.
Hi,


Zitat:Falls unzutreffend, war es ein Beitrag für die neue Welt.
Thumbsupsmileyanim
Fortsetzung zu #3:

WENN ist geeigneter als WAHL, wenn es auf unveränderte Wiedergabe der meisten Spalten ankommt:

X2: =FILTER(WENN(SPALTE(A2:C6)=1;TEIL(A2:A6;4;99);A2:C6);LINKS(A2:A6;2)="VW")

Code:
VW Golf           1    WAHR
ldjv              2    23
skjdfh            3    4
VW Passat         4    221
VW T-Roc          5    Juhu
wird zu
Code:
Golf      1    WAHR
Passat    4    221
T-Roc     5    Juhu
Hallo,

ich habe Kurmuro so verstanden, dass er das Beispiel mit "VW" nur exemplarisch gemeint hat.
Spricht er doch von unterschiedlichen Länge der Abkürzungen.

Dann macht es doch auch Sinn erst einmal eine Liste mit den Automarken (zB. Volkswagen, Opel, Mercedes, BMW usw.) mit Kürzel und vollem Markennamen als Bezug für seine Formel zu erstellen und in seine Spalte B dann folgende Formel (beinhaltet die Suche nach dem  1. Freizeichen nach dem Kürzel und den Bezug zur Liste (hier: Fahrzeuge))

=WECHSELN(LINKS(A2;FINDEN(" ";A2;1)-1);LINKS(A2;FINDEN(" ";A2;1)-1);SVERWEIS(LINKS(A2;FINDEN(" ";A2;1)-1);Fahrzeuge;2;0))

zu stellen. 
Es gibt bestimmt auch elegantere Lösungen, aber es ist erst mal eine.
Für seinen Wunsch, dieses Kürzel aus dem Text in Spalte A zu entfernen, kommt meines (beschaulichen) Wissens nur eine VBA- Lösung in Frage, oder ein Eintrag in einer neuen Spalte. 

Gruß Rudi