Clever-Excel-Forum

Normale Version: Zelle mit Wert in zweidimensionaler Matrix finden
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hallo zusammen,

kann mir jemand einen Tipp zu folgendem Anliegen geben:
Ich möchte in einer Tabelle, von der ich weiß, dass sie den Suchwert enthält, Zeile und Spalte des ersten Treffers ermitteln. (Quasi "VERGLEICH..." im 2D-Format). Anbei versuche ich, meine Frage mit einer Beispieltabelle zu illustrieren:
[attachment=32078]
Vielen Dank für eure Unterstützung.
Gruß Ludwig
Moin


Code:
=AGGREGAT(15;6;SPALTE($C$5:$J$21)/($C$5:$J$21=$E$25);1)-2
=AGGREGAT(15;6;ZEILE($C$5:$J$21)/($C$5:$J$21=$E$25);1)-4
PHP-Code:
=SUMPRODUCT(($C$5:$J$21=$E$25)*COLUMN($A$1:$H$17)) 

PHP-Code:
=SUMPRODUCT(($C$5:$J$21=$E$25)*ROW($A$1:$H$17)) 
Recht vielen Dank ihr beiden,

funktioniert!

Anmerkung noch zur Lösung von snb:
Der Ansatz bringt, falls mehrere Treffer existieren, die jeweilige Aufsummierung der Spalten bzw. Zeilen;
für 1 Suchergebnis - wie in meinem Beispiel- funktioniert er tadellos.

Viele Grüße Ludwig
Nachtrag:
Ich hab grad gesehen, dass ich meinen Betreff schlampig geschrieben hatte.
Ich meinte natürlich "Zweidimensionale Matrix".
Gruß Ludwig
Hi Ludwig,

kein Problem - wird ausgebessert.
Servus zusammen,

eine Erkenntnis aus der Anwendung der 2D-Suche hat mich noch ereilt:
Wenn man mit dem Formelansatz von shift-del sowohl Zeile als auch Spalte ermittelt, kann es Ärger geben, wenn mehrere Treffer vorhanden sind.
Man erhält -logischerweise- den Schnittpunkt aus der ersten Trefferzeile und der ersten Trefferspalte. (siehe Anhang)
Deshalb habe ich nochmal modifiziert, wobei der Zeilentreffer priorisiert wird; innerhalb dieser Zeile suche ich dann mit "VERGLEICH...".
D.h. meine Formel lautet nun:
Code:
{ZEILE} = AGGREGAT(15;6;ZEILE($C$5:$J$21)/($C$5:$J$21=$E$25);1)+1-ZEILE($C$5:$J$21)
{SPALTE} = VERGLEICH($E$25;INDEX($C$5:$J$21;AGGREGAT(15;6;ZEILE($C$5:$J$21)/($C$5:$J$21=$E$25);1)+1-ZEILE($C$5:$J$21););0)

Viele Grüße Ludwig
Tja, wenn du am Anfang erwähnt hättest dass es mehrere Treffer geben kann dann ich hätte ich dir auch die entsprechende Lösung gegeben.
Hallo shift-del,

daran zweifle ich nicht. Die von mir formulierte Erkenntnis bringt hoffnungsvoller Weise zum Ausdruck, dass ich(!) hier gedanklich zu kurz gesprungen war . Idea
Viele Grüße Ludwig