(23.05.2020, 19:08)LuckyJoe schrieb: [ -> ]Hi,
du kannst die aufrufende Schaltfläche ja verändern, damit sie "auffällt", hier ein paar Beispiele (angehängt an dein vorhandenes Makro):
Du musst die Schaltfläche natürlich danach wieder zurücksetzen. Noch besser geht es natürlich mit ActiveX-Schaltflächen, da dürften die Eigenschaften noch einfacher zu ändern sein.
Das ist schonmal gut ich hänge jetzt mal meine datei dran damit man sieht was ich vorhab
in der lasche chipliste und rechner werden diverse faktoren ausgewählt wie Kurs, Pin Loch wetter usw
und die buttons die gewählt sind hätte ich gerne farblich bis ein anderer gewählt wird
wenn das besser geht mit active x dann komm ich nicht drum rum alles zu ändern die schrift in rot z.b. wie im bsp würde jedoch schon reichen
nicht lachen ich bin vba anfänger falls ich es sehr umständlich gelöst habe
[
attachment=31912]
Hallo,
erst einmal: Lass Dir keinen Floh ins Ohr setzen von wegen ActiveX-Schaltflächen sind besser und so ...
Nicht im Tabellenblatt, schon gar nicht bei der Menge.
Ich habe die Schaltflächennamen so geändert, dass man mit den Schaltflächen auch vernünftig arbeiten kann.
Zudem ist allen ein und dasselbe Makro zugewiesen (ButtonKlick hab ich es getauft):
Option Explicit
Sub ButtonKlick()
Dim oButton As Button
Dim oWs As Worksheet
Dim strCaller As String
Dim strGruppe As String
Set oWs = Tabelle4
strCaller = Application.Caller
strGruppe = Left(strCaller, InStr(1, strCaller, " ") - 1)
For Each oButton In oWs.Buttons
With oButton
If Left(.Name, Len(strGruppe)) = strGruppe Then
If .Name = strCaller Then
.Font.ColorIndex = 3
Else
.Font.ColorIndex = -4105
End If
End If
End With
Next oButton
Select Case strGruppe
Case "Button_Kurs"
oWs.Cells(13, 6).Value = oWs.Buttons(strCaller).Caption
Case "Button_Schlaeger"
oWs.Cells(13, 1).Value = oWs.Buttons(strCaller).Caption
Case "Button_Pin"
oWs.Cells(13, 4).Value = Mid(oWs.Buttons(strCaller).Caption, 4)
Case "Button_Loch"
oWs.Cells(13, 5).Value = Mid(oWs.Buttons(strCaller).Caption, 2)
Case "Button_Temp"
oWs.Cells(13, 3).Value = Left(oWs.Buttons(strCaller).Caption, 2)
Case "Button_Wetter"
oWs.Cells(13, 2).Value = oWs.Buttons(strCaller).Caption
End Select
End Sub
Gruß Uwe
klasse das hätt ich nie hinbekommen vielen vielen dank
ich versuche mir das jetzt mal aufzudröseln wie das funktioniert echt top
@Uwe: wow ... immer wieder faszinierend