Hi,
könnt ihr mir sagen warum die Formel in der angehängten Datei nicht funktionieren?
Ich versuche die Anzahl der Werte mit "nl" in C:C und 8 oder 9 oder 10 in D: D herauszufinden.
Array: =SUMME((C3:C6="nl")*(D3: D6={"7"."8"."9"."10"}))
Formel =SUMMENPRODUKT((C3:C6="nl")*((D3: D6="8")+(D3: D6="9")+(D3: D6="10")))
Danke!
Hallo,
suchst du evtl. diese Formel?
=SUMMENPRODUKT((C3:C6="X")*(D3:D6={8.9.10}))
bzw. als Matrixformel
=SUMME((C3:C6="nl")*(D3:D6={7.8.9.10}))
Danke für deine schnelle Antwort, ich verstehe aber nicht was du meinst. Das ist doch die gleiche Formel? Bei mir gibt die Formel nur eine 0 als Wert.
EDIT: achja, ich sehe nun meinen Fehler. Warum funktioniert aber die =SUMMENPRODUKT((C3:C6="nl")*((D3: D6="8")+(D3: D6="9")+(D3: D6="10"))) Funktion nicht?
Danke!
Hallo,
auch die funktioniert wenn du die Anführungszeichen weglässt:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D |
2 | 0 | | | |
3 | 2 | | nl | 8 |
4 | | | de | 6 |
5 | | | es | 9 |
6 | | | nl | 10 |
7 | | | | |
8 | | | | |
9 | 0 | | | |
10 | 2 | | | |
11 | 2 | | | |
Zelle | Formel |
A2 | {=SUMME((C3:C6="nl")*(D3:D6={"7"."8"."9"."10"}))} |
A3 | {=SUMME((C3:C6="nl")*(D3:D6={7.8.9.10}))} |
A9 | =SUMMENPRODUKT((C3:C6="nl")*((D3:D6="8")+(D3:D6="9")+(D3:D6="10"))) |
A10 | =SUMMENPRODUKT((C3:C6="nl")*(D3:D6={8.9.10})) |
A11 | =SUMMENPRODUKT((C3:C6="nl")*((D3:D6=8)+(D3:D6=9)+(D3:D6=10))) |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hi!
Der Vollständigkeit halber die Variante mit Zählenwenns.
Vorteil: schluckt problemlos ganze Spalten:
Formeln der Tabelle |
Zelle | Formel | E3 | =ZÄHLENWENNS(C:C;"nl";D:D;">=8";D:D;"<=10") |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Ralf