Hallöchen,
ich möchte mit Bordmitteln, also ohne vba, aus einer Spalte mit Werten UND Leerzellen automatisch nur die Werte fortlaufend in eine andere Spalte übernehmen.
Also die Inhalte in Spalte A in Zeile 1, 2, 3, 5, 7, 10 in Spalte B in Zeile 1-6
Danke schon einmal vorab für Hilfe ???
Opa Oli
Hi Oli,
mit einer (ausblendbaren) Hilfsspalte:
Arbeitsblatt mit dem Namen 'Tabelle3' |
| A | B | C |
1 | abc | abc | 1 |
2 | def | def | 2 |
3 | ghi | ghi | 3 |
4 | | jkl | |
5 | jkl | mno | 5 |
6 | | pqr | |
7 | mno | | 7 |
8 | | | |
9 | | | |
10 | pqr | | 10 |
Zelle | Formel |
B1 | =INDEX(A:A;WENN(ISTFEHLER(KKLEINSTE($C$1:$C$10;ZEILE(A1)));"";KKLEINSTE($C$1:$C$10;ZEILE(A1)))) |
C1 | =WENN(A1<>"";ZEILE();"") |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Das funktioniert prima. Danke.
Wenn man es vor sich hat: da hätte man auch selbst darauf kommen können.
Schönen Abend noch und gute Gesundheit !
Opa Oli
... oder ohne Hilfsspalte:
Arbeitsblatt mit dem Namen 'Tabelle2' |
| A | B |
1 | abc | abc |
2 | def | def |
3 | ghi | ghi |
4 | | jkl |
5 | jkl | mno |
6 | | pqr |
7 | mno | |
8 | | |
9 | | |
10 | pqr | |
Zelle | Formel |
B1 | =WENNFEHLER(INDEX($A$1:$A$10;AGGREGAT(15;6;ZEILE($A$1:$A$10)/($A$1:$A$10<>"");ZEILE(A1)));"") |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Gruß
Fred
(29.04.2020, 22:12)Fred11 schrieb: [ -> ]... oder ohne Hilfsspalte:
...
Gruß
Fred
Das wird beimTE nicht funktionieren...
Angenommen, Opi abonniert Excel:
B1: =FILTER(A:A;A:A<>"")