Clever-Excel-Forum

Hallo Leute

Test

	A	B	C	D	E	F
1	2014
2		Mi	Do	Fr	Sa	So
3	Januar	01	02	03	04	05
4	Urlaub
5	Krank
6	Schicht	N	N	N	N	N
7	Übertrag	-	#NV	#NV	#NV	#NV

Formeln der Tabelle

Zelle Formel A1 =Jan!B1 B2 =WOCHENTAG(B3) C2 =WOCHENTAG(C3) D2 =WOCHENTAG(D3) E2 =WOCHENTAG(E3) F2 =WOCHENTAG(F3) B3 =DATUM($A$1;1;1) C3 =B3+1 D3 =C3+1 E3 =D3+1 F3 =E3+1 B7 =WENN(ODER(WOCHENTAG(B3)=7;WOCHENTAG(B3)=1;VERGLEICH(B3;$A$11:$A$25;0));"-";B6) C7 =WENN(ODER(WOCHENTAG(C3)=7;WOCHENTAG(C3)=1;VERGLEICH(C3;$A$11:$A$25;0));"-";C6) D7 =WENN(ODER(WOCHENTAG(D3)=7;WOCHENTAG(D3)=1;VERGLEICH(D3;$A$11:$A$25;0));"-";D6) E7 =WENN(ODER(WOCHENTAG(E3)=7;WOCHENTAG(E3)=1;VERGLEICH(E3;$A$11:$A$25;0));"-";E6) F7 =WENN(ODER(WOCHENTAG(F3)=7;WOCHENTAG(F3)=1;VERGLEICH(F3;$A$11:$A$25;0));"-";F6)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

hier möchte ich in Zeile 7 ein "-" ausgeben wenn das Datum in Zeile 3
entweder auf einen Feiertag oder aufs Wochenende fällt ansonsten
das Schichtkürzel aus Zeile 6
die Feiertage stehen im selben Arbeitsblatt in A11:A25
hab auch schon mit ISTNV(VERGLEICH.... versucht doch da hab ich
grad irgendwie ne Hirnblockade :@
würde mich über eine Lösung freuen

MfG Tom

Hallo,

probier es mal mit folgender Formel:

=WENN(ODER(ZÄHLENWENN($A11:$A25;B3)=1;WOCHENTAG(B3;2)>5);"-";B6)

Hi Tom,

anhand deines Tabellenausschnittes kann ich leider noch nicht entnehmen, was du genau berechnet haben möchtest. In diesem Fall wäre eine Mustertabelle etwas hilfreicher. Bitte lade eine solche hoch - am Ende des Antwortformulars siehts du Attachments/Neues Attachment.

(21.04.2014, 12:49)WillWissen schrieb: [ -> ]anhand deines Tabellenausschnittes kann ich leider noch nicht entnehmen, was du genau berechnet haben möchtest. In diesem Fall wäre eine Mustertabelle etwas hilfreicher. Bitte lade eine solche hoch - am Ende des Antwortformulars siehts du Attachments/Neues Attachment.

er will in Zeile 7

• ein "-" stehen haben, wenn der Tag ein WE oder Feiertag ist,
  
• wenn es ein Werktag ist, will er das Zeichen (den Buchstaben) aus Zeile 6.
  

Hallo Peter

danke das funktioniert bestens

@Günter
danke für dein Interesse an meinem Anliegen
die Idee ist, dass wenn der Tag in Zeile 3 ein Wochenend- oder Feiertag ist,
dass dann in der Zeile 7 ein minus erscheint ansonsten der Buchstabe in Zeile 6
der dann entweder ein N für Normalschicht, ein F für Frühschicht oder ein S für Spätschicht ist
aber mit Peters Formel haut es schon bestens hin deswegen sehe ich das Thema
für mich als erledigt an

hi, ich würde das ähnlich wie Peter machen..:

Arbeitsblatt mit dem Namen 'Test'
	A	B	C	D	E	F
1	2014
2		Mi	Do	Fr	Sa	So
3	Januar	01	02	03	04	05
4	Urlaub
5	Krank
6	Schicht	N	N	N	N	N
7	Übertrag	-	#NV	#NV	#NV	#NV
8		-	N	N	-	-
9
10
11	01. Jan
12
13

Zelle	Format	Wert
B8	0;-0;"-"	0

Zelle	Formel
A1	=Jan!B1
B2	=B3
B3	=(A3&-A1)+0
C3	=B3+1
B7	=WENN(ODER(WOCHENTAG(B3)=7;WOCHENTAG(B3)=1;VERGLEICH(B3;$A$11:$A$25;0));"-";B6)
B8	=WENN(ODER(ZÄHLENWENN($A11:$A25;B3);REST(B3;7)<2);0;B6)

Hallo Jörg

danke auch dir, funktioniert ebenfalls hervorragend

MfG Tom

Hallo Tom,

oder auch Formel in B7:

=WENN(UND(ISTNV(VERGLEICH(B3;$A11:$A25;0));WOCHENTAG(B3;2)<6);B6;"-")

Gruß Uwe

Hallo Uwe

auch deine Formel haut bestens hin
nun hab ich die Qual der Wahl :16:
MfG Tom

(21.04.2014, 13:21)Crazy Tom schrieb: [ -> ]Hallo Uwe

auch deine Formel haut bestens hin
nun hab ich die Qual der Wahl :16:
MfG Tom

hi Tom, wenn du deine XL-version in deine beiträge schreibst z.b. in der signatur... kann dir in zukunft sicher noch punktueller geholfen werde...