Clever-Excel-Forum

Hallo Forum,

ich möchte aus meiner Datenbank bestehend aus Baustelle (Spalte A) und Datum des Arbeitseinsatzes (Spalte B) das erste und letzte Datum der jeweiligen Baustelle auswerten.

[attachment=30749]


für das letzte Datum habe ich die Formel: =AGGREGAT(14;6;B2:B26*(A2:A26=D2);1) (Spalte F) verwendet. Wenn ich nun die gleiche beim ersten Datum anwende bloß mit "15" also: =AGGREGAT(15;6;B2:B26*(A2:A26=D2);1) (Spalte E) eingebe, dann gibt er mir 0 als Wert zurück, das ich nicht nachvollziehen kann.

Ich bitte um Hilfe! Ich benutze Excel 2010

[attachment=30748]

Moin

Mache aus dem * ein /.

Moin!
Für Deine ältere Version mal eine Lösung mit Matrixformeln:

	A	B	C	D	E	F
1				Baustelle	erster	letzter
2	Baustelle	Datum		A	02.01.2019	08.05.2019
3	A	08.05.2019
4	B	07.03.2019
5	A	02.01.2019
6	B	07.03.2019
7	C	04.01.2019
8	D	05.01.2019
9	E	07.03.2019
10	A	08.05.2019
11	A	07.05.2019
12	A	08.02.2019
13	B	08.01.2019
14	D	08.02.2019
15	D	09.02.2019
16	B	08.03.2019
17	B	09.04.2019

Zelle	Formel
E2	{=MIN(WENN(A3:A17=D2;B3:B17))}
F2	{=MAX(WENN(A3:A17=D2;B3:B17))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Ich würde das aber (ganz ohne Formeln) per Pivot-Table lösen:

[attachment=30750]

Gruß Ralf

vielen Dank für Eure schnelle Hilfe!!!

Problem gelöst! :D

Hallo... ohne AGGREGAT() und ohne CSE-Formeln... einfach ..:

Arbeitsblatt mit dem Namen 'Leistungszeitraum (2)'
	D	E	F
1	Baustelle	erster Arbeitseinsatz	letzter Arbeitseinsatz
2	A	02.01.2019	08.05.2019

Zelle	Format	Wert
E2	TT.MM.JJJJ	02.01.2019
F2	TT.MM.JJJJ	08.05.2019

Zelle	Formel
E2	=DBMIN(A2:B17;2;D1:D2)
F2	=DBMAX(A2:B17;2;D1:D2)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Moin Jörg!
Daran hatte ich auch gedacht, es aber schnell wieder verworfen.
Begründung:
Die DB-Funktionen eignen sich gut dazu, ein Kriterium auszuwerten (starrer Kriterienbereich).
In der Regel wird man aber auch wissen wollen, was auf den anderen Baustellen los war.

Daher bleibe ich dabei, dass hier eine Pivot-Auswertung (die ja auch blitzschnell erstellt werden kann) das Mittel der Wahl sein dürfte.

Ab Excel 2019 gäbe es ja auch =MAXWENNS()
In Excel 365 böte sich zusätzlich =MAX(FILTER(…)) an.

Gruß Ralf