Clever-Excel-Forum

Normale Version: Excel vba Spalten umkopieren
Du siehst gerade eine vereinfachte Darstellung unserer Inhalte. Normale Ansicht mit richtiger Formatierung.
Hallo zusammen,

habe leider schon wieder eine Frage an Euch und hoffe auf Hilfe.

Ich möchte im ersten Schritt in einem Workbook aus einer Tabelle Werte aus einer Spalte (die ganze Spalte) in eine andere Tabelle in der gleichen Datei kopieren.

Mit diesem Code habe ich es versucht - es kommt aber eine Fehlermeldung und ich komme nicht drauf wo das Problem liegt.
Es kommt immer der Fehler Laufzeitfehler 40036 - Anwendungs- oder objektdefinierter Fehler.

Code:
Sub SpaltenKopieren()
  Dim Spalte As Integer
  Dim ZielSpalte As Integer
 
  dayOffset = 2
  strZeile = 5
  Spalte = 16
 
  With ActiveSheet
     
      'Aus Datum den Tag ermitteln + Offset für Zielspalte
      datTag = Left(Range("L10"), 2) + dayOffset
      Sheet2 = Format(Range("L10"), "MMMM")        'hier soll der Monat herausgelesen werden.
     
      ZielSpalte = datTag
     
      lRow = Cells(Rows.Count, 4).End(xlUp).Row
      Range("D1:D" & lRow).SpecialCells(xlCellTypeVisible).Copy _
        Destination:=Sheets(Sheet2).Range(Cells(strZeile, ZielSpalte), Cells(strZeile, ZielSpalte))
       
  End With
End Sub

Was mache ich da falsch?

Und weitergehend, wie müsste der Code aussehen wenn ich die kopierte Spalte in eine andere Datei auf ein bestimmtes Tabellenblatt kopieren möchte?

Vielleicht habt Ihr mir ja eine Lösung für beide Fragen.
Hallo

so??
Code:
Sub SpaltenKopieren()
  Dim Spalte As Integer
  Dim ZielSpalte As Integer
  Dim dayOffset As Integer, strZeile As Integer, datTag As Integer, sheet2 As Worksheet, lrow As Long
  Dim WB As Workbook
 
  Set WB = Workbooks("Mappe2.xlsx") 'Beispiel. Muss geöffnet sein
 
  dayOffset = 2
  strZeile = 5
  Spalte = 16

  With ActiveSheet
    
      'Aus Datum den Tag ermitteln + Offset für Zielspalte
      datTag = Left(Range("L10"), 2) + dayOffset
      Set sheet2 = WB.Sheets(Format(Range("L10"), "MMMM"))        'hier soll der Monat herausgelesen werden.
    
      ZielSpalte = datTag
    
      lrow = Cells(Rows.Count, 4).End(xlUp).Row
      .Range("D1:D" & lrow).SpecialCells(xlCellTypeVisible).Copy _
        Destination:=sheet2.Cells(strZeile, ZielSpalte)
  End With
End Sub


LG UweD
Hallo Uwe,

danke für die Hilfe und den Hinweis.

Funktioniert prima!