Clever-Excel-Forum

Hallo zusammen,

habe ein kleines Problem, mit den folgenden VBA Code, er wurde mit den Recorder aufgezeichnet.

Wenn ich den Code in der ( Vorlage - Neu ) starte kann ich eine Datei öffnen und die Daten werden Kopiert, nun kann es aber sein das die Datei  " Vorlage - Neu "  einen andern Namen hat.
Wie müsste ich den Code ab ändern das der Dateiname Variabel ist?
Im Voraus schon mal vielen Dank.



Sub datenimportneu()
'

'
öffnen_pfad = Application.GetOpenFilename
Workbooks.Open (öffnen_pfad)
Sheets("Januar").Select
    Range("H3:I34").Select
    Application.CutCopyMode = False
    Selection.Copy
    Windows("Vorlage - Neu.xlsm").Activate
    Sheets("Januar").Select
     Range("H3:I34").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Workbooks.Open(öffnen_pfad).Activate
    Sheets("Januar").Select
    Range("O3:X34").Select
    Application.CutCopyMode = False
    Selection.Copy
    Windows("Vorlage - Neu.xlsm").Activate
    Sheets("Januar").Select
    Range("O3:X3").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Workbooks.Open(öffnen_pfad).Activate
    ActiveWindow.Close
End Sub



Viele Grüße
Achim

Hallo Achim,

Sub datenimportneu()

öffnen_pfad = Application.GetOpenFilename

If Not CVar(öffnen_pfad) = False Then

  With Workbooks.Open(öffnen_pfad)

    ThisWorkbook.Sheets("Januar").Range("H3:I34").Value = .Sheets("Januar").Range("H3:I34").Value

    ThisWorkbook.Sheets("Januar").Range("O3:X34").Value = .Sheets("Januar").Range("O3:X34").Value

    .Close False

  End With

End If

End Sub

Gruß Uwe

Hallo Uwe,

Dankeschön, funktioniert genau so wie ich es wollte.
Der Code schaut übersichtlicher aus als meiner.
Bin auch gerade dabei mich damit zu befassen.

Viele Grüße
Achim