Clever-Excel-Forum

Hallo liebes Forum,

die Umgestaltung meiner angehängten Übersicht [attachment=29417] trägt den Fehler im Detail...aber Schritt für Schritt geht es voran auf dem richtigen Weg.

In der Gesamtübersicht habe ich Spalte K, jetzt in Abhängigkeit der Eintragungen in P:AA, einen Text anzeigen lassen von 0/12 - 12/12 je nachdem für wie viele Monate mir Daten vorliegen. In der Zelle B4 ist die Summe der Kunden aufgeführt, die in den letzten beiden Monaten Zahlen geschickt haben.

Im alten System war Spalte K händisch mit "ja" oder "nein" ausgefüllt und ich habe in B4 die Summe der "ja" anzeigen lassen. In der Gesamtübersicht hat der Wechsel zum neuen System einwandfrei funktioniert!
Im Reiter Detail-Übersicht Zeile 41 soll das Pendant zur Zelle B4 aus der Gesamtübersicht stehen, immer an einen Namen gekoppelt. Bisher habe ich das über =SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("Gesamtübersicht!K"&ZEILE(Gesamtübersicht!9:94)))*(Gesamtübersicht!K9:K94="ja")*(Gesamtübersicht!H9:H94="Name2")) ermitteltsiehe Zelle E41 oder H41. Es gibt nun aber kein "ja" mehr zu zählen.
Wie kann ich die Summe der Kunden anzeigen lassen, die in den letzten beiden Monaten (Bezugsdatum =Gesamtübersicht H1) ihre Zahlen gesendet haben und einem bestimmten Namen zugeordnet sind???

Ich habe schon ähnliche Probleme zum Summenprodukt gefunden, aber die Lösungen nicht übernehmen können. Meine Formel zur bedingten Formatierung der Spalte K habe ich auch nicht anwenden können :(

Hallo,

dann macht der rot-markierte Teil der Formel ja keinen Sinn mehr: =SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("Gesamtübersicht!K"&ZEILE(Gesamtübersicht!9:94)))*(Gesamtübersicht!K9:K94="ja")*(Gesamtübersicht!H9:H94="Name2"))

Hallo Klaus-Dieter,

genau so ist! Welches Kriterium kann ich stattdessen dort einsetzen, damit der korrekte Bezug zum Datum hergestellt wird? Die ZÄHLENWENN-Formel aus der bedingten Formatierung bringt es ja auf den Punkt -> Ist die Zelle in der Spalte K gelb oder grün formatiert soll sie gezählt werden.

Hallöchen,

sollen die farbigen Zellen gezählt werden oder die Werte aus November und Dezember?

letzteres z.B. im Prinzip so:
=SUMMENPRODUKT((H9:H94="name")*(Z9:Z94))+SUMMENPRODUKT((H9:H94="name")*(AA9:AA94))

Hallöchen schauan,

die farbigen Zellen wären meine "Notlösung" gewesen. Es geht eben nicht fix um November und Dezember, sondern jeweils die beiden Vormonate. Im März ist das also Januar und Februar, etc. etc. der Datumsbezug steht oben in H1.
Die bedingte Formatierung ist so eingestellt, dass der Vormonat die Spalte K grün färbt und den Vorvormonat gelb. D.h. mit den Formeln aus der bedingten Formatierung könnte ich auch alle "gelben" und "grünen" Zellen in K zählen, die in einer Zeile mit "Name" oder "Name2", ... stehen. Ich hab nur keine Idee wie?!

Hallo,

ich erkenne in deiner Datei kein Datum.

Hallo Klaus-Dieter,

entschuldige ich war etwas ungenau! In der Gesamtübersicht H1 ist das Datum, welches für die bedingte Formatierung der Spalte K in der Gesamtübersicht berücksichtigt wird. Die Detailübersicht liefert ein kleines Abbild des ersten Diagramms in der Gesamtübersicht bezogen auf den jeweiligen Namen.

Hallöchen,

das wäre jetzt mal nur für den Vormonat von H1 und den davor müsstest Du addieren, also die gleiche Formel nochmal, nur beim Monat -2

Arbeitsblatt mit dem Namen 'Detail-Übersicht'
	A	B
41	Aktuelle Zusendungen	211,85

Zelle	Formel
B41	=SUMMENPRODUKT((Gesamtübersicht!H9:H94="Name")*(INDEX(Gesamtübersicht!$P$9:$AB$94;;VERGLEICH(TEXT(DATUM(JAHR(Gesamtübersicht!H1);MONAT(Gesamtübersicht!H1)-1;1);"MMM. jj");Gesamtübersicht!$P$8:$AA$8;0))))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

Schauan danke für die Mühe!

Ich steige leider nicht durch die genaue Logik hinter deiner Formel ;) Jetzt bekomme ich die Summe der Zielerreichung im Dezember korrekt angezeigt! Ich suche aber die Anzahl der Werte, in diesem Fall also "2". Wie bekommt man das jetzt noch hin?!

Hoffentlich ist jetzt nur noch eine kleine Anpassung nötig 

Hallöchen,

ja, geht einfach - siehe hinten <>0.

=SUMMENPRODUKT((Gesamtübersicht!H9:H94="Name")*(INDEX(Gesamtübersicht!$P$9:$AB$94;;VERGLEICH(TEXT(DATUM(JAHR(Gesamtübersicht!H1);MONAT(Gesamtübersicht!H1)-1;1);"MMM. jj");Gesamtübersicht!$P$8:$AA$8;0))<>0))