Clever-Excel-Forum

Hallo zusammen,

Ich bin ein VBA Anfänger und komme leider überhaupt nicht weiter.

Ich habe zwei Tabellen, Tabelle 1 und Tabelle 2. In Tabelle 1 in Spalte B stehen Artikelnummern und in Spalten C und D weitere Kriterien, diese sind aber nicht weiter relevant, da diese sich nur auf Tabelle 1 beziehen.

In Tabelle 2, Spalte A stehen ebenfalls Artikelnummern und in Spalte B steht der Preis.

Jetzt Möchte ich mittels VBA die Spalten A in beiden Tabellen abgleichen, das heißt wenn die Artikelnummer aus Tabelle 2, Spalte A in Tabelle 1 , Spalte A vorhanden ist, soll in Tabelle 1, Spalte E der wert (Preis) aus Tabelle 2, Spalte B, Eingetragen werden. Ist diese nicht vorhanden, soll die Artikelnummer einfach unten in Tabelle 1 eingefügt werden ( Artikelnummer in Spalte A und Preis in Spalte E). Die Artikelnummern, die in Tabelle 1 nicht vorhanden sind und unten eingefügt werden sollen, haben keinen Eintrag in Spalten C und D, deshalb sollte an der Stelle in beiden spalten eine 0 stehen.

Ich hoffe ich habe es halbwegs verständlich erklären können.
Gibt es einen möglichst einfachen VBA Code mit dem das möglich wäre? Habe schon einiges probiert aber leider ohne Erfolg.

Gruß

Aidan

Hallo Aidan,

Sub PreisUebertrag()

  Dim i As Long

  Dim varZeile As Variant

  Dim oWs1 As Worksheet

  Dim oWs2 As Worksheet

  

  Set oWs1 = Worksheets("Tabelle1")

  Set oWs2 = Worksheets("Tabelle2")

  

  For i = 2 To oWs2.Cells(Rows.Count, 1).End(xlUp).Row

    varZeile = Application.Match(oWs2.Cells(i, 1).Value, oWs1.Columns(1), 0)

    If IsError(varZeile) Then

      varZeile = oWs1.Cells(Rows.Count, 1).End(xlUp).Row + 1

      oWs1.Cells(varZeile, 1).Value = oWs2.Cells(i, 1).Value

    End If

    oWs1.Cells(varZeile, 5).Value = oWs2.Cells(i, 2).Value

  Next i

End Sub

Gruß Uwe

aidan1403

Kuwer