Hallo zusammen,
ich hab für meine Auswertung bereits zwei Formeln gefunden.
Jetzt möchte ich gern beide Formeln kombinieren. Leider fällt mir keine Lösung ein, wie ich das bewerkstelligen kann. Meine versuchten Lösungen haben bisher leider nicht funktioniert
{=INDEX($G$4:$K$87;VERGLEICH($B$2&$B$3&$B$4;$H$4:$H$87&$I$4:$I$87&$J$4:$J$87;0);1)}
=INDEX($G$4:$K$87;VERGLEICH(KGRÖSSTE($K$4:$K$87;1);$K$4:$K$87;0);1)
Aus den zwei eingefügten Formeln würde ich gern die Kombi finden.
Ich füge meine Datei bei.
Vielleicht gibt es auch eine andere Lösung.
Mir ist nur wichtig, dass ich aus meiner Datenansammlung anhand der Bedingung "Geschlecht, Altersgruppe und Bogenklasse" automatisch den 1. bis 3. Platz ermitteln kann.
In meinem Beispieldatei ist bei der zweiten Anzeige das Ergebnis, dass ich leider manuell ermittelt habe, zum Vergleich eingegeben.
Gibt es eine andere Formel als die Ankettung der Wenn-Formel beim zweiten Tabelle unter Altersgruppe, die entsprechende Altersklasse zu ermitteln?
Ich hoff ihr könnt mir weiterhelfen, da ich leider schon mit meinem Latein am Ende bin...
Gruß Wolfi2019
Hi Wolfi,
du suchst so etwas?
| Arbeitsblatt mit dem Namen 'Auswerung' |
| A | B | C |
| 20 | Altersgruppe | Senior | |
| 21 | Geschlecht | männlich | |
| 22 | Bogenart | BHR | |
| 23 | | Punktzahl | Name |
| 24 | 1. Platz | 640 | Muster1 |
| 25 | 2. Platz | 490 | Muster31 |
| 26 | 3. Platz | 430 | Muster43 |
| Zelle | Formel |
| B24 | =INDEX(K:K;AGGREGAT(15;6;ZEILE($K$3:$K$86)/($H$3:$K$86=$B$20)/($I$3:$I$86=$B$21)/($J$3:$J$86=$B$22);ZEILE(A1))) |
| C24 | =INDEX($G$2:$G$87;VERGLEICH(B24;$K$2:$K$87;0)) |
| B25 | =INDEX(K:K;AGGREGAT(15;6;ZEILE($K$3:$K$86)/($H$3:$K$86=$B$20)/($I$3:$I$86=$B$21)/($J$3:$J$86=$B$22);ZEILE(A2))) |
| C25 | =INDEX($G$2:$G$87;VERGLEICH(B25;$K$2:$K$87;0)) |
| B26 | =INDEX(K:K;AGGREGAT(15;6;ZEILE($K$3:$K$86)/($H$3:$K$86=$B$20)/($I$3:$I$86=$B$21)/($J$3:$J$86=$B$22);ZEILE(A3))) |
| C26 | =INDEX($G$2:$G$87;VERGLEICH(B26;$K$2:$K$87;0)) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Danke für die schnelle Antwort
ich probiere es gleich mal aus.
Hi,
ich wahr so schlau und hab deine Formel kopiert und eingefügt, leider hat mir dann das Ergebnis #ZAHL! angezeigt.
Ich hab versuch, die Formel zu ändern. Siehe nachfolgende Formel, in der Spalte C hat es funktioniert, aber leider B noch nicht ganz. Es zeigt mir ein falsches Ergebnis an. Das hab ich auch hier eingefügt.
1. Platz
B 24 =INDEX(K:K;AGGREGAT(14;6;ZEILE($K$3:$K$86)*($H$3:$H$86=$B$20)*($I$3:$I$86=$B$21)*($J$3:$J$86=$B$22);ZEILE(A1)))
2. Platz
B 25 =INDEX(K:K;AGGREGAT(14;6;ZEILE($K$3:$K$86)*($H$3:$H$86=$B$20)*($I$3:$I$86=$B$21)*($J$3:$J$86=$B$22);ZEILE(A2)))
3. Platz
B 26 =INDEX(K:K;AGGREGAT(14;6;ZEILE($K$3:$K$86)*($H$3:$H$86=$B$20)*($I$3:$I$86=$B$21)*($J$3:$J$86=$B$22);ZEILE(A3)))
1. Platz
B24 = 540
C24 = Muster21
2. Platz
B25 = 535
C25 = Muster22
3. Platz
B26 = 530
C26 = Muster23
Wo genau da der Wurm drin ist, steig ich leider nicht durch. Ich bin noch dabei, deine Formel zu studieren.
Danke schonmal für deine Hilfe.
Mir ist aufgefallen, dass bei dem eingefühten Ergebnis die falsche Bogenklasse von der Formel ausgewählt war.
Hi Wolfi,
Ich habe zwar einen kleinen Patzer in meiner Formel, der aber
nicht zu einem falschen Ergebnis führt:
Es muss korrekt
heißen.
Du hast aber die Formel völlig falsch geändert:
1. den falschen Parameter (14 statt 15) und
2. multiplizierst du statt zu dividieren
Moin Wolfi,
damit du die Formel besser verstehst, habe ich dir mal ein kleineres Beispiel (Liste auf Langbogen und nur auf Senioren und Schülern - männlich - beschränkt. Zusätzlich habe ich die Formel für die Namensspalte geändert, damit auch bei Punktegleichheit alle Namen aufgeführt werden. Falls weniger Teilnehmer als die drei Plätze in einer Klasse gelistet sind, schreibt die Formel eine 0 in die Zelle. Falls sie stört, kannst du sie mit der benutzerdefinierten Formatierung
ausblenden.
Die Liste muss zwingend nach Punktzahl abwärts sortiert sein.
Zum Verständnis der Arbeitsweise schau mal in das Menü Formel / Formelüberwachung und hier in Formelauswertung.
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G | H | I | J |
| 1 | Altersgruppe | Senior | | | | Name | Altersgruppe | Geschlecht | Bogenart | Punktzahl |
| 2 | Geschlecht | männlich | | | | Klaus | Senior | männlich | LB | 650 |
| 3 | Bogenart | LB | | | | Heiko | Senior | männlich | LB | 640 |
| 4 | | Punktzahl | Name | | | Volker | Senior | männlich | LB | 640 |
| 5 | 1. Platz | 650 | Klaus | | | Fritz | Schüler | männlich | LB | 630 |
| 6 | 2. Platz | 640 | Volker | | | Ralf | Schüler | männlich | LB | 620 |
| 7 | 3. Platz | 640 | Heiko | | | | | | | |
| Zelle | Formel |
| B5 | =WENNFEHLER(INDEX(J:J;AGGREGAT(15;6;ZEILE($J$2:$J$10)/($G$2:$G$10=$B$1)/($H$2:$H$10=$B$2)/($I$2:$I$10=$B$3);ZEILE(A1)));"") |
| C5 | =WENNFEHLER(INDEX(F:F;AGGREGAT(15;6;ZEILE($J$2:$J$10)/($J$2:$J$10=B5);ZEILE(A1)));INDEX(F:F;AGGREGAT(15;6;ZEILE($J$2:$J$10)/($J$2:$J$10=B5);ZEILE($A$1)))) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Hey
Lieben lieben Danke
es hat funktioniert und es kommt das rauch, was ich brauch
Nochmals vielen lieben DANK :79: :79: :79: :79: