Hallo.
Ich habe in einer "Kundenmappe" bei jedem Kunden eine Angebots- und eine Rechungs-Nr. bestehend aus "A" oder "R" - zwei Jahreszahlen und drei fortlaufenden Zahlen
z.B. A19-005. Nun möchte ich die "höchte" Zahl anzeigen lassen, dass ich nicht immer suchen muss was nun die nächste Nr. ist.
Die Reihenfolge ist - logischerweise - wie folgt: A18-001, A18-002, A18-002 ... A19-001, A19-002, A19-003 ... A20-001.
Wie mache ich dies am "besten"?
Danke im Voraus,
Gruß, ichhalt033
Moin,
Extrahieren in einer Hilfsspalte deine Ziffern und sortiere nachHS.
Moin!
Geht auch ohne Hilfsspalte und ohne Sortierung:
| A | B |
1 | Nummer | 8 |
2 | A21-005 | |
3 | A19-008 | |
4 | A19-002 | |
Zelle | Formel |
B1 | {=MAX(WENN(LINKS(A2:A4;3)="A19";--RECHTS(A2:A4;3)))} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Gruß Ralf
Hallöchen,
wenn R und A unterschiedliche Nummernkreise beinhalten - also es z.B. R19-001 und A19-001 für einen Kunden geben kann und das für die Aufgabe relevant ist, dann vielleicht so:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G |
1 | Willi | A19-001 | A | 19001 | Willi | R | R18-002 |
2 | Bald | A19-002 | A | 19002 | | | |
3 | Willi | R18-001 | R | 18001 | | | |
4 | Bald | A19-004 | A | 19004 | | | |
5 | Willi | A19-005 | A | 19005 | | | |
6 | Bald | A19-006 | A | 19006 | | | |
7 | Willi | R18-002 | R | 18002 | | | |
8 | Bald | A19-008 | A | 19008 | | | |
9 | Willi | A19-009 | A | 19009 | | | |
10 | Bald | A19-010 | A | 19010 | | | |
11 | Willi | A19-011 | A | 19011 | | | |
12 | Bald | A19-012 | A | 19012 | | | |
Zelle | Formel |
C1 | =LINKS(B1;1) |
D1 | =WECHSELN(RECHTS(B1;6);"-";"") |
G1 | {=F1&TEXT(WENN(ZEILE(A1)>ZÄHLENWENNS(A:A;E$1;C:C;$F$1);"";INDEX(D:D;KGRÖSSTE(WENN(E$1&F$1=A$1:A$10&C$1:C$10;ZEILE($1:$10));ZEILE(A1))));"00-000")} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Der Kundenname ist doch imo irrelevant, André.
Hallöchen,
das war dann schon die Antwort auf eine vielleicht zusätzliche Frage
In Anlehnung an Deinen Vorschlag würde ich es dann so machen:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G |
1 | Willi | A19-001 | A | 19001 | Willi | A | A19-009 |
2 | Bald | A19-002 | A | 19002 | nur nach | R | R18-004 |
3 | Willi | R18-004 | R | 18004 | | | |
4 | Bald | A19-004 | A | 19004 | | | |
5 | Willi | A19-005 | A | 19005 | | | |
6 | Bald | A19-006 | A | 19006 | | | |
7 | Willi | R18-002 | R | 18002 | | | |
8 | Bald | A19-008 | A | 19008 | | | |
9 | Willi | A19-009 | A | 19009 | | | |
10 | Bald | R18-003 | R | 18003 | | | |
Zelle | Formel |
G2 | {=F2&TEXT(MAX(WENN(LINKS(B1:B10;1)=F2;--WECHSELN(RECHTS(B1:B10;6);"-";"")));"00-000")} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
(07.09.2019, 07:35)RPP63 schrieb: [ -> ]Moin!
Geht auch ohne Hilfsspalte und ohne Sortierung
Gruß Ralf
Moin, und das geht auch ohne CSE-Abschluss Stichwort: INDEX...
In "meinem" Excel braucht es ohnehin kein CSE mehr ...
Das erkennt das Programm von ganz allein.
Hi André,
Arbeitsblatt mit dem Namen 'Blatt1' |
| A | B |
1 | Nummer | 8 |
2 | A21-005 | 8 |
3 | A19-008 | |
4 | A19-002 | |
Zelle | Formel |
B1 | {=MAX(WENN(LINKS(A2:A4;3)="A19";--RECHTS(A2:A4;3)))} |
B2 | =MAX(INDEX((--RECHTS(A2:A4;3));LINKS(A2:A4;3)="A19")) |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
(07.09.2019, 14:11)RPP63 schrieb: [ -> ]In "meinem" Excel braucht es ohnehin kein CSE mehr ...
Das erkennt das Programm von ganz allein. ;-)
Hi Ralf, wem hilft dies Antwort..? Du hattest eine CSE-Formel gepostet... Und dass du die Insider Version hast ist schön für dich. Wirklich. Aber wie viele der user haben die auch? Bzw. können das in der Praxis (einer Firma o.ä.) anwenden...? Ich halte das für posen... Ich kann mich irren. Schönen Tag noch.