Code:
=WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$B$1);Erfolgsspiegel!$G5*Prov!$B$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$C$1);Erfolgsspiegel!$G5*Prov!$C$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$D$1);Erfolgsspiegel!$G5*Prov!$D$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$E$1);Erfolgsspiegel!$G5*Prov!$E$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$F$1);Erfolgsspiegel!$G5*Prov!$F$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$G$1);Erfolgsspiegel!$G5*Prov!$G$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$H$1);Erfolgsspiegel!$G5*Prov!$H$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$I$1);Erfolgsspiegel!$G5*Prov!$I$2/1000;
WENN(UND(Erfolgsspiegel!$D5=Prov!$A$2;Erfolgsspiegel!$H5=Prov!$J$1);Erfolgsspiegel!$G5*Prov!$J$2/1000;
Hallo Leute,
ich bräuchte eine riesige WENN-Formel mit mehr als 64 Verschachtelungsebene.
Es wären mind. 9 Blocks á 9 Zeilen.
Kann man den Code in einer Formel zusammenfassen ?
Danke euch für eine schnelle Antwort.
Hola,
lad doch bitte eine Beispieldatei hoch, dann muss das niemand nachbauen.
Gruß,
steve1da
Kann damit leider nicht dienen, da es sich um eine sehr große Exceldatei handelt die schon mit 4000 Zeilen gefüllt ist.
Hallo,
das sollte mit einer Verweis Tabelle zu regeln sein
alle Wenn Bedingungen in der Tab abbilden und die Provision daneben
Da ich nicht wirklich zu einem Ergebnis komme, habe ich die Datei mal aus Minimum reduziert.
Hoffe Ihr blickt da durch.
Auf der "Reg1" hat Spalte "A" und "C" jeweils 9 Auswahlmöglichkeiten.
Jenachdem was ausgewählt wurde, ergibt das eine Zahl aus der Matrix.
Die soll mit der in Spalte "B" Multipliziert werden.
Hola,
Code:
=B5*INDEX(Bezugstabelle!$A$1:$J$10;VERGLEICH($A5;Bezugstabelle!$A$1:$A$10;0);VERGLEICH($C5;Bezugstabelle!$A$1:$J$1;0))/1000
Gruß,
steve1da
Das ja mal sehr geil. Funktioniert, DANKE !
Geht das auch irgendwie, wenn die Spalten "A" und "C" nicht ausgefüllt sind, dass in der Formelzeile nicht "#NV" steht sondern nichts ?
Hola,
=wennfehler(Formel;"")
Gruß,
steve1da
Mach von der Bezugstabelle eine intelligente Tabelle.
Dann reicht:
PHP-Code:
=B6/1000*INDEX(Table1;MATCH(A6;Table1[Column1];0);MATCH(C6;Table1[#Headers];0))