Hallo zusammen
Ich habe folgendes dabei:
Eine Datei (siehe im Anhang) von Auslagerungsdaten aus einer automatisiertes Lagersysteme im Excel exportiert.
Ich möchte nun auswerten können:
1. für eine Tour wie viele Kisten ausgelagert worden - jede Zeile ist dementsprechend eine Kiste. - ACHTUNG!: Es kann sein, dass eine Tour nur "halb" fertig war und den Rest erst später ausgelagert worden.
2. Vorstellung nach dem Auswertung: siehe im Datei (31.07.2019) nebendran in Form einer Tabelle, möglichst automatisiert, mit Knopfdrucksfunktion wäre am besten.
Kann jemand mit dem etwas anfangen? Braucht ihr noch etwas?
Danke für eure Hilfe.
Hallo Daniel,
für die Kistenanzahl und den Auslagerungsstart helfen diese beiden Formeln:
| Arbeitsblatt mit dem Namen '31.07.19' |
| L | M |
| 11 | 36 | 08:18:33 |
| Zelle | Formel |
| L11 | =ZÄHLENWENN(G:G;K4) |
| M11 | =INDEX(B:B;VERGLEICH(K4;G:G;0)) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Für den Rest musst du erst einmal deine Zeiten in Zahlenform bringen; bislang sind sie Text. Danach wäre eventuell VERGLEICH() in Verbindung mit MAX() denkbar. Die Berechnung der Dauer ist dann eine einfache Subtraktion.
Hallo Daniel,
hab' dir mal die Hilfsspalte für die Umwandlung deiner Textzeiten in echte Zeiten eingefügt und die einzelnen Positionen berechnet. Die Hilfsspalte kannst du einfach ausblenden.
| Arbeitsblatt mit dem Namen '31.07.19' |
| A | B | C | H | I | J | K | L | M | N | O |
| 1 | Datum | Zeit | HS-Zeit | Tour | Bezeichnung | | | | | | |
| 2 | 31.07.2019 | 08:18:33 | 8:18:33 | 701 | Migrolino_Suhr | | | | Zeit in Minuten |
| 3 | 31.07.2019 | 08:19:34 | 8:19:34 | 701 | Migrolino_Suhr | | Tour | Kistenanzahl | Auslagerungsstart | Auslagerungsende | Auslagerungsdauer |
| 4 | 31.07.2019 | 08:19:37 | 8:19:37 | 701 | Migrolino_Suhr | | 701 | 7 | 08:18 | 08:21 | 3 Min |
| 5 | 31.07.2019 | 08:19:45 | 8:19:45 | 701 | Migrolino_Suhr | | 702 | 3 | 08:21 | 08:21 | 1 Min |
| 6 | 31.07.2019 | 08:19:58 | 8:19:58 | 701 | Migrolino_Suhr | | 703 | 6 | 08:22 | 08:22 | 1 Min |
| 7 | 31.07.2019 | 08:21:46 | 8:21:46 | 701 | Migrolino_Suhr | | | | | | |
| 8 | 31.07.2019 | 08:21:49 | 8:21:49 | 701 | Migrolino_Suhr | | | | | | |
| 9 | 31.07.2019 | 08:21:52 | 8:21:52 | 702 | Migrolino_Suhr | | | | | | |
| 10 | 31.07.2019 | 08:21:54 | 8:21:54 | 702 | Migrolino_Suhr | | | | | | |
| 11 | 31.07.2019 | 08:21:57 | 8:21:57 | 702 | Migrolino_Suhr | | | | | | |
| 12 | 31.07.2019 | 08:22:00 | 8:22:00 | 703 | Migrolino_Suhr | | | | | | |
| 13 | 31.07.2019 | 08:22:05 | 8:22:05 | 703 | Migrolino_Suhr | | | | | | |
| 14 | 31.07.2019 | 08:22:08 | 8:22:08 | 703 | Migrolino_Suhr | | | | | | |
| 15 | 31.07.2019 | 08:22:11 | 8:22:11 | 703 | Migrolino_Suhr | | | | | | |
| 16 | 31.07.2019 | 08:22:13 | 8:22:13 | 703 | Migrolino_Suhr | | | | | | |
| 17 | 31.07.2019 | 08:22:16 | 8:22:16 | 703 | Migrolino_Suhr | | | | | | |
| 18 | | | | | | | | | | | |
| Zelle | Format | Wert |
| O4 | m" Min" | 2,26851851851856E-03 |
| Zelle | Formel |
| C2 | =ZEITWERT(B2) |
| L4 | =ZÄHLENWENN(H:H;K4) |
| M4 | =INDEX(C:C;VERGLEICH(K4;H:H;0)) |
| N4 | =MAXWENNS(C:C;H:H;K4) |
| O4 | =WENN(N4-M4<1/24/60;1/24/60;N4-M4) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg |
Hi,
hab gerade gesehen, dass du XL2010 angegeben hast. Diese Version kennt noch kein MAXWENNS(). Stattdessen kannst du mit
Code:
=INDEX(C:C;AGGREGAT(14;6;ZEILE($H$2:$H$17)/($H$2:$H$17=K4);1))
dein Auslagerungsende holen.
Hallo, wenn die Zeiten aufsteigend sortiert sind, geht das doch einfacher mit...
PHP-Code:
=VERWEIS(42;1/($G$2:$G$1423=K4);$C$2:$C$1423)
Ich würde das vermutlich mit Power Query lösen, aber das geht hier in der Version wohl nicht...