Hallo ihr Lieben,
ich habe folgendes Problem:
In Spalte A stehen Zahlenwerte (unsortiert)
In Spalte B stehen (zugehörig zu dem jeweiligen Eintrag aus Spalte A) zusätzliche Zahlenwerte
nun will ich von Spalte A die "N" kleinsten Werte bestimmen, deren Zusatzwert aus Spalte B größer als ein Mindestwert "X" ist.
Anbei eine Sample Tabelle dazu... (ich verwende Excel 2013)
Liebe Grüße,
Markus
Moin
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
15 | 1 | 0,29 | Banane |
16 | 2 | 0,49 | Nudeln |
17 | 3 | 0,59 | Reis |
Zelle | Formel |
B15 | =AGGREGAT(15;6;$B$2:$B$7/($C$2:$C$7>=$G$2);A15) |
C15 | =INDEX($A$2:$A$7;VERGLEICH(B15;$B$2:$B$7;0)) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Edit:
Falls es in Spalte B Duplikate gibt.
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
15 | 1 | 0,29 | Banane |
16 | 2 | 0,49 | Nudeln |
17 | 3 | 0,59 | Reis |
Zelle | Formel |
B15 | =AGGREGAT(15;6;($B$2:$B$7+ZEILE($B$2:$B$7)%%%)/($C$2:$C$7>=$G$2);A15) |
C15 | {=INDEX($A$2:$A$7;VERGLEICH(B15;$B$2:$B$7+ZEILE($B$2:$B$7)%%%;0))} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
B15:B17 sind auf zwei Nachkommastellen formatiert.
Hi
so bekommst du die Zeilen Nummer.
Code:
=REST(AGGREGAT(15;6;($B$2:$B$7*100+ZEILE($B$2:$B$7)%)/($C$2:$C$7>=$G$2);ZEILE(A1));1)*100
Gruß Elex
@shift-del Was wenn es den selben Preis dann auch mit weniger Volumen gibt.
Edit: Ok haste schon gemerkt.
Hallo
ich hätte vermutlich eine zusätzliche Spalte angelegt und es in der gleichen Liste gelöst
Gruß Holger
Hi,
ich hatte auch schon ein wenig getüftelt. Mein Ergebnbis: Spalte B aufwärts sortieren, Hilfsspalte anlegen und ohne CSE arbeiten:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | H |
1 | WARE | Preis | Volumen | hs | |
2 | Reis | 0,19 | 3100 | x | 0,19 |
3 | Banane | 0,29 | 5200 | x | 0,29 |
4 | Apfel | 0,29 | 2400 | x | 0,29 |
5 | Nudeln | 0,49 | 2300 | x | |
6 | Eis | 1,2 | 3900 | x | |
7 | Schokolade | 1,99 | 1300 | | |
Zelle | Formel |
H2 | =INDEX($B$1:$B$7;AGGREGAT(15;6;ZEILE($D$2:$D$7)/($D$2:$D$7="x");ZEILE(A1))) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
:100: Klasse
ihr seid die Besten!
Vielen Dank!