Hallo Community,
ich suche Hilfe bei folgendem Problem:
Eine Tabelle soll so aufgebaut sein, dass in einer Zeile Jahreszahlen stehen, in den Spalten darunter nach Monaten untergliederte Werte, schließlich die Jahressummen. Für das laufende, noch nicht abgeschlossene Jahr liegen nur Werte für eine bestimmte Anzahl von Monaten vor (z.B. Januar bis März) und die bis dahin aufgelaufene Summe. Diese Summe dynamisch zu ermitteln, ist mit Hilfe der Formel {=SUMME(WENN.......))} unproblematisch.
Wie ermittle ich die im gleichen Zeitraum eines abgeschlossenen Jahres entstandene Summe ?
Im Voraus vielen Dank für eine Lösung.
Hardbopper
Hi,
Zitat:Wie ermittle ich die im gleichen Zeitraum eines abgeschlossenen Jahres entstandene Summe ?
vermutlich auch über SUMMEWENN?
Stelle doch bitte einen Tabellenausschnitt oder eine Mustertabelle vor. Dann kann dir auch gezielt geholfen werden.
Hallo Günter,
hier die gewünschte Mustertabelle.
Hardbopper
[
attachment=1833]
Hallo,
für die Spalte F z.B. so:
Code:
=SUMME(F9:INDEX(F$9:F$20;ANZAHL($H$9:$H$20)))
Wenn das für mehrere Jahre gelten soll:
Code:
=SUMME(F9:INDEX(F$9:F$20;ANZAHL(INDEX($F$9:$I$21;;VERGLEICH(JAHR(HEUTE());$F$8:$I$8;0)))))
(31.03.2015, 11:36)BoskoBiati schrieb: [ -> ]Hallo,
für die Spalte F z.B. so:
Code:
=SUMME(F9:INDEX(F$9:F$20;ANZAHL($H$9:$H$20)))
Wenn das für mehrere Jahre gelten soll:
Code:
=SUMME(F9:INDEX(F$9:F$20;ANZAHL(INDEX($F$9:$I$21;;VERGLEICH(JAHR(HEUTE());$F$8:$I$8;0)))))
Hallo, oder mit SUMMENPRODUKT()...
=SUMMENPRODUKT(($H$9:$H$20<>"")*1;F9:F20)
und analog
=SUMMENPRODUKT((INDEX($F$9:$I$20;;VERGLEICH(JAHR(HEUTE());$F$8:$I$8;0))<>"")*1;F9:F20)
Hallo Jörg,
ok, aber warum eine Matrixfunktion verwenden, wenn es auch ohne geht.
(31.03.2015, 12:31)BoskoBiati schrieb: [ -> ]Hallo Jörg,
ok, aber warum eine Matrixfunktion verwenden, wenn es auch ohne geht.
Hallo Edgar, ich hätte es ja auch mit INDEX() gemacht, da warst du einfach schneller, so gibt's halt 'ne Alternative... ... zudem eine ("wesentlich" :18: ) kürzere.
Hallo zusammen,
ich kann leider die Datei nicht runterladen (mobil), deswegen die Frage, ist die Aufgabe nicht mit einer Pivottabelle lösbar?
(31.03.2015, 13:25)atilla schrieb: [ -> ]Hallo zusammen,
ich kann leider die Datei nicht runterladen (mobil), deswegen die Frage, ist die Aufgabe nicht mit einer Pivottabelle lösbar?
Hi Atilla, der TabellenAusschnitt sieht so aus..:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | D | E | F | G | H | I |
| 8 | | | 2013 | 2014 | 2015 | 2016 |
| 9 | Januar | | 464,80 | 385,86 | 405,59 | |
| 10 | Februar | | 454,44 | 319,74 | 410,53 | |
| 11 | März | | 406,58 | 258,55 | 332,57 | |
| 12 | April | | 306,91 | 157,89 | | |
| 13 | Mai | | 191,45 | 153,95 | | |
| 14 | Juni | | 73,03 | 88,82 | | |
| 15 | Juli | | 27,63 | 109,54 | | |
| 16 | August | | 46,38 | 82,89 | | |
| 17 | September | | 98,68 | 91,78 | | |
| 18 | Oktober | | 200,33 | 161,84 | | |
| 19 | November | | 341,45 | 272,37 | | |
| 20 | Dezember | | 453,95 | 384,87 | | |
| 21 | | | | | | |
| 22 | Summen | | 3065,63 | 2468,09 | 1148,68 | 0,00 |
| Zelle | Formel |
| F22 | =SUMME(F9:F20) |
| G22 | =SUMME(G9:G20) |
| H22 | =SUMME(H9:H20) |
| I22 | =SUMME(I9:I20) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo Jörg,
danke für die Info.
Die dargestellten Zahlen kommen haben ihren Bezug sicher n einer Datentabelle.
Man müsste diese sehen, um entscheiden zu können, ob eine Pivottabelle möglich ist.