Clever-Excel-Forum

Hallo zusammen,

ich möchte folgenden Sachverhalt durch eine Wenn Formel Lösen:

nach 1-jähriger Betriebszugehörigkeit vom 19. bis 35. Lebensjahr 10,10 €, ab dem 36. Lebensjahr 10,41 €,
nach 2-jähriger Betriebszugehörigkeit vom 19. bis 35. Lebensjahr 11,63 €, ab dem 36. Lebensjahr 11,94 €,
nach 3-jähriger Betriebszugehörigkeit vom 19. bis 35. Lebensjahr 13,17 €, ab dem 36. Lebensjahr 13,48 €

Mein Versuch:

=WENN(D8=0;0;WENN(D8=1;WENN(F8<=35;10,1;WENN(F8>=35;10,46;WENN(D8=2;WENN(F8<=35;11,63;WENN(F8>=35;11,94;)))))))

Sobald D8 (die Betriebszugehörigkeit ) von mir auf zwei gesetzt wird kommt FALSCH
F8 sagt das Alter aus.

Kann mir jemand weiter helfen  :22:

LG

Yves

Hi,

hol dir die Daten mit einem SVERWEIS():

Vorschlag entfernt - hat nicht mit allen Kombinationen funktioniert

Hallo,

würde auch mathematisch gehen und wäre kürzer, wenn es den Rundungsfehler im 2. Jahr nicht geben würde!

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H
7	BZ		Alter
8	2		36		11,94

Zelle	Formel
H8	=10,1+(F8>=36)*0,31+(D8=2)*1,53++(D8>=3)*1,54

Hi,

habe gerade festgestellt, dass mein vorheriger Vorschlag nicht richtig funktioniert. Hier ein funktionsfähiger:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F
1	Alter	Zugeh.	Betrag		Zugeh.	Betrag
2	22	3	13,70 €		1	10,10 €
3					2	11,63 €
4					3	13,70 €
5					1	10,41 €
6					2	11,94 €
7					3	13,48 €

Zelle	Formel
C2	=WENN(A2<19;"#NV";WENN(A2>=36;SVERWEIS(B2;$E$5:$F$7;2;0);SVERWEIS(B2;$E$2:$F$4;2;0)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Etwas kürzer:


Tabelle1

	A	B	C	D	E	F	G	H
1	Alter	Zugeh.	Betrag		Alter	1 Jahr	2 Jahre	3 Jahre
2	22	3	13,17		19	10,1	11,63	13,17
3					36	10,41	11,94	13,48

verwendete Formeln
Zelle	Formel	Bereich	N/A
C2	=SVERWEIS(A2;E2:H3;B2+1)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 25.14 einschl. 64 Bit

Moin,

schöne Lösung für das Anwendungsbeispiel. Ich fürchte aber, dass die Zugehörigkeiten 1, 2 und 3 Jahre reine Beispielzahlen sind.

Im Gegensatz zu silex 

=10,1+(F8>=36)*0,31+(D8=2)*1,53++(D8>=3)*1,54

geht auch nur jeweils einmalige D8-Parameternennung (die DM-statt-RUNDEN-Variante funktioniert bei meinem xl365 noch):

=--DM(MIN(D8;3)*1,535+(F8>35)*31%+8,56)
=RUNDEN(MIN(D8;3)*1,535+(F8>35)*31%+8,56;2)

Funktionieren tut das über den nicht gefragten Funktionswert im Nullpunkt. 

Für D8<1 Jahr oder F8<19 Jahre haben wir DÜ (= dann sind auch nur die Eingaben möglich, die in den Bedingungen überhaupt zugelassen werden!). Ganzzahligkeit Prämisse.

Oder TE spezifiziert für andere Eingaben Null (plausible Annahme):

=RUNDEN(MIN(D8;3)*1,535+(F8>35)*31%+8,56;2)*(F8>18)*(D8>0)

Hi, 

=(D8>0)*(10,10+min(2;D8-1)*1,54+(D8>2)%+(F8>35)*0,31)

Hallo Bosko,

das RUNDEN erfolgte nicht grundlos.

Hi,

mag sein, aber bei mir liegt der Fehler woanders, es muss 1,53 heißen:



Meine hat aber Deiner etwas voraus:

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	F	G	H	I	J	K
5			Bosko	LCohen
6	0	39	-   €	8,87 €	-   €	-   €	-   €
7	0	34	-   €	8,56 €	-   €	-   €	-   €
8	1	34	10,10 €	10,10 €	10,10 €	10,10 €	10,10 €
9	2	34	11,63 €	11,63 €	11,63 €	11,63 €	11,63 €
10	3	34	13,17 €	13,17 €	13,17 €	13,17 €	13,17 €
11	1	39	10,41 €	10,41 €	10,41 €	10,41 €	10,41 €
12	2	39	11,94 €	11,94 €	11,94 €	11,94 €	11,94 €
13	3	39	13,48 €	13,48 €	13,48 €	13,48 €	13,48 €

Zelle	Formel
G6	=(D6>0)*(10,1+MIN(2;D6-1)*1,53+(D6>2)%+(F6>35)*0,31)
H6	=RUNDEN(MIN(D6;3)*1,535+(F6>35)*31%+8,56;2)
I6	=WENN(D6=0;0;WENN(D6=1;WENN(F6<=35;10,1;10,41);WENN(D6=2;WENN(F6<=35;11,63;11,94);WENN(F6<=35;13,17;13,48))))
J6	=WENN(D6=0;0;WENN(D6=1;10,1;WENN(D6=2;11,63;13,17))+(F6>35)*0,31)
K6	=WENN(D6=0;0;WAHL(MIN(D6;3);10,1;11,63;13,17)+(F6>35)*0,31)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg