Hallo zusammen,
ich bin mit Excel leider nicht sehr gut und brauche daher dringend eure Hilfe! Ich habe folgendes Problem:
Ich habe in beigefügter Excel Datei auf dem 2. Tabellen-Blatt einen F-Systemkatalog. Ein F-System besteht immer aus einer Kombination von E-Systemen.
Die Eingaben in Spalte B im ersten Tabellenblatt sind per Drop-Down Menü auf die Eingabe der E-Systeme aus dem F-Systemkatalog beschränkt. In jeder Zeile kann nur ein E-System eingegeben werden.
Die Funktion die ich gerne hätte wäre folgende: Sobald eine der E-System Kombinationen in den Zellen der Spalte B auftaucht, soll es in Zelle A2 den Namen des F-Systems eintragen.
Funktioniert das ohne weiteres?
Für eure Hilfe bin ich euch sehr dankbar.
Liebe Grüße
Hallo Highlander90,
man kann das F-System berechnen für einen Eintragungswert z.B. in B2.
Dafür z.B. folgende Formel in Deiner verbundenen Zelle A2:A4
Code:
=WENNFEHLER(VERWEIS(9;1/(ZEILE('F-Systemkatalog'!A1:A99)<=VERGLEICH(B2;'F-Systemkatalog'!B2:B99;0))/
('F-Systemkatalog'!A1:A99<>"");'F-Systemkatalog'!A:A);"")
Für die Zellen in B3 und B4 würde ich vorschlagen diese in Abhängigkeit dee für B2 ermittelten F-Systems in A2 zu ermitteln. Denn bei Deiner angedachten Lösung könnten aus Versehen verschiedene "E-Systemwerte in B2:B4 gewählt werden, was dann zu keiner eindeutigen "F-System"-Wert führt.
[Nachtrag]
es gibt es in Deinem Systemkatalog auch "F-Systeme mit 4 anstelle nur 3 "E-System"-Daten. Du müsstest also dann schon A2:A5 verbinden und B5 bleibt eben bei den mit nur drei Werten frei.
Hallo neopa,
vielen Dank für deine Antwort.
Ich glaube ich habe mich in meiner anfänglichen Beschreibung falsch ausgedrückt oder verstehe deine Ausführung falsch.
Ein F-System besteht immer aus 3 (oder wie du richtig angemerkt hast, aus 4) E-Systemen. Diese 3 oder 4 E-Systemen müssen immer zusammen auftreten um ein F-System zu bilden.
Als Beispiel: die E-Systeme ES_A_GR1.01_1, ES_S_GR1.01_1 und ES_A_GR1.01_2 bilden nur zusammen das F-System FS_FU_GR1.01.
Die Angabe eines einzelnen E-Systems bildet kein F-System. Ein E-System kann aber Bestandteil von verschiedenen F-Systemen sein.
Daher ist die Zuordnung eines E-Systems zu nur einem F-System nicht möglich. Nur die spezifische Kombination der E-Systeme wie sie im 2. Tabellenblatt hinterlegt ist bringt ein F-System hervor.
Ist es also möglich, dass in Zelle A2 der Name des jeweiligen F-Systems auftaucht, sobald die passende Kombination an E-Systemen in den Zellen B2 bis B5 auftaucht?
Liebe Grüße
Hier nochmals die veränderte Beispieldatei.
Entsprechende User in die "Ignorehölle" verschoben :19:
Hier geht es weiter
Hallo Highlander90,
mich interessierte eine Formellösungsmöglichkeit. Eine solche hab ich nun mal aufbereitet. Momentan ging ich davon aus, dass im Katalog nur bis zu 98 Datensätze erfasst sind und zwar mit "3er" und "4er"-E-Systeme gemischt. Eine Anpassung auf bis ca. 1000 sollte noch vertretbar sein. Für Massendatenauswertung (tausend und mehr F-Systeme) bedarf es jedoch einer anderen Auswertungsmethode.
Um meine nachfolgende Formellösung überschaubar(er) zu halten, hab ich eine Hilfsspalte im Katalog-Tabellenblatt eingeführt und arbeite mit benannten Formeln. Diese sollte bei aktivierter Zelle B2 im Namensmanager definiert werden.
Die Hilfsspaltenformel ist bis zum Datensatzende ziehend nach unten zu kopieren. Die Hilfsspalte selbst kann anschließend ausgeblendet werden.
Die bedingten Formatierungen in der Eingabe sind lediglich zur visuellen Eingabekontrolle vorgesehen aber nicht notwendig.
Bei Rückfragen kann ich wohl frühestens morgen reagieren, weil ich gleich offline gehen muss.
| Arbeitsblatt mit dem Namen 'F-Systemkatalog' |
| A | B | C | D | E |
| 1 | F-System | E-System | | | Hilfssp. |
| 2 | F-System 1 | E-System 1 | | | |
| 3 | E-System 2 | | | |
| 4 | E-System 3 | | | |
| 5 | F-System 2 | E-System 1 | | | |
| 6 | E-System 2 | | | |
| 7 | E-System 4 | | | |
| 8 | F-System 3 | E-System 1 | | | |
| 9 | E-System 3 | | | |
| 10 | E-System 4 | | | |
| 11 | F-System 4 | E-System 1 | | | |
| 12 | E-System 4 | | | |
| 13 | E-System 6 | | | |
| 14 | F-System 5 | E-System 2 | | | 0 |
| 15 | E-System 6 | | | |
| 16 | E-System 3 | | | |
| 17 | E-System 1 | | | |
| 18 | F-System 6 | E-System 2 | | | 18 |
| 19 | E-System 6 | | | |
| 20 | E-System 4 | | | |
| 21 | E-System 1 | | | |
| 22 | F-System 7 | E-System 2 | | | |
| 23 | E-System 3 | | | |
| 24 | E-System 4 | | | |
| 25 | F-System 9 | E-System 1 | | | 0 |
| 26 | E-System 2 | | | |
| 27 | E-System 3 | | | |
| 28 | E-System 4 | | | |
| 29 | | | | | |
| Name | Bezug |
| _EingAnz | =ANZAHL2(Eingabe!$B$2:$B$5) |
| _EingZae | =SUMMENPRODUKT(ZÄHLENWENN(Eingabe!$B$2:$B$5;Eingabe!$B$2:$B$5)) |
| _ESysAusw | =SUMMENPRODUKT(ZÄHLENWENN('F-Systemkatalog'!$B1:INDEX('F-Systemkatalog'!$B:$B;WENNFEHLER(_FSysTeil+ZEILE('F-Systemkatalog'!$A1048576);_KatEnd-1));Eingabe!$B$2:Eingabe!$B$5)) |
| _FSysTeil | =VERGLEICH(1;INDEX(0+('F-Systemkatalog'!$A2:$A5>0););0) |
| _KatEnd | =VERWEIS(9;1/('F-Systemkatalog'!$B$1:$B$99<>"");ZEILE('F-Systemkatalog'!$B$2:$B$99)) |
| Zelle | Formel |
| E2 | =WENN(($A2="")+($B2="")+(WENNFEHLER(_FSysTeil+ZEILE();_KatEnd)-ZEILE()<>_EingAnz)+(_EingZae<>_EingAnz);"";ZEILE()*(_ESysAusw=_EingAnz)) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
| Arbeitsblatt mit dem Namen 'Eingabe' |
| A | B |
| 1 | F-System | E-System |
| 2 | F-System 6 | E-System 2 |
| 3 | E-System 4 |
| 4 | E-System 1 |
| 5 | E-System 6 |
| Name | Bezug |
| _FSysNr | =WENN(MAX('F-Systemkatalog'!E:E)=0;"";INDEX('F-Systemkatalog'!A:A;MAX('F-Systemkatalog'!E:E))) |
| Zelle | bedingte Formatierung... | Format |
| B2 | 1: ZÄHLENWENN(B$2:B$5;B2)>1 | abc |
| B2 | 2: (ZÄHLENWENN($B$2:$B$5;"")>1)*(B2=0) | abc |
| B3 | 1: ZÄHLENWENN(B$2:B$5;B3)>1 | abc |
| B3 | 2: (ZÄHLENWENN($B$2:$B$5;"")>1)*(B3=0) | abc |
| B4 | 1: ZÄHLENWENN(B$2:B$5;B4)>1 | abc |
| B4 | 2: (ZÄHLENWENN($B$2:$B$5;"")>1)*(B4=0) | abc |
| B5 | 1: ZÄHLENWENN(B$2:B$5;B5)>1 | abc |
| B5 | 2: (ZÄHLENWENN($B$2:$B$5;"")>1)*(B5=0) | abc |
| Zelle | Gültigkeitstyp | Operator | Wert1 | Wert2 |
| B2 | Liste | | E-System 1; E-System 2; E-System 3; E-System 4; E-System 5; E-System 6 | |
| B3 | Liste | | E-System 1; E-System 2; E-System 3; E-System 4; E-System 5; E-System 6 | |
| B4 | Liste | | E-System 1; E-System 2; E-System 3; E-System 4; E-System 5; E-System 6 | |
| B5 | Liste | | E-System 1; E-System 2; E-System 3; E-System 4; E-System 5; E-System 6 | |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |