Hallo,
ich habe 3 Spalten:
Spalte A enthält die Zahlen 1 99
Spalte B ist entweder leer oder enthält eine Zahl zwischen 1 und 99
Spalte C ist die Spalte mit der bedingten Formatierung. Die Zellen in Spalte C sollen bei einer Zahl in Spalte B in Zeile x zwischen Cx und C(Zahl in Bx) formatiert werden.
Zur Veranschaulichung habe ich ein kleines Excel mit dem Wuschergebnis erstellt. Spalte C soll über eine bedingte Formatierung gelb eingefärbt werden.
Hola,
wenn du schon mehrere Foren bemühst, verlinke bitte deine Fragen gegenseitig.
Gruß,
steve1da
Hallo F...,
1. in Zelle B23 einen Wert >22 eintragen
2. für die Zellen C2:C22 eine bedingte Formatierung mit folgender Bedingung anlegen:
Code:
=ODER(A2<=MAX($B$2:B2);A2>=MIN(B2:$B$23))
Super. Das hat funktioniert! Und sogar rückwärts!
Eine Frage habe ich noch zum Verständnis. Wenn ich in B23 keine große Zahl einsetze, wird die Formatierung bis zum Schluss gezogen. Was ist der Grund dafür?
Ich habe die Formel noch etwas angepasst und die 99 in die Min-Bedingung hineingeschrieben. Dann kann man auf die große Zahl in B23 verzichten. Entsprechend braucht man dann in Min nur bis B22 laufen.
Code:
=ODER(A2<=MAX($B$2:B2);A2>=MIN(B2:$B$22;99))
@ego
Ich brauchte das jetzt noch in einer Matrix. Die Spalte E gibt (im Beispiel E11 und E16) an, wie groß der Aufsatz ist. Die Spalte E ist nicht sortiert.
Hallo F...,
ich habs so verstanden (erste Formel), aber übersichtlicher wirds wohl wenn man zwei bedingte Formatierungen nutzt (Formel zwei und drei):
Code:
=ODER(WENNFEHLER($A2<=AGGREGAT(14;6;($B$2:$B2)/($E$2:$E2=F$1);1);FALSCH);WENNFEHLER($A2>=AGGREGAT(15;6;($B2:$B$22)/($E2:$E$22=F$1);1)/(AGGREGAT(15;6;($B2:$B$22)/($E2:$E$22=F$1);1)<>0);FALSCH))
=WENNFEHLER($A2<=AGGREGAT(14;6;($B$2:$B2)/($E$2:$E2=F$1);1);FALSCH)
=WENNFEHLER($A2>=AGGREGAT(15;6;($B2:$B$22)/($E2:$E$22=F$1);1)/(AGGREGAT(15;6;($B2:$B$22)/($E2:$E$22=F$1);1)<>0);FALSCH))
Hallo F...,
hier eine Korrektur für den zweiten Teil (in der Datei Formatierung für Zeile 4)
Code:
=ODER(WENNFEHLER($A2<=AGGREGAT(14;6;($B$2:$B2)/($E$2:$E2=F$1);1);FALSCH);WENNFEHLER($A2>=AGGREGAT(15;6;($B2:$B$22)/(($E2:$E$22=F$1)*($B2:$B$22<>""));1);FALSCH))
=WENNFEHLER($A2<=AGGREGAT(14;6;($B$2:$B2)/($E$2:$E2=F$1);1);FALSCH)
=WENNFEHLER($A2>=AGGREGAT(15;6;($B2:$B$22)/(($E2:$E$22=F$1)*($B2:$B$22<>""));1);FALSCH)
Echt spitze! Vielen Dank
Mit der Zwischentabelle kann ich leben.
Hallo F...,
die "Zwischentabelle" ist für die Formatierung nicht notwendig.
Ich habe nur die Formeln in den Zellen entwickelt, da im Fehlerfall eine Formelauswertung in Zellen möglich ist.