(11.01.2019, 14:21)Jockel schrieb: [ -> ]Hallo, bei welchen denn? Wahrscheinlich so.. Spalte C ist mit Power Query eingelesen und ausgegeben.. :
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
1 | Date | | Date |
2 | 01JAN19 | 43466 | 01.01.2019 |
3 | 15MAR18 | #WERT! | 15.03.2018 |
Zelle | Formel |
B2 | =A2*1 |
B3 | =A3*1 |
Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Anbei die Tabelle, vielleicht erkennst du so den Fehler?
Hallo, ja klar, hatte ich ja in meinem letzten Beitrag schon vermutet (kein Fehler) ... ... es handelt sich um englische Datumstexte...
P.S. Bitte keine Vollzitate
Und wie kann man dies lösen?
Hallo, das hatte ich bereits geschrieben mit Power Query. In deiner Version XL2013 - richtig? - müsste man das Add-in kostenlos bei Microsoft runterladen und installieren.
Ich würde hier auch PowerQuery verwenden.
Hier noch eine Formellösung:
=VERWEIS(9^99;WECHSELN(A2;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1)
Sehr schön, das WECHSELN im VERWEIS. Ist für mich was Neues. 9 Zeichen eingespart:
=VERWEIS(9^9;WECHSELN(A2;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"})*1)
Hallöchen,
die Formellösung funktioniert aber nur im März, weil AR im Array vorne steht. Ab dem zweiten, also AY im Mai, hab ich keinen Erfolg:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
9 | 15MAR18 | 15MRZ18 |
10 | 15MAY18 | 15MAY18 |
Zelle | Formel |
B9 | =WECHSELN(A9;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"}) |
B10 | =WECHSELN(A10;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"}) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hi,
kann ich nicht nachvollziehen:
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F |
1 | Start | Lösung onyx1985 | Steuerfuzzi | LCohen | Steuerfuzzi | LCohen |
2 | 01JAN19 | 01.01.2019 | 01.01.2019 | 01.01.2019 | 01.Jan.2019 | 01.Jan.2019 |
3 | 02FEB19 | 02.02.2019 | 02.02.2019 | 02.02.2019 | 02.Feb.2019 | 02.Feb.2019 |
4 | 03MAR19 | #WERT! | 03.03.2019 | 03.03.2019 | 03.Mrz.2019 | 03.Mrz.2019 |
5 | 04APR19 | 04.04.2019 | 04.04.2019 | 04.04.2019 | 04.Apr.2019 | 04.Apr.2019 |
6 | 05MAY19 | #WERT! | 05.05.2019 | 05.05.2019 | 05.Mai.2019 | 05.Mai.2019 |
7 | 06JUN19 | 06.06.2019 | 06.06.2019 | 06.06.2019 | 06.Jun.2019 | 06.Jun.2019 |
8 | 07JUL19 | 07.07.2019 | 07.07.2019 | 07.07.2019 | 07.Jul.2019 | 07.Jul.2019 |
9 | 08AUG19 | 08.08.2019 | 08.08.2019 | 08.08.2019 | 08.Aug.2019 | 08.Aug.2019 |
10 | 09SEP19 | 09.09.2019 | 09.09.2019 | 09.09.2019 | 09.Sep.2019 | 09.Sep.2019 |
11 | 10OCT19 | #WERT! | 10.10.2019 | 10.10.2019 | 10.Okt.2019 | 10.Okt.2019 |
12 | 11NOV19 | 11.11.2019 | 11.11.2019 | 11.11.2019 | 11.Nov.2019 | 11.Nov.2019 |
13 | 12DEC19 | #WERT! | 12.12.2019 | 12.12.2019 | 12.Dez.2019 | 12.Dez.2019 |
Zelle | Format | Wert |
B2 | TT.MM.JJJJ | 01.01.2019 |
C2 | TT.MM.JJJJ | 01.01.2019 |
D2 | TT.MM.JJJJ | 01.01.2019 |
E2 | TT.MMM.JJJJ | 01.01.2019 |
F2 | TT.MMM.JJJJ | 01.01.2019 |
Zelle | Formel |
B2 | =A2*1 |
C2 | =VERWEIS(9^99;WECHSELN(A2;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1) |
D2 | =VERWEIS(9^9;WECHSELN(A2;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"})*1) |
E2 | =VERWEIS(9^99;WECHSELN(A2;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1) |
F2 | =VERWEIS(9^9;WECHSELN(A2;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"})*1) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hallo André. So, so ..:
Welches Format haben deine Zellen..?
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
4 | 15MAR18 | 15.03.2018 | 15.03.2018 |
5 | 15MAY18 | 15.05.2018 | 15.05.2018 |
Zelle | Formel |
B4 | =VERWEIS(9^99;WECHSELN(A4;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1) |
C4 | =VERWEIS(9^9;WECHSELN(A4;{"AR";"AY";"CT";"EC"};{"RZ";"AI";"KT";"EZ"})*1) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hi Jörg,
die Zellen sind Standard formatiert. Ich hab einfach den Text 15MAR18 kopiert und eingefügt und dann den Formelteil mit Wechseln rüber kopiert. Mir gings nur darum, ob Wechslen mit Array für einen Text funktioniert. Bisher kenne ich es nur so, dass man das Schachteln muss. Siehe da:
https://www.clever-excel-forum.de/thread...#pid146406
Hätte ich in meinem Beitrag mal besser drauf hinweisen sollen :22:
Mit dem Datum und VERWEIS … klappt es, aber als reiner Text mit dem Array halt nicht - siehe C3, da müsste ja MAI stehen und nicht MAY.
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
2 | 15MAR18 | 15.03.2018 | 15MRZ18 |
3 | 15MAY18 | 15.05.2018 | 15MAY18 |
Zelle | Formel |
B2 | =VERWEIS(9^99;WECHSELN(A2;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1) |
C2 | =WECHSELN(A2;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"}) |
B3 | =VERWEIS(9^99;WECHSELN(A3;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"})*1) |
C3 | =WECHSELN(A3;{"MAR";"MAY";"OCT";"DEC"};{"MRZ";"MAI";"OKT";"DEZ"}) |
Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |