Clever-Excel-Forum

Hallo zusammen,
ich stehe aktuell vor folgender Herausforderung:

Ich möchte aus einer Tabelle 1 mit Daten in der ersten Spalte und sich wiederholenden Werten aus der 2.Spalte. z.B:

Spalte A    Spalte E

01.01.2019    Wert 1
02.01.2019    Wert 2
08.01.2019    Wert 3
04.01.2019    Wert 1
07.01.2019    Wert 1

folgendes in einer anderen Tabelle 2 ausgeben in welche der Wert in Spalte B ebenfalls auftaucht
Die Ausgabe hier erfolgt in Spalte H bzw I

Tabelle 2

Spalte B Spalte H Spalte I

Wert 1 letztes Datum Wert 1 vorletztes Datum Wert 1

Das letzte Datum des Wertes 1 --> somit der 07.01.2019 habe ich durch eine MAX Funktion in geschweiften Klammern hinbekommen:
{=MAX(('Tabelle 1`!$E$1:$E$800=Tabelle 2!B2)*'Tabelle 1'!$A1$:$A$800)}

(Dollarzeichen, damit die Funktion nach unten kopiert werden kann...)

Kann mir nun jemand sagen wie man das vorletzte Datum (hier der 04.01.2019) des Wert 1 angezeigt/ausgegeben bekommt?
ich habe hier schon alles versucht, komme mit sämtlichen Varianten von -1 aber immer nur auf den Tag vor dem Maximalwert, also hier der 06.01.2019.
Es wäre Spitze wenn jemand eine Lösung dafür hätte, denn ich bin schon gefühlt eine Ewigkeit auf der Suche nach der Lösung für dieses Problem...

DANKE

Moin

in H2:

Code:
=AGGREGAT(14;6;Tabelle1!$A$2:$A$6/(Tabelle1!$B$2:$B$6=$B2);1)

In I2:

Code:
=AGGREGAT(14;6;Tabelle1!$A$2:$A$6/(Tabelle1!$B$2:$B$6=$B2);2)

luHallo,

angenommen Deine Daten beginnen in Tabelle 1 ab z.B. Zeile 3 und "Wert 1" steht in B2 der Tabelle 2, dann mit Formel in H2:

Code:
=WENNFEHLER(AGGREGAT(14;6;Tabelle1!$A3:$A99/(Tabelle1!$B3:$B99=$B2);SPALTE(A2));"")

und diese nach I2 kopieren.

[Edit:] sorry Detlef, ich wurde abgehalten, so dass ich erst später abschloss.
[Edit2 :] außerdem sollte es richtig so :

Code:
=WENNFEHLER(AGGREGAT(14;6;Tabelle1!$A3:$A99/(Tabelle1!$E3:$E99=$B2);SPALTE(A2));"")

lauten .

Hallo, eine Formellösung... für H nach rechts und unten (oder umgekehrt) ziehbar:

PHP-Code:
=WENNFEHLER(KGRÖSSTE(INDEX(Tabelle1!$A$2:$A$6*(Tabelle1!$E$2:$E$6=$B2););SPALTE(A$1));"") 

Achtung: kein CSE-Abschluss erforderlich!!

Ich habe meinen Beitrag ergänzt.
Für nur zwei Spalten muss man nicht unbedingt den Wert für k dynamisch machen.

cracky

shift-del

neopa

Jockel

shift-del