Hallo Forum,
Ich habe in Spalte A Chargennummern (je nach dem welche BwA auch doppelt) und in Spalte B eine BwA (Bewegungsart) stehen.
nun möchte ich mir die Chargen ausgeben lassen die eine BwA E aber keine BwA A haben.
siehe Bitte Tabelle im Anhang.
Besten Dank im Voraus
omron2003
Moin,
eine Möglichkeit:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| B | C | D | E |
| 3 | Charge: | BwA | HS | Ergebnis: |
| 4 | 3001 | E | | 3002 |
| 5 | 3001 | A | | 3005 |
| 6 | 3002 | E | 6 | |
| 7 | 3003 | E | | |
| 8 | 3003 | A | | |
| 9 | 3004 | A | | |
| 10 | 3004 | E | | |
| 11 | 3005 | E | 11 | |
| 12 | 3006 | A | | |
| 13 | 3006 | E | | |
| Zelle | Formel |
| D4 | =WENN(ZÄHLENWENN($B$4:$B$14;B4)=1;ZEILE();"") |
| E4 | =WENNFEHLER(INDEX(B:B;KKLEINSTE($D$4:$D$14;ZEILE(A1)));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hilfsspalte kann bei Bedarf ausgeblendet werden.
Hallo,
hier noch eine Lösung ohne Hilfsspalte:
| B | C | D | E |
| 3 | Charge: | BwA | | Ergebnis: |
| 4 | 3001 | E | | 3002 |
| 5 | 3001 | A | | 3005 |
| 6 | 3002 | E | | |
| 7 | 3003 | E | | |
| 8 | 3003 | A | | |
| 9 | 3004 | A | | |
| 10 | 3004 | E | | |
| 11 | 3005 | E | | |
| 12 | 3006 | A | | |
| 13 | 3006 | E | | |
| Zelle | Formel |
| E4 | {=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE($B$4:$B$13)/NICHT(MMULT((MTRANS($B$4:$B$13)=$B$4:$B$13)*1;($C$4:$C$13="A")*1));ZEILE(A1)));"")} |
| Achtung, Matrixformel enthalten! |
| Die geschweiften Klammern{} werden nicht eingegeben. |
| Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Denkbar wären auch Lösungsansätze mittels Pivot-Tabelle oder PowerQuery.
(19.12.2018, 15:35)Der Steuerfuzzi schrieb: [ -> ]Hallo,
...
Denkbar wären auch Lösungsansätze mittels Pivot-Tabelle oder PowerQuery.
Hallo, ja oder jein. Ich würde schon eine PQ-Lösung vorgeschlagen haben, ABER: der TE hat eine *.xls Datei gepostet... Deswegen wackelt auch deine Formellösung...
Hi Jörg,
is zwar nur 'ne .xls; im Profil gibt der TE aber XL2013 an.
(19.12.2018, 15:42)Jockel schrieb: [ -> ]der TE hat eine *.xls Datei gepostet... Deswegen wackelt auch deine Formellösung...
Geht auch mit KKLEINSTE:
| Zelle | Formel |
| E4 | {=INDEX(B:B;KKLEINSTE(ZEILE($B$4:$B$13)/(NICHT(MMULT((MTRANS($B$4:$B$13)=$B$4:$B$13)*1;($C$4:$C$13="A")*1))+1%%%%);ZEILE(A1)))} |
| Achtung, Matrixformel enthalten! |
| Die geschweiften Klammern{} werden nicht eingegeben. |
| Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Allerdings ist hier das Abfangen des Fehlers nicht so einfach ohne WENNFEHLER!
Hallo, ich weiß. Das war von mir reiner Spekulatius... wegen der *.xls und des Benutzernamens... Nun hat der TE drei Formellösungen...