Hallo Excel-User,
ich habe ein Problem, bei dem ich nicht weiterkomme. Ich möchte gern aus den Beispielen nur den Wert vor "%" isolieren:
MON12345 maize, >99,94% --> >99,94
MON23456 maize, QC 1.2, 1% --> 1
MON98765, 10% Std. --> 10
Kann mir jemand dafür eine Formel nennen?
Danke für's Nachdenken!
Schöne Grüße
Christopher
kleine BSP Datei oder eine Erklärung wie genau die Daten in der Zelle stehen wäre sehr gut
Falls du Excel ab 2013 bzw. 2010 Professional einsetzt, wäre das MS Addin Power Query für dich die perfekte Lösung.
Alles klar, Beispiel-Datei im Anhang.
Schöne Grüße
Hi
zumindest für die drei Bsp.
____|_____________A_____________|____B___|_C|
1|MON12345 maize, >99,94% | >99,94 | |
2|MON23456 maize, QC 1.2, 1% | 1| |
3|MON98765, 10% Std. | 10| |
Code:
B1 =TEIL(A1;VERWEIS(5^5;SPALTE(A1:BZ1)/(FINDEN(" ";A1;SPALTE(A1:BZ1))<FINDEN("%";A1;1)));FINDEN("%";A1;1)-VERWEIS(5^5;SPALTE(A1:BZ1)/(FINDEN(" ";A1;SPALTE(A1:BZ1))<FINDEN("%";A1;1))))
Moin,
Elex hat in der Zeit, in der ich verschiedene Lösungsansätze ausprobiert habe, dir zwar schon eine Formellösung geschrieben. Trotzdem stelle ich meine Lösung mit einer (ausblendbaren) Hilfsspalte vor.
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D |
| 1 | Text | Wunsch | HS | Ergebnis |
| 2 | MON12345 maize, >99,94% | >99,94 | >99,94 | >99,94 |
| 3 | MON23456 maize, QC 1.2, 1% | 1 | QC 1.2, 1 | 1 |
| 4 | MON98765, 10% Std. | 10 | 10 | 10 |
| Zelle | Formel |
| C2 | =TEIL(A2;SUCHEN(",";A2;2)+1;SUCHEN("%";A2)-SUCHEN(",";A2)-1) |
| D2 | =WENNFEHLER(TEIL(C2;SUCHEN(","&" ";C2)+1;25);C2) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
B1: =WECHSELN(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));MIN(WENN(RECHTS(
GLÄTTEN(TEIL(WECHSELN(A1;" ";WIEDERHOLEN(" ";99));
SPALTE((A1:K1))*99-98;99)))="%";
SPALTE(A1:K1)))*99-98;99));"%";)
(in Versionen vor 365 wohl mit {} abzuschließen) oder
B1: =
WECHSELN(GLÄTTEN(LINKS(WECHSELN(TEIL(A1;FINDEN("#";WECHSELN(A1;" ";"#";
LÄNGE(
LINKS(A1;FINDEN("%";A1)))-
LÄNGE(WECHSELN(
LINKS(A1;FINDEN("%";A1));" ";))))+1;99);" ";WIEDERHOLEN(" ";99));99));"%";)
(ohne {})
Hallo, ich bin da ganz bei MisterBurns (Berni) ... PQ ohne Formeln (ohne Hilfsspalte[n]) ...
Vielen Dank für die sehr guten und sehr schnellen Hilfestellungen!
Ich habe alle Vorschläge ausprobiert.
zu Elex: Funktioniert bei all meinen Einträgen!
zu WillWissen: Funktioniert bei fast allen Einträgen, aber im Fall von "Bs-99 Maize STD 0,08%" erscheint in der Zielspalte D "08" , statt "0,08". Das liegt wohl daran, dass in meinem Datensatz scheinbar auch Einträge sind, die kein zusätzliches Komma (abgesehen vom Prozent-Wert) enthalten.
zu Case: Funktioniert bei all meinen Einträgen! Allerdings sind Makros bei mir schwierig anzuwenden.
zu LCohen: Funktioniert bei all meinen Einträgen!
Ich werde die Funktion von Elex nutzen, könnte aber auch eine andere nehmen.
Ich danke euch für die Unterstützung!
Schöne Grüße
Christopher