Clever-Excel-Forum

Hallo zusammen,

nach tagelangem, erfolglosem Suchen hoffe ich, hier Hilfe zu finden!

Mein Problem:

Ich möchte mit Excel die Anzahl der Stunden außerhalb einer vorgegeben Zeitspanne berechnen. Konkret gesagt geht es um die Anrechnung von Reisezeiten, die nicht in die reguläre Arbeitszeit gefallen sind.

Beispiel:

Arbeitszeit: 08:00 - 17:00 Uhr

Reise A: 06:00 - 10:00 Uhr
Reise B: 15:00 - 22:00 Uhr
Reise C: 12:00 - 16:00 Uhr

Für A wären also 2 Stunden auszuweisen (06:00 - 08:00), für B 5 Stunden (17:00 - 22:00 Uhr) und C=0 Stunden, weil komplett innerhalb der Arbeitszeit.

(Alternativ ginge dann auch umgekehrt die Anzahl innerhalb der Zeitspanne 17:01 - 07:59, Hauptsache ich komme auf das richtige Ergebnis) 

Egal was ich probiere, ich bekomme es einfach nicht hin. Google konnte mir leider auch nicht helfen..

Hat jemand eine Idee? :)

Danke vorab.


PS: Falls es dazu schon Beiträge gibt, sorry!

Hola,

http://excelformeln.de/formeln.html?welcher=9

In A1 schreibst du deine 17:00 Uhr, in B1 deine 08:00 Uhr. Dann kannst du deine Zeiten errechnen indem du die von-bis-Zeiten in A2 und B2 schreibst.

Gruß,
steve1da

Hallo,
ich würde mich ja gerne damit beschäftigen, aber:
Wenn der Arbeitgeber mich auf eine Dienstreise schickt und die nicht mit der Arbeitszeit übereinstimmen, dann steht mir dennoch Arbeitszeit (0,5) zu. Die Aufgabe ist von daher verkehrt.

Lg
Marcus

C3: =REST(B3-A3;1)-
MAX(;MIN(B3+(B3<A3);17/24)-MAX(A3;0+8/24))-
MAX(;MIN(B3+(B3<A3);41/24)-MAX(A3;1+8/24))

Danke Danke, hat sofort geklappt!

@ Marcus: sorry, was genau meinst du mit "dir steht dennoch Arbeitszeit zu"?

(26.11.2018, 18:18)Scara schrieb: [ -> ]Danke Danke, hat sofort geklappt!

@ Marcus: sorry, was genau meinst du mit "dir steht dennoch Arbeitszeit zu"?

Er meint wohl es muss auch die Zeit ausserhalb der reellen Arbeitszeit bezahlt werden.

Aber wenn man es genau so macht wie steve1da geschrieben hat, errechnet es auch exakt die Zeit ausserhalb der eigentlichen Arbeitszeit!!

jack :19:

Hallo Jack, die Nr. 9 ist

• länger
  
• kaum verständlich
  
• unsymmetrisch aufgebaut
  

als/ggü meine(r) Formel.

(26.11.2018, 21:47)LCohen schrieb: [ -> ]Hallo Jack, die Nr. 9 ist

• länger
  
• kaum verständlich
  
• unsymmetrisch aufgebaut
  

als/ggü meine(r) Formel.

Hi,

Ja schon, aber sorry, mit deiner Formel komm ich nicht zurecht, denn ich habe ja 4 Zellen mit Einträgen:
"Reisebeginn + Reiseende" und "realer Arbeitszeitbeginn + reales Arbeitszeitende"!

Deine Formel rechnet aber nur mit 2 Zellen und das funktioniert (bei mir) nicht und ich kapiers auch nicht.  

jack :17:

Hallo Jack,

(27.11.2018, 00:08)happy-jack schrieb: [ -> ]Ja schon, aber sorry, mit deiner Formel komm ich nicht zurecht, denn ich habe ja 4 Zellen mit Einträgen:
"Reisebeginn + Reiseende" und "realer Arbeitszeitbeginn + reales Arbeitszeitende"!

dann so:

	A	B	C	D	E
1	Beginn	Ende	Regelbeginn	Regelende	Überhang
2	06:00	10:00	08:00	17:00	02:00
3	15:00	22:00	08:00	17:00	05:00
4	12:00	16:00	08:00	17:00	00:00

Formeln der Tabelle

Zelle Formel E2 =REST(B2-A2;1)- MAX(;MIN(B2+(B2<A2);D2)-MAX(A2;0+C2))- MAX(;MIN(B2+(B2<A2);1+D2)-MAX(A2;1+C2)) E3 =REST(B3-A3;1)- MAX(;MIN(B3+(B3<A3);D3)-MAX(A3;0+C3))- MAX(;MIN(B3+(B3<A3);1+D3)-MAX(A3;1+C3)) E4 =REST(B4-A4;1)- MAX(;MIN(B4+(B4<A4);D4)-MAX(A4;0+C4))- MAX(;MIN(B4+(B4<A4);1+D4)-MAX(A4;1+C4))

Gruß Uwe

Danke, Kuwer,

mir gefallen Deine Wörter "Regelbeginn" und "Regelende"! :)

=REST(B2-A2;1)-
MAX(;MIN(B2+(B2<A2);D2)-MAX(A2;0+C2))-
MAX(;MIN(B2+(B2<A2);1+D2)-MAX(A2;1+C2))

lässt sich symmetrisch schreiben, damit Jack die Formel versteht:

=REST(B2-A2;1)-
MAX(;MIN(B2+(B2<A2);0+D2)-MAX(A2;0+C2))-
MAX(;MIN(B2+(B2<A2);1+D2)-MAX(A2;1+C2))

Es gibt auch Fälle ("Regelzeitraum overnight" mit Kuwers Wortwahl), wo noch eine (dritte MAX-) Zeile mit "2+..." nötig ist. Einen solchen haben wir hier nicht.

Die Nr. 9 habe ich übrigens bis heute nicht verstanden.

Wer Probleme hat, ein formatiertes Kleinerzeichen hier bei CEF zu schreiben (wird mit nachfolgenden Zeichen oft verschluckt), kann es durch & l t ; (ohne Leerzeichen) ersetzen (maskieren). Gleiches gilt  für & g t ;, wobei das Größerzeichen m.E. nicht verschluckt wird.