Schönen Guten Tag Liebes Excel Forum,
derzeit erstelle ich eine übergroße Mitarbeiterplanung und bin auf der Suche nach verschiedenen Formeln.
Zunächst möchte ich gerne wissen wie ich nur zwei bzw. 4 Buchstaben aus folgender Beispielkette ausbringe
A1: FS.SL.100
A2: FS.SL.110
A3: SS.SL.100
B1: Formel = Zählenwenn(//in Spalte A in der Mitte SL steht und am Anfang FS. Info: in Spalte A ist das Format immer nur "AA.ZZ.999"
ich freue mich auf eure Unterstützung
Hi,
ich würde das mit Hilfsspalten lösen (einfach ausblenden, dann stören sie nicht):
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E |
| 1 | Ident | HS Vorkommen links | HS Vorkommen Mitte | FS | SL |
| 2 | FS.SL.100 | FS | SL | 2 | 3 |
| 3 | FS.SL.110 | FS | SL | | |
| 4 | SS.SL.100 | SS | SL | | |
| Zelle | Formel |
| B2 | =LINKS(A2;2) |
| C2 | =TEIL(A2;4;2) |
| D2 | =ZÄHLENWENN($B$2:$B$4;$D$1) |
| E2 | =ZÄHLENWENN($C$2:$C$4;$E$1) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hey WillWissen,
danke für die schnelle Antwort.
Ich finde deine Idee sehr gut. Das konntest du jetzt nicht wissen aber ich hab in jeder Spalte ein Datum. Ich mach mal eine Hilfstabelle
in Zelle B3 möchte ich, dass ein Abgleich mit dem Datum gemacht wird und dann bei Frühschicht in SL (B3) die Anzahl der FS.SL aus Spalte D eingefügt werden
Hallo,
deine jetzige Problembeschreibung hat ja gleich gar nichts mit deinem Eröffnungsbeitrag zu tun.
Vllt. solltest du eine kleine Beispieltabelle, die vom Aufbau her deinem Original entspricht, hochladen. So geht's:
https://www.clever-excel-forum.de/thread-326.html
Hallo,
ich dachte ich hätte bereits die Arbeitsmappe hochgeladen.
anbei..
Hallo,
Tabelle1 | A | B | C | D | E | F | G |
| 1 | Datum: | 01.10.2018 | | | | | |
| 2 | Frühschicht (FS) | | Spätschicht (SS) | | | | |
| 3 | SL | 1 | SL | 1 | | | |
| 4 | BF | 5 | BF | 5 | | | |
| 5 | QS | 1 | QS | 0 | | | |
| 6 | DS | 1 | DS | 0 | | | |
| 7 | | | | | | | |
| 8 | Name | Kompetenz | in/out | 01.10.2018 | 02.10.2018 | 03.10.2018 | 04.10.2018 |
| 9 | A | SL | in | FS.SL.001 | | | |
| 10 | B | SL | in | SS.SL.001 | | | |
| 11 | C | Bandführung | in | FS.BF.100 | | | |
| 12 | D | Bandführung | in | FS.BF.200 | | | |
| 13 | A | Bandführung | in | FS.BF.300 | | | |
| 14 | B | Bandführung | in | FS.BF.400 | | | |
| 15 | C | Bandführung | in | FS.BF.500 | | | |
| 16 | D | | out | | | | |
| 17 | A | Bandführung | in | SS.BF.100 | | | |
| 18 | B | Bandführung | in | SS.BF.200 | | | |
| 19 | C | Bandführung | in | SS.BF.300 | | | |
| 20 | D | Bandführung | in | SS.BF.400 | | | |
| 21 | A | Bandführung | in | SS.BF.500 | | | |
| 22 | B | QS | in | FS.QS.001 | | | |
| 23 | C | Dispo | in | FS.DS.001 | | | |
| Formeln der Tabelle |
| Zelle | Formel | | B3 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"FS."&$A3&".???") | | D3 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"SS."&$A3&".???") | | B4 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"FS."&$A4&".???") | | D4 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"SS."&$A4&".???") | | B5 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"FS."&$A5&".???") | | D5 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"SS."&$A5&".???") | | B6 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"FS."&$A6&".???") | | D6 | =ZÄHLENWENN(BEREICH.VERSCHIEBEN($D$9:$D$23;0;TAG($B$1)-1);"SS."&$A6&".???") |
|
Gruß Uwe
Eine Frage noch dazu. Soll nur für das Datum im B1 gezählt werden (Tageszusammenfassung) oder gleich für alle Tage zusammengefasst?
Vorschlag für erstere Variante siehe Anlage.
Voraussetzung der Zeitraum ab D8 beginnt immer am 1. eines Monats (wg. Bereich.Verschieben). Müsste ansonsten nochmal angepasst werden (Liste monatlich oder je für eine Woche oder?).
Für eine Gesamtzusammenfassung kann der gesamte Bereich in Zählenwenn (ohne Bereich.verschieben).
PS: Zu spät:)
SAU GEIL!!
Danke Leute. das mit dem Bereich.verschieben habe ich noch nie gesehen aber hilft ungemein. Damit ist ein Thema schonmal vom Tisch.
Jetzt stoße ich wieder an die Grenzen meiner Kenntnisse, denn ich kann nun auf dem Plan (Tabellenblatt2) ausgeben wie viele Mitarbeiter der einzelnen Sache zugeordnet sind.
Allerdings ist der Plan (Tabellenblatt2) nachher dazu da, etwas für die Mitarbeiter auszuhängen
Wie ich es bereits vorgegeben habe soll das genau so passieren. Die Index.Vergleich ist doch noch aktuell oder gibt es einen Verweis der es einfacher macht ?
Was ich aber cool fande in eurer Lösung war, dass ich nur das Datum ändern musste und mir direkt die Daten für das eingegebene Datum ausgespuckt hat.
Wie kann ich das nun abändern für die Plan Tabelle?
Also wenn ich oben in A1 anstatt 1.10.2018 - 2.10.2018 eingebe?
Eure Hilfe ist echt genial
MfG
BTW: der Tageszähler ist genau so richtig. Ist praktisch ein kleines Dashbboard beim eintragen, um schnell zu gucken wie viele bereits für welche Position eingeplant sind.
Was muss denn am Ende bzw. am Anfang eines neuen Monats beachtet werden?
Also ab Spalte F bis -> Ende wird immer ein neues Datum (das nächste Datum) hinzugefügt und dementsprechend soll sich dann auf dem neuen Tabellenblatt Plan immer alles aktualisieren:)
Hallo,
Mitarbeiter | A | B | C | D | E | F | G | AG | AH | AI | AJ |
| 1 | Datum: | 01.10.2018 | | | | | | | | | |
| 17 | Mitarbeiter2 | FG | Organisation | Kompetenz2 | Status | 01.10.2018 | 02.10.2018 | 28.10.2018 | 29.10.2018 | 30.10.2018 | 31.10.2018 |
| Formeln der Tabelle |
| Zelle | Formel | | F17 | =MONATSENDE(B1;-1)+1 | | G17 | =F17+1 | | AG17 | =AF17+1 | | AH17 | =WENN($AG17+1<=MONATSENDE($B$1;0);AG17+1;"") | | AI17 | =WENN($AG17+2<=MONATSENDE($B$1;0);$AG17+2;"") | | AJ17 | =WENN($AG17+3<=MONATSENDE($B$1;0);$AG17+3;"") |
|
Plan | A | B | C |
| 1 | Montag, 1. Oktober 2018 |
| 2 | Band 1 |
| 3 |
| 4 |
| 5 | AP | Mitarbeiter | FG |
| 6 | BF.100 | C | |
| 7 | ET.100 | aa | |
| 8 | QS.100 | r | |
| 9 | DS.100 | s | |
| 10 | DS.101 | | |
| 11 | WA.100 | y | |
| Formeln der Tabelle |
| Zelle | Formel | | A1 | =Mitarbeiter!B1 | | B6 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A6&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") | | B7 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A7&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") | | B8 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A8&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") | | B9 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A9&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") | | B10 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A10&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") | | B11 | =WENNFEHLER(INDEX(Mitarbeiter!$A$18:$A$1001;VERGLEICH("FS."&A11&"";BEREICH.VERSCHIEBEN(Mitarbeiter!$F$18:$F$1001;0;TAG($A$1)-1);0));"") |
|
Gruß Uwe