Hallo zusammen,
zerbreche mir gerade den Kopf. Ich benötige in der Zelle T2 die Summe aus der Spalte N die in dem Zeitraum vom Datum aus "B2 abzüglich 90 Tage" stattgefunden hat. Sprich innerhalb von 90 Tagen rückwirkend B2.
In der Zelle T3 dann vom Datum von B3-90Tagen usw....
Wer kann mir helfen
Gruß Marco
Hallo
versuche es mal so:
=SUMMEWENNS(N:N;B:B;"<="&B2;B:B;">="&B2-90)
alternativ
=SUMMENPRODUKT((B:B<=B2)*(B:B>=(B2-90))*(B:B<>"")*N:N)
Gruß Holger
.... kurzer Nachtrag:
B:B und N:N : Ganze Spalten in der Formel benötigen unter Umständen doch einiges an Rechenleistung
Ich würde mir dazu Überlegen die Matrix auf einen maximal möglichen Bereich zu begrenzen.
Beispiel
$B$2:$B$1000 und $N$2:$N$1000
LG
Moin!
Nur eine zusätzliche Anmerkung, bin mir sicher, dass Holger dies auch genau so meinte:
SUMMEWENNS() verarbeitet problemlos ganze Spalten und nutzt automatisch nur den UsedRange.
Bei SUMMENPRODUKT(), einer uralten aber genialen Funktion, ist dies nicht der Fall.
Daher gilt der letzte Beitrag nur für SUMMENPRODUKT()
Gruß Ralf
Für "Nostalgiker" gibt es hier eine blitzschnelle Alternative mit DBSUMME():
| A | B | C | D | E |
| 1 | Datum | Wert | | Datum | Datum |
| 2 | 01.01.2018 | 7 | | <=43352 | >=43262 |
| 3 | 01.02.2018 | 1 | | 09.09.2018 | 11.06.2018 |
| 4 | 01.03.2018 | 5 | | | |
| 5 | 01.04.2018 | 8 | | 13 | |
| 6 | 01.05.2018 | 1 | | | |
| 7 | 01.06.2018 | 3 | | | |
| 8 | 01.07.2018 | 3 | | | |
| 9 | 01.08.2018 | 1 | | | |
| 10 | 01.09.2018 | 9 | | | |
| 11 | 01.10.2018 | 9 | | | |
| 12 | 01.11.2018 | 9 | | | |
| 13 | 01.12.2018 | 3 | | | |
| Zelle | Formel |
| D2 | ="<="&D3 |
| E2 | =">="&E3 |
| E3 | =D3-90 |
| D5 | =DBSUMME(A:B;2;D1:E2) |
(09.09.2018, 09:58)RPP63 schrieb: [ -> ]Für "Nostalgiker" gibt es hier eine blitzschnelle Alternative mit DBSUMME():
......]
Hi, prima! Gefällt mir gut, ich bin auch ein DB-Formel-Fan! :19:
wie muss die Formel aussehen wenn man den jeweils berechnenden Datumsbereich bedingt farbig formatieren möchte? (angenommen in Spalte A eine Liste mit mindest 1x jeder Tag)
Ich hab's probiert, aber bekomme es nicht hin.
Danke mal !
jack
Hallo zusammen,
danke für die schnelle und Zahlreiche Hilfe. Ich habe die Formel von echo genommen "Summenprodukt" die andere hat leider nicht funktioniert. Die Matrix hatte ich schon gleich mit eingearbeitet, da in der unteren Hälfte Daten stehen die nicht für die Berechnung geeignet sind. Funktioniert prima.
Muss aber auch sagen, dass ich die Formel nicht verstehen, aber so lange sie funktioniert
Danke an alle
Gruß Marco
Na denn: Willkommen im Klub, Jack! :19:
Arbeitest Du bei "Die Bahn"? :05:
Formel der bedingten Form. für Spalte A:
=UND(A1<=HEUTE();A1>=HEUTE()-90)
@Biker:
Wenn SUMMEWENN() bei Dir nicht funktioniert, solltest Du mal eine Beispieldatei hochlaben!
Schließlich ist dies die Funktion, die es gerade "Neulingen" einfacher macht.
Gruß Ralf
(09.09.2018, 18:52)RPP63 schrieb: [ -> ]Na denn: Willkommen im Klub, Jack! :19:
Arbeitest Du bei "Die Bahn"? :05:
Formel der bedingten Form. für Spalte A:
=UND(A1<=HEUTE();A1>=HEUTE()-90)
.................................................]
Gruß Ralf
Danke! :18: ich werde probieren das umzustricken so dass es nicht nur mit HEUTE geht, sondern auch mit einem frei einzugebendem "Startdatum" . Wenn ich's nicht hinbekomme, melde ich mich noch mal. ;)
jack
Hi,
hab die Formel "Summewenns" eben noch mal probiert. Funktioniert doch, vielleicht habe irgendwie beim ersten Mal einen Fehler reingebracht
:19:
Danke