Clever-Excel-Forum

Hallo liebe Community!

Ich habe ein Problem mit einer Umsetzung dieser Arbeitsaufgabe.

Ich habe anzahl an Öfen zur Verfügung welche eingegeben werden kann. Auf den verfügbaren Öfen muss ich eine bestimmte Menge aufteilen (z.B. eine Menge in der Größe von 26.000kg). Noch ist dies recht einfach. Die aufgeteilte Menge muss aber aus kleineren Teilen bestehen (z.B. jeweils 8.000kg). Bleibt ein Rest übrig, so muss der Rest den Ofen mit dem kleinsten anteil bekommen.

Beispiel:
Öfen: 3
Menge: 24.000kg
Teilmengen: 8.000kg

Ofen 1: 8.000kg
Ofen 2: 8.000kg
Ofen 3: 8.000kg

Dieses beipiel ist noch recht einfach. Komplizierter wird es mit dem folgenden:

Beispiel 2:
Öfen: 2
Menge: 23.000kg
Teilmenge: 8.000kg

Ofen 1: 15.000kg <=1x 8.000kg + 1x 7.000kg Rest
Ofen 2: 8.000kg

Ein weiteres komplizierteres Beispiel:

Beispiel 3:
Öfen: 5
Menge: 75.000kg
Teilmenge: 8.000kg

Ofen 1: 16.000kg <= 2x 8.000kg
Ofen 2: 16.000kg <= 2x 8.000kg
Ofen 3: 16.000kg <= 2x 8.000kg
Ofen 4: 16.000kg <= 2x 8.000kg
Ofen 5: 11.000kg <= 1x 8.000kg + 1x 3.000kg

Also kurzgefasst meine Frage: Wie kann ich am einfachsten automatisch berechnen welcher Ofen wie viel aufnehmen muss?

Ist auch mein erster Post und benötige dringend Hilfe also bitte verzeiht mir Fehler oder Regelverstöße

LG Stifl

Edit#1
Meine Frage in anderen Foren:
https://www.ms-office-forum.net/forum/sh...p?t=353901

Hola,

verlinkst du bitte deine Fragen in den verschiedenen Foren gegenseitig?
Danke.

Gruß,
steve1da

Gemacht wenn du das meinst was ich gemacht habe.

Hallo S...,

zB so:

=WENN(D$3>=$C7;(D$4-REST(D$4;D$3*D$5))/D$3+MIN(D$5;MAX(0;REST(D$4;D$3*D$5)-($C7-1)*D$5));0)

Der Formelteil vor dem MIN ermittelt die gleichmässig aufgeteilte Menge und ab dem MIN wird der Rest berechnet.

Hut ab - ich hab auch dran geknispelt, aber heute wollten meine Zellen nicht.

Bleibt mir nur die Verkürzung ohne WENN und Ersatz von MIN|MAX durch MEDIAN:

=WENN(D$3>=$C7;(D$4-REST(D$4;D$3*D$5))/D$3+MIN(D$5;MAX(0;REST(D$4;D$3*D$5)-($C7-1)*D$5));0)
würde dann
=(D$3>=$C7)*((D$4-REST(D$4;D$3*D$5))/D$3+MEDIAN(;D$5;REST(D$4;D$3*D$5)-($C7-1)*D$5))

Es hat mir keine Ruhe gelassen:

=REST(D$4-SUMME(D$6:D6);D$5)+KÜRZEN((D$4-SUMME(D$6:D6))/D$5/(D$3-ZEILE(D1)+1))*D$5

sorgt für das gleiche Ergebnis, nur nicht in abnehmender Menge wie bei Ego (was aber auch nicht verlangt war). Mit Verwendung der Ofennummern (C6 leer!) von Ego noch kürzer:

=REST(D$4-SUMME(D$6:D6);D$5)+KÜRZEN((D$4-SUMME(D$6:D6))/D$5/(D$3-$C6))*D$5

Fehlermeldungen (bei mir, nicht bei Ego) kann man noch mit WENNFEHLER(;) selbst wegmachen. Bei Ego kann man noch einen Parameter einsparen und ebenfalls C6 statt C7 verwenden:

=(D$3>=$C7)*((D$4-REST(D$4;D$3*D$5))/D$3+MEDIAN(;D$5;REST(D$4;D$3*D$5)-($C7-1)*D$5))
=(D$3>$C6)*(KÜRZEN(D$4/D$3/D$5)*D$5+MEDIAN(;D$5;REST(D$4;D$3*D$5)-$C6*D$5))

An Egos Lösung ist die Nichtabhängigkeit von Vorgängerzeilen besser.

Vielen Vielen Vieleeen Dank!
Die Formel macht genau das was ich gesucht habe! Perfekt.

Du hast mein Leben gerettet :97:

Mir ist gerade aufgefallen das ich zitieren vergessen habe... Kann man die irgendwie löschen? Ich finde nichts

Scheint auch super zu funktionieren, jedoch ist egos lösung für mich simpler und leichter zu erklären(in meinen Augen).

Trotzdem großen Dank! War eine enorme Hilfe für mein Verständnis.

Nochmals zitieren vergessen...

Hmmmm das muss ich mir noch genauer anschauen :92:

Schonmal danke für deine Hilfe!

Und hier nochmals...

(23.08.2018, 15:32)Ego schrieb: [ -> ]Hallo S...,

zB so:

=WENN(D$3>=$C7;(D$4-REST(D$4;D$3*D$5))/D$3+MIN(D$5;MAX(0;REST(D$4;D$3*D$5)-($C7-1)*D$5));0)

Der Formelteil vor dem MIN ermittelt die gleichmässig aufgeteilte Menge und ab dem MIN wird der Rest berechnet.

Vielen Vielen Vieleeen Dank!
Die Formel macht genau das was ich gesucht habe! Perfekt.

Du hast mein Leben gerettet [img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]