Hallo zusammen, ich habe folgende Formel in meiner Datenbank und seit dem stürzt mit der Serienbrief beim zusammen führen auch nur eines Datensatzes ab.
Die Datei hat ohen die Formel 2 MB und mit 3,6 MB.
Was kann man da tun?
Danke euch.
Die Formel:
WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)
Hallo, ich sehe ja deine Datei nicht, aber what the hell soll das denn..?
PHP-Code:
... SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d")))...
Ist das n' Scherz?
Erst mal ist bei Dir was anderes zu lang: Es heißt Terabyte.
Deine Formel braucht ein wenig Case-Modeling (rot wird zu halb so viel blau), und Deine 4malige SUMME ist Blöd-Zinn.
=WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";
WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));
WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)
...
UND(AC3="";AE3="")*(HEUTE()-A3)+
UND(S3<>"";AC3<>"";AE3="")*(HEUTE()-A3+S3-MIN(HEUTE();AC3))+
UND(S3<>"";AC3<>"";AE3<>"")*(AE3-A3+S3-MIN(AC3;AE3))+
UND(S3="";AE3<>"")*(AE3-A3)+
...
Statt WENN geht es auch mit WAHL mit 8 Ausgängen, obwohl Du nur 5 hast. Drei davon schiebt man dann noch zusammen.
Hi,
ich würde die Formel mal so kürzen (UNGETESTET!!!):
Code:
=WENN((A3="")+(A3<--"1.1");"";WENN((AC3="")*(AE3="");HEUTE()-A3;WENN((S3<>"")*(AC3<>"");WENN(AE3<>"";AE3-A3+S3-MIN(AE3;AC3);HEUTE()-A3+S3-MIN(HEUTE();AC3));WENN(AE3<>"";AE3-A3;AC3-S3))))
(22.08.2018, 14:29)Jockel schrieb: [ -> ]Hallo, ich sehe ja deine Datei nicht, aber what the hell soll das denn..?
PHP-Code:
... SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d")))...
Ist das n' Scherz?
Guten Morgen,
die Formel zieht Wartezeiten ab, in der der Sachbearbeiter nichts machen kann.
Die Formel berechnet Bearbeitungszeiten im Unternehmen.
(22.08.2018, 15:10)LCohen schrieb: [ -> ]Erst mal ist bei Dir was anderes zu lang: Es heißt Terabyte.
Deine Formel braucht ein wenig Case-Modeling (rot wird zu halb so viel blau), und Deine 4malige SUMME ist Blöd-Zinn.
=WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";
WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));
WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)
...
UND(AC3="";AE3="")*(HEUTE()-A3)+
UND(S3<>"";AC3<>"";AE3="")*(HEUTE()-A3+S3-MIN(HEUTE();AC3))+
UND(S3<>"";AC3<>"";AE3<>"")*(AE3-A3+S3-MIN(AC3;AE3))+
UND(S3="";AE3<>"")*(AE3-A3)+
...
Statt WENN geht es auch mit WAHL mit 8 Ausgängen, obwohl Du nur 5 hast. Drei davon schiebt man dann noch zusammen.
Guten Morgen,
ich habe deine Änderungen einmal eingegeben, da kommt die Fehlermeldung "ZU WENIG ARGUMENTE FÜR DIE FUNKTION"
(22.08.2018, 17:45)BoskoBiati schrieb: [ -> ]Hi,
getestet:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | S | AC | AE | AF | AG | AH | AI |
| 2 | 01.10.2017 | | | | | | | 0 |
| 3 | 01.01.2018 | | | | 233 | 233 | 233 | 233 |
| 4 | 01.01.2018 | | | 16.08.2018 | 227 | 227 | 227 | 227 |
| 5 | 01.01.2018 | | 11.08.2018 | 14.08.2018 | 225 | 225 | 225 | 225 |
| 6 | 01.01.2018 | 15.05.2018 | | 14.08.2018 | 225 | 225 | 225 | 225 |
| 7 | 01.01.2018 | 15.05.2018 | | | 233 | 233 | 233 | 233 |
| 8 | 01.01.2018 | 15.05.2018 | 17.05.2018 | | 231 | 231 | 231 | 231 |
| 9 | 01.01.2018 | 15.05.2018 | 23.08.2018 | | 134 | 134 | 134 | 134 |
| 10 | 01.01.2018 | 15.05.2018 | 25.05.2018 | 01.06.2018 | 141 | 141 | 141 | 141 |
| 11 | 01.01.2018 | 15.05.2018 | 25.05.2018 | 20.05.2018 | 134 | 134 | 134 | 134 |
| Zelle | Formel |
| AF2 | =WENNFEHLER(WENN(A2="";"";WENN(A2<43101;"";WENN(UND(S2="";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2<>"";AE2="";AC2<=HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2="";AC2>HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;HEUTE();"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2<=AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2>AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AE2;"d"))));WENN(UND(S2="";AC2="";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2="";AC2<>"";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2<>"";AC2="";AE2<>"");DATEDIF(A2;AE2;"d"))))))))))));0) |
| AG2 | =WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");WENN(AE2<>"";AE2-A2+S2-MIN(AE2;AC2);HEUTE()-A2+S2-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2)))) |
| AH2 | =WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");S2-A2+WENN(AE2<>"";AE2-MIN(AE2;AC2);HEUTE()-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2)))) |
| AI2 | =(A2<>"")*(A2>=--"1.1")*(WENN(AE2="";HEUTE();AE2)-WENN(ANZAHL(S2:AC2)<2;0;MIN(HEUTE();MIN(AC2;AE2))-S2)-A2) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo Edgar,
das wirft bei mir falsche Ergebnisse aus.
Es soll so sein:
Spalte A = EINGANGSDATUM ANTRAG
Spalte S = Datum, an dem der Sachbearbeiter fehlende Unterlagen nachgereicht hat
Spalte AC = Datum, an dem die Unterlagen spätestens wieder eingehen müssen
Slpalte AE = Datum, an dem der Antrag geschlossen wurde.
Die Zeit zwischen S und AC darf maximal 33 Tage beteragen.
Diese Zeit soll dem Sachbearbeiter nicht angerechnet werden.
Sofern es nur Daten in A gibt, soll immer mit Datum HEUTE die Zeit berechnet werden.
Danke für deine Mühe.
Hi,
in AF stehen die Ergebnisse Deiner Formel, in den weiteren Spalten die meiner Formeln. Siehst Du da einen Unterschied?
(23.08.2018, 06:40)BoskoBiati schrieb: [ -> ]Hi,
in AF stehen die Ergebnisse Deiner Formel, in den weiteren Spalten die meiner Formeln. Siehst Du da einen Unterschied?
Hallo Edgar,
sorry, ich bin wohl zu blöd.
Wenn ich deine Formel aus AI2 in meine Tabelle kopiere, kommt immer 0 raus.
Bei allen anderen bleibt das Feld weiß???