Clever-Excel-Forum

Hallo zusammen,

ich komme leider bei meiner Tabelle nicht wirklich weiter.

Ich habe in Spalte A Zahlen stehen (aktuell müssen die als Text formatiert sein).
In Spalte H stehen Beträge.

Ich möchte gern die Summe aller Beträge aus H, für die in A bestimmte Werte stehen.

Aktuell verwende ich für die Berechnung das Summenprodukt:
{=SUMMENPRODUKT(($A$9:$A$266={"67"."69"."72"})*(H$9:H$266))}

Also Summe aus H, wenn in A "67", "69" oder "72" steht.

Das ganze funktioniert auch. 

Allerdings ist das nur ein Beispiel. Welche Werte aus A berücksichtigt werden sollen, soll eigentlich in Zelle B1 stehen. Es sind auch nicht immer genau 3 Kriterien. Manchmal nur 1, manchmal auch 10, oder irgendwas dazwischen.

Daher hatte ich auf sowas in der Art gehofft:
in B1 steht "67"."69"."72"
und dann: {=SUMMENPRODUKT(($A$9:$A$266={B1})*(H$9:H$266))}
... was natürlich nicht funktioniert.

Über Ideen und Lösungsvorschläge, würde ich mich sehr freuen.
Vielen Dank schon mal.



PS: Auf VBA kann ich dabei leider nicht zurückgreifen, da bei uns Makros gesperrt sind.

Hi

lade bitte eine Beispieldatei hoch. So geht's: http://www.clever-excel-forum.de/thread-326.html
Es reichen ein paar wenige relevante Datensätze; sensible Daten bitte anonymisieren. Dazu solltest du 2-3 Wunschergebnisse händisch eintragen. Aber achte bitte darauf, dass der Aufbau der Beispieldatei zu 100 Prozent deinem Original entspricht.

Hallo,

bei deiner ersten Summenproduktformel ist Strg-Shift-Enter nicht notwendig.

Vielleicht wäre so etwas eine Variante?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	67	1		67		6
2	69	2		69		6
3	72	3		72
4	73	100
5

Zelle	Formel
F1	=SUMMENPRODUKT(($A$1:$A$10={"67"."69"."72"})*(B$1:B$10))
F2	{=SUMMENPRODUKT(($A$1:$A$10=MTRANS(D1:D10))*(B$1:B$10))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Das Strg-Shift-Enter in F2 ist bei dieser Formel allerdings notwendig.

Alternativ könnte man natürlich auch mit einer Pivottabelle arbeiten. Hier gäbe es z.B. die Möglichkeit einer Hilfsspalte in der Datentabelle bei der die für die Berechnung notwendigen Werte mit einem X gekennzeichnet werden oder man filtert in der PT einfach die gewünschten Werte.

Hi

Zitat:PS: Auf VBA kann ich dabei leider nicht zurückgreifen, da bei uns Makros gesperrt sind.

Auch die Excel eigenen Makrofunktionen? Sonst würde das Funktionieren.

Im Namensmanger
Name:     Daten
Bezieht sich auf       =AUSWERTEN(Tabelle1!$B$1)
 
In B1
{"67"."69"."72"}
 
Deine Formel
=SUMMENPRODUKT(($A$9:$A$266=Daten)*(H$9:H$266))

Gruß Elex

Vielen Dank für die schnelle Beantwortung.
Beide Lösungen funktionieren super. 

Ich bin jetzt noch garnicht sicher, welche ich am Ende nutzen werden.

Auf jeden herzlichen Dank. Das Problem ist jetzt gelöst.