Clever-Excel-Forum

Hallo Excel-Experten...,

ich habe da einen besonderen Wunsch für eine Formel, ich hoffe das Ihr mir helfen könnt...

Und zwar habe ich eine Tabelle mit mehreren Arbeitsblättern (ich glaube die heissen so, oder ???).
Diese habe ich entsprechend benannt..., sagen wir mal: Tabelle 1, Tabelle 2, Tabelle 3 usw. ...

Nun möchte ich dass Excel den Inhalt bestimmter Zellen (gehen wir mal von B2, C2 und D2 aus) in bestimmte Zellen auf dem 2. Arbeitsblatt automatisch überträgt, wenn z.B. in Zelle E2 ein bestimmter Wert (z.B.: 1) steht.
Sollte dort etwas anderes stehen sollen die Zellen nicht übertragen werden...

Das wäre schon einmal prima...

Besser wäre es noch wenn dann in Tabelle 2 keine lehren Spalten entstehen würden, also alle Zellen die kopiert werden würden automatisch sortiert untereinander stehen würden...

Ich hoffe es kann mir vielleicht einer helfen...

Hola,

eine Exceldatei wäre hilfreich.

Gruß,
steve1da

(04.03.2018, 18:50)steve1da schrieb: [ -> ]Hola,

eine Exceldatei wäre hilfreich.

Gruß,
steve1da

Hallo,

die habe ich natürlich...,
das Problem ist nur dass ich die nicht einfach so veröffentlichen kann, da diese private Daten von Mitgliedern enthält...

Hallo,

kannst du sie vielleicht einfach anonymisieren (z.B. Mitglied 1, ...) und einen kleinen Ausschnitt hochladen? Prinzipiell klingt das aber erst einmal nach einem Fall für Sverweis.

Beste Grüße

Hi,

(04.03.2018, 19:05)Florian19 schrieb: [ -> ]Prinzipiell klingt das aber erst einmal nach einem Fall für Sverweis.

oder ganz einfach mit WENN().

Heißt "Zellen sollen übertragen werden", daß sie dann auf dem 1. Blatt weg sein sollen?
Wie ist das, wenn es Neueinträge in Zwischenzeilen gibt, das sind doch mit Sicherheit nicht nur die Zellen B2, C2, D2?

Hi,

und was genau willst du jetzt wohin kopiert haben? Deine Beispieltabelle ist dahingehend leider absolut nichtssagend. Enstpricht sie vom Aufbau her überhaupt deinem Original?

(06.03.2018, 18:40)WillWissen schrieb: [ -> ]Hi,

und was genau willst du jetzt wohin kopiert haben? Deine Beispieltabelle ist dahingehend leider absolut nichtssagend. Enstpricht sie vom Aufbau her überhaupt deinem Original?

Diese entspricht dem Original.

Auf der 1. Seite stehen die Namen, Nummer und Position und die Zuordnung.

Wenn in der Zeile "Zuordnung" z.B. Meister steht, dann sollen die Zeilen auf das Blatt "Meister" kopiert werden. Ebenso mit Gesellen und Helfer in das jeweilige Arbeitsblatt.

Dafür sind insgesamt 4 Arbeitsblätter angelegt. Nur die letzten 3 sind lehr. Dorthin sollen die entsprechenden Inhalt automatisch kopiert werden, je nach Textinhalt

Hi,

sofern ich's richtig verstanden habe, probier's mal so:

Arbeitsblatt mit dem Namen 'Meister'
	A	B	C	D	E	F	G	H	I	J
1	Meister	Nummer	Nachname	Vorname	Position	Geburtstag	Alter aktuell	Alter 01.01.	Eintritt	Zuordnung 1
2	2	1	Mustermann	Max	Chef	22708	56	55	2002	Meister
3		5	Mustermann	Max	Chef	25071	49	49	2006	Meister
4
5
6	6
7
8
9
10

Zelle	Formel
A1	=TEIL(ZELLE("dateiname";A1);FINDEN("]";ZELLE("dateiname";A1))+1;255)
A2	=WENN(ZÄHLENWENN(Gesamtliste!$I2:I2;$A$1);ZEILE();"")
B2	=WENNFEHLER(INDEX(Gesamtliste!A:A;KKLEINSTE($A$2:$A$10;ZEILE(A1)));"")
C2	=WENNFEHLER(SVERWEIS($B2;Gesamtliste!$A$2:$I$10;SPALTE(B1);0);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT :.00] MS Excel 2013

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

In den Meister-, Monteur- und Helferblättern jeweils in A1 die Formel zum Auslesen der Blattbeschriftung (die absolut identisch mit der Zuordnung1 sein muss) eintragen; ab A2 die Spalte als Hilfsspalte für die Zeilennummern nehmen. Die Spalte kann dann ausgeblendet werden. Die SVEWEIS-Formel in C2 und nach rechts und unten ziehen.

Hi,

du kannst auch ganz auf die Hilfsspalte verzichten:

Arbeitsblatt mit dem Namen 'Monteur'
	A	B	C	D
1	Nummer	Nachname	Vorname	Position
2	2	Mustermann	Max	Chef
3	3	Mustermann	Max	Chef
4		0	0	0

Zelle	Formel
A2	=WENNFEHLER(INDEX(Gesamtliste!$A$1:$A$10;AGGREGAT(15;6;ZEILE($A$1:$A$10)/(Gesamtliste!$I$1:$I$10=TEIL(ZELLE("dateiname";A1);FINDEN("]";ZELLE("dateiname";A1))+1;255));ZEILE(A1)));"")
B2	=WENNFEHLER(WENNFEHLER(SVERWEIS($A2;Gesamtliste!$A$2:$I$10;SPALTE(B1);0);"");"")

Verwendete Systemkomponenten: [Windows (32-bit) NT :.00] MS Excel 2013

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Verweisformel in diesem Fall in B2 und wieder nach rechts und unten ziehen. Die Nullwerte kanns du im Übrigen (gilt natürlich auch für den vorherigen Tipp) mit dem benutzerdef. Format ;; ausblenden.