Hallo Leute,
nachdem ich nach langem googlen und probieren auf keine Lösung gekommen bin, hoff ich nun die Experten hier können mir helfen.
Folgendes Problem
Ich habe eine Datei in der Name und Vorname und eine dazugehörige Gruppe stehen.
--> Datei 1 [
attachment=1211]
Und nun möchte ich in einer anderen Datei diese Namen+Vornamen zu der Gruppe zuordnen sozusagen eine Liste.
--> Datei 2 [
attachment=1212]
Wenn möglich ohne VBA.
Gruß Bleame
Hallo,
danke für die schnelle Antwort.
Hab jetz folgendes in Feld B11 in Datei 2 eingegeben:
Code:
=WENNFEHLER(KKLEINSTE(WENN('[Datei 1.xlsx]Tabelle1'!$C$2:$C$22=B10;'[Datei 1.xlsx]Tabelle1'!$A$2:$A$22&", "&'[Datei 1.xlsx]Tabelle1'!$B$2:$B$22);ZEILE(A1));"")
Leider kommt ein leeres Feld raus... also der Wert_falls_Fehler bei WENNFEHLER also ""
hab ich irg. etwas falsch eingegeben???
Gruß Bleame
Hallo,
öffne doch beide Dateien und gib die Formel schritt für Schritt ein, in dem Du die angegebenen Bereiche
in den Dateien markierst.
Sonst einfach mal Wennfehler rausnehmen und die Formel auswerten.
Hab jetz mal die Auswertung gemacht und ich denke das Problem liegt an dem Zeile(A1),
was bedeutet denn dieser Ausdruck in der Formel?... gehört ja zu KKleinste, oder?
Das ist ja logischer Weise 1...
Hier noch ein Bild von der Auswertung ohne WENNFEHLER [
attachment=1219]
Danke nochmals für eure Hilfe!
Hallo,
mir ist die Formeln von Edgar nicht ganz klar.
Aus Gründen der einfacheren Darstellung habe ich das mal in einem Tabellenblatt untergebracht. Stellst du dir das so vor?
Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E | F | G | H |
2 | Name | Vorname | Gruppe | | | A | B | C |
3 | Klauser | K | C | | | Better, S | Mayer, S | Klauser, K |
4 | Better | S | A | | | | Jahn, F | Huber, M |
5 | Mayer | S | B | | | | | |
6 | Huber | M | C | | | | | |
7 | Jahn | F | B | | | | | |
8 | | | | | | | | |
Zelle | Formel |
F3 | {=WENNFEHLER(INDEX($A$2:$A$10;KKLEINSTE(WENN($C$2:$C$10=F$2;ZEILE($1:$9));ZEILE(A1)))&", "&INDEX($B$2:$B$10;KKLEINSTE(WENN($C$2:$C$10=F$2;ZEILE($1:$9));ZEILE(A1)));"")} |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Erst mal guten Abend.
@ Peter: Super hat mit folgender Formel funktioniert!
Code:
=WENNFEHLER(INDEX('[Datei 1.xlsx]Tabelle1'!$A$2:$A$22;KKLEINSTE(WENN('[Datei 1.xlsx]Tabelle1'!$C$2:$C$22=$B$10;ZEILE($1:$20));ZEILE(A1)))&", "&INDEX('[Datei 1.xlsx]Tabelle1'!$B$2:$B$22;KKLEINSTE(WENN('[Datei 1.xlsx]Tabelle1'!$C$2:$C$22=$B$10;ZEILE($1:$20));ZEILE(A1)));"")
DANKE, Danke, Danke nochmal!
Gruß Bleame