Hallo,
gerne möchte ich von einer Ligatabelle eine Augenblickform mit Sieg, Unentschieden und Niederlagen erstellen.
Die Schwierigkeit ist für mich, nur die letzten 5 vergangenen Begegnungen der entsprechenden Mannschaft auszuwerten.
Neue Einträge/Spielbegegnungen werden von der oberen Zeile nach unten eingetragen. D.h. neue Einträge sollen dann automatisch erfasst werden.
Vielen Dank schon mal für Eure Lösungen/Vorschläge
Andi
Seltsam, dass Anfänger ihre Postings nicht kontrollieren: Vor dem Absenden mit Beitragsvorschau, danach mit Bearbeiten (1 Stunde lang möglich).
Seltsam, dass Anfänger Bildchen schicken und erwarten, dass der Antworter alle Daten noch mal eingibt.
Das Bildchen wirft schon mal Fragen auf:
1. Du zeigst uns die Heimtabelle; der Augenblicksstatus soll aber vermutlich die letzten 5 Spiele, nicht nur die Heimspiele, umfassen. - ? -
2. Stehen die ältesten Partien oben?
Hallo CLohen,
1. In meinem Beispiel sollen nur die Heimspiele berücksichtigt werden
2. Die neusten Partien stehen oben
Anleitung für 2 Hilfsspalten:
- Füge eine Spalte G ein
- G2:G307: =A2&ZÄHLENWENN(A$2:A2;A2)
- H4:H21: =VERGLEICH(I4&5;G$2:G$307;)
- R4:T21: =SUMME(INDEX(($I4=$A$2:INDEX($A:$A;$H4+1))*(VORZEICHEN($D$2:INDEX($D:$D;$H4+1)-$C$2:INDEX($C:$C;$H4+1))+2=SPALTE(A4));))
Die Verwendung von E:F würde das noch abkürzen. Hab drauf verzichtet.
Hi,
oder so:
| Arbeitsblatt mit dem Namen 'AUG2' |
| Q | R | S | T | U |
| 3 | S | U | N | | |
| 4 | 4 | 1 | 0 | Beispiel (manuell eingetragen) | 125 |
| 5 | 2 | 1 | 2 | Beispiel (manuell eingetragen) | 131 |
| 6 | 3 | 1 | 1 | Beispiel (manuell eingetragen) | 122 |
| Zelle | Formel |
| Q4 | =SUMMENPRODUKT((INDEX($A:$A;$U4):$A$1000<>"")*(INDEX($A:$A;$U4):$A$1000=$H4)*(INDEX($C:$C;$U4):$C$1000-INDEX($D:$D;$U4):$D$1000>0)) |
| R4 | =SUMMENPRODUKT((INDEX($A:$A;$U4):$A$1000<>"")*(INDEX($A:$A;$U4):$A$1000=$H4)*(INDEX($C:$C;$U4):$C$1000-INDEX($D:$D;$U4):$D$1000=0)) |
| S4 | =SUMMENPRODUKT((INDEX($A:$A;$U4):$A$1000<>"")*(INDEX($A:$A;$U4):$A$1000=$H4)*(INDEX($C:$C;$U4):$C$1000-INDEX($D:$D;$U4):$D$1000<0)) |
| U4 | =AGGREGAT(14;6;ZEILE(A:A)/(A:A=H4);5) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
oder auch so:
| Arbeitsblatt mit dem Namen 'AUG2' |
| D | G | H | I | J | K | L | M | N | O | P | Q | R | S | T |
| 1 | ErgA | | | | | | | | | | | | | | |
| 2 | 2 | | | Heimtabelle | | Augenblickform = 5 vergangene Spiele |
| 3 | 1 | | | SP | T | GT | Pkt | S | U | N | | S | U | N | |
| 4 | 0 | | FCB | 11 | 34 | 9 | 31 | 10 | 1 | 0 | | 4 | 1 | 0 | Beispiel (manuell eingetragen) |
| Zelle | Formel |
| G2 | =WENN(ZÄHLENWENN(A2:A1000;A2)>5;"";VERWEIS(C2-D2;{-20;0;1};{3;2;1})&VERGLEICH(A2;$H$4:$H$21;0)) |
| Q4 | =ZÄHLENWENN($G:$G;SPALTE(A$1)&VERGLEICH($H4;$H$4:$H$21;0)) |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hallo LCohen, hallo BoskoBiati,
super vielen Dank für die schnelle Unterstützung.
Unglaublich, wie schnell Ihr eine Lösung parat hattet.
Bei der Lösung von BoskoBiati war das Problem, dass die Formel davon ausgegangen ist, dass die untersten Einträge in der Tabelle, die neuste Einträge sind. D.h. die Formel muss von oben die ersten 5 Spiele je Mannschaft auswerten.
Die von Lösung von LCohen funktioniert. Aber die Formel ist für mich krass. Ich bin Anfänger und muss mich da noch eine ganze Weile damit beschäftigen, um die Formel zu verstehen.
Auf jeden Fall besten Dank!
Grüße Andi
=SUMME(INDEX(($I4=$A$2:INDEX($A:$A;$H4+1))*(VORZEICHEN($D$2:INDEX($D:$D;$H4+1)-$C$2:INDEX($C:$C;$H4+1))+2=SPALTE(A4));))
beinhaltet zwei fortgeschrittene Ansätze (in blau der erste):
_______________________________
Flexible Datenlänge:
=SUMME(INDEX(($I4=
$A$2:INDEX($A:$A;$H4+1))*(VORZEICHEN(
$D$2:INDEX($D:$D;$H4+1)-
$C$2:INDEX($C:$C;$H4+1))+2=SPALTE(A4));))
Es wird damit der Bereich nur bis zum fünftletzten Heimauftritt aufgespannt. Der ist für FCB ungefähr bei Eintrag 85 (habe die Datei schon gelöscht). Diese 85 steht in H4. Also ergibt $A$2:INDEX($A:$A;$H4+1) halt A2:A86.
_______________________________
Der andere Ansatz funktioniert über VORZEICHEN. So brauche ich keine unterschiedlichen Operatoren pro Spalte wie >, = oder < zu berücksichtigen, denn mit Minus geht es für alle drei zusammen, schön kopierbar:
G = C>D => D-C=-1 => D-C+2=1 und für unentsch. /verloren entspr. 2 und 3.