Hi Experten,
bei mir kommt immer ein falsches Ergebnis raus.
Wäre super, wenn das einer hinbekommt:
Wie schreibt man folgende Bedingung in eine Formel:
J38=Wenn L36 eine 1 steht, dann I28+G33+G35
Wenn L36 eine 0 steht, dann G28+G33
+
H30,wenn H28 ein Minusbetrag oder Null steht oder
+
G30, wenn H28 ein Plusbetrag steht.
Vielen Dank
Gruss markus
Hallo Markus,
meinst du so:
=WENN(L36=1;I28+G33+G36)+WENN(UND(H28<>"";H28<=0);H30)+WENN(H28>0;G30)
Gruß Werner
(30.12.2017, 16:48)Werner.M schrieb: [ -> ]Hallo Markus,
meinst du so:
=WENN(L36=1;I28+G33+G36)+WENN(UND(H28<>"";H28<=0);H30)+WENN(H28>0;G30)
Gruß Werner
Vielen Dank Werner,
Immoment ist es so:
Wenn L36 eine 1 dann ist es meist richtig, vorausgestzt das H28 ein Minusbetrag ist. Beim Plusbetrag von H28 habe ich irgendwie auch ein anderes Ergebnis.
Wenn L36 eine 0, dann ist das Ergebnis mit der Formel immer -1 oder 0
Danke
Hi Markus,
so?
=WENN(L36=1;SUMME(I28;G33;G35);WENN(UND(H28>0;L36=0);SUMME(G28;G33;G30);SUMME(G28;G33;H30)))
(30.12.2017, 17:18)coemm schrieb: [ -> ]Hi Markus,
so?
=WENN(L36=1;SUMME(I28;G33;G35);WENN(UND(H28>0;L36=0);SUMME(G28;G33;G30);SUMME(G28;G33;H30)))
Hi Conny,
sieht schon verdammt gut aus.
Jedoch wenn L36 eine 1 und H28 eine Null oder Minusbetrag ist das Ergebnis noch falsch.
Gruss Markus
off topic...
Hallo, kannst du bitte für jedes Thema einen eigenen und wenn es irgend machbar ist passenenden Betreff verwenden...? Wer soll denn - wenn er ein ähnliches Problem hat diese threads finden... Ich finde das wenig kollegial...
Hi Markus,
meinst du so?
=WENN(UND(H28>0;L36=1);SUMME(I28;G33;G35;G30);WENN(UND(H28<=0;L36=1);SUMME(I28;G33;G35;H30);WENN(UND(H28>0;L36=0);SUMME(G28;G33;G30);SUMME(G28;G33;H30))))
Hallo Markus,
Deine Aufgabenstellung ist noch nicht ganz eindeutig, bzgl. dessen ob Du auch eine Leerzelle als 0 betrachtet haben willst oder nicht. Aber es bedarf in beiden Fällen keiner Excelfunktion zur Ergebnisermittlung.
Wenn Du Leerzellen wie 0 betrachtet willst, dann reicht folgende Formel:
=G33+(L36=1)*(I28+G35)+(L36=0)*G28+H30*(H28<=0)+G30*(H28>0)
Anderenfalls (Leerzellen in H28 und oder L36) sollen nicht wie 0 in diesen Zellen gewertet werden. so:
=(L36<>"")*(G33+(L36=1)*(I28+G35)+(L36=0)*G28)+(H28<>"")*(H30*(H28<=0)+G30*(H28>0))
(30.12.2017, 18:44)coemm schrieb: [ -> ]Hi Markus,
meinst du so?
=WENN(UND(H28>0;L36=1);SUMME(I28;G33;G35;G30);WENN(UND(H28<=0;L36=1);SUMME(I28;G33;G35;H30);WENN(UND(H28>0;L36=0);SUMME(G28;G33;G30);SUMME(G28;G33;H30))))
Conny ich bin begeistert!!!
Funktioniert 1a. DANKE!
Gruss Markus
(30.12.2017, 19:10)neopa schrieb: [ -> ]Hallo Markus,
Deine Aufgabenstellung ist noch nicht ganz eindeutig, bzgl. dessen ob Du auch eine Leerzelle als 0 betrachtet haben willst oder nicht. Aber es bedarf in beiden Fällen keiner Excelfunktion zur Ergebnisermittlung.
Wenn Du Leerzellen wie 0 betrachtet willst, dann reicht folgende Formel:
=G33+(L36=1)*(I28+G35)+(L36=0)*G28+H30*(H28<=0)+G30*(H28>0)
Anderenfalls (Leerzellen in H28 und oder L36) sollen nicht wie 0 in diesen Zellen gewertet werden. so:
=(L36<>"")*(G33+(L36=1)*(I28+G35)+(L36=0)*G28)+(H28<>"")*(H30*(H28<=0)+G30*(H28>0))
Hi Werner!
beide Formeln kommen auf das richtige Ergebnis! Ganz vielen Dank!!!!!!!!!!
Viele Grüße Markus