Hallo,
ich habe ein kleines Excel Problem und komme leider nicht weiter. Im Anhang zu meinem Problem habe ich eine Test Datei. Ich würde gerne in einer Zelle die Anzahl grünen, roten und weißen Zeilen zählen, wenn ein x eingetragen ist beim Standort (Siehe unten Test Datei).
Ich würde gerne dieses Problem mit einer Formel lösen und nicht mit VBA. Ist das möglich? Vielleicht hat einer von euch Experten eine Gute Idee.
Ich bin gespannt :)
Gruß
Hamza
Servus Hamza,
mhm ... hätte da eine tricky Lösung für Dich, ohne VBA zu bemühen.
Bei der Definition von NAMEN ist es möglich, spezielle (VBA-) Formeln zu hinterlegen.
Hierzu einfach im Reiter Formeln auf "Namen definieren" klicken, als Name "Farbe" eintragen und bei "Bezieht sich auf" die unten stehende Formel rein kopieren.
Das Ergebnis in einer Hilfsspalte könnte z.B. so aussehen.
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| G | H | I |
| 2 | Lieferant 1 | 1 | 20 |
| 3 | Lieferant 1 | 2 | 20 |
| 4 | Lieferant 3 | 3 | 20 |
| Name | Bezug |
| Farbe | =ZELLE.ZUORDNEN(63;INDIREKT("ZS(-2)";)) |
| Zelle | Formel |
| I2 | =Farbe |
| I3 | =Farbe |
| I4 | =Farbe |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2013 |
| Diese Tabelle wurde mit Tab2Html (v2.6.1) erstellt. ©Gerd alias Bamberg |
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C |
| 57 | | Anzahl | |
| 58 | grün | 8 | 20 |
| 59 | rot | 19 | 22 |
| 60 | weiß | 23 | 0 |
| Name | Bezug |
| Farbe | =ZELLE.ZUORDNEN(63;INDIREKT("ZS(-2)";)) |
| Zelle | Formel |
| B58 | =ZÄHLENWENN(I$2:I$51;C58) |
| C58 | =Farbe |
| B59 | =ZÄHLENWENN(I$2:I$51;C59) |
| C59 | =Farbe |
| B60 | =ZÄHLENWENN(I$2:I$51;C60) |
| C60 | =Farbe |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2013 |
| Diese Tabelle wurde mit Tab2Html (v2.6.1) erstellt. ©Gerd alias Bamberg |
Nachteil dieser speziellen Formel ist, dass man die Mappe im XLSM-Format abspeichern muss.
Ist das was für Dich?
LG Gerd
Hallo Gerd,
Danke für deine tolle Lösung nur habe ich zwei Probleme.
-Ich muss je nach Standort Auswahl. Also Hamburg oder Köln etc. Die mit "X" hinterlegt sind Zählen und dann die Zählen, die rot grün oder weiß markiert sind (Siehe Anhang).
-Mich stört leider die Hilfsspalte, da ich nicht weiß, wo ich diese in dieser Ausgangsdatei, die schon extremst überfüllt ist einbauen könnte.
Ich habe daher mir folgendes überlegt. Anstelle der Farben könnte ich ein v für grün ein x für weiß und nichts für rot eintragen in einer anderen Spalte (Neben Preis).
Kannst du mir hier nochmal Helfen?
Servus Hamza,
gute Entscheidung! Werte zu zählen ist besser als Farben ^^
Versuch mal so etwas ...
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B |
| 55 | Köln | |
| 56 | | |
| 57 | | Anzahl |
| 58 | grün | 3 |
| 59 | rot | 4 |
| 60 | weiß | 5 |
| Zelle | Formel |
| B58 | =ZÄHLENWENNS(B$2:B$39;"x";I$2:I$39;"v") |
| B59 | =ZÄHLENWENNS(B$2:B$39;"x";I$2:I$39;"") |
| B60 | =ZÄHLENWENNS(B$2:B$39;"x";I$2:I$39;"x") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2013 |
| Diese Tabelle wurde mit Tab2Html (v2.6.1) erstellt. ©Gerd alias Bamberg |
LG Gerd
Hi,
(05.12.2017, 16:04)Hamza420 schrieb: [ -> ]-Mich stört leider die Hilfsspalte, da ich nicht weiß, wo ich diese in dieser Ausgangsdatei, die schon extremst überfüllt ist einbauen könnte.
eine Hilfsspalte kann irgendwo ganz weit rechts in dem Tabellenblatt sein, die muß nicht zwischen oder direkt neben den eigentlichen Datenspalten sein.
Da sie eine Hilfsspalte ist, muß sie auch nicht sichtbar sein, sondern wird ausgeblendet.
In den Formeln und Funktionen wird auch auf eine ausgeblendete Hilfsspalte zugegriffen.
Hallo Ralf,
du hast vollkommen recht. Aber ich denke Gerd hat mich überzeugt Werte zu zählen ist doch angenehmer für mich. Wenn ich über die Datei nachdenke, die es am ende werden soll, dann ist es besser mit v für grün, x für weiß und kein Inhalt für rot zu arbeiten. Danke an euch beide.
Aber leider habe ich ein Problem nicht richtig erläutert. Also in Zelle A55 gibt es eine DropDown Feld (Blau). Hier kann man nach Köln oder Hamburg etc wählen. Wenn also Hamburg ausgewählt wurde, dann soll er für Hamburg die x zählen (C2:C51), bei Köln dann B2:B51, D2 : D51) etc. Ansonsten ist die Formel super. Der erste Zählbereich ist also variabel und Abhängig von der Zelle a55.
Kannst du mir da noch helfen Gerd wäre dir sehr dankbar.
Servus Hamza,
dann nehmen wir doch gleich Summenprodukt ;)
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | A | B |
| 55 | Paris | |
| 56 | | |
| 57 | | Anzahl |
| 58 | grün | 6 |
| 59 | rot | 3 |
| 60 | weiß | 1 |
| Zelle | Formel |
| B58 | =SUMMENPRODUKT(($I$2:$I$49="v")*($A$55=$B$1:$E$1)*($B$2:$E$49="x")) |
| B59 | =SUMMENPRODUKT(($I$2:$I$49="")*($A$55=$B$1:$E$1)*($B$2:$E$49="x")) |
| B60 | =SUMMENPRODUKT(($I$2:$I$49="x")*($A$55=$B$1:$E$1)*($B$2:$E$49="x")) |
| Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg |
LG Gerd
Hallo,
die Lösung von Gerd klappt perfekt. Vielen Lieben Dank an alle.
Gruß
Hamza420