Danke an Elex, funktioniert. Habs abgeändert, dass es mit einer Tabelle unbestimmter Länge geht:
Code:
=SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!F:F;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!F:F;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))+
SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!G:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!G:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))
läuft. Jetzt guck ich mal, was das Problem war.
Hi,
irgendwie hat sich ind die Formel ein INDEX eingeschlichen, der nicht dahin gehört:
Code:
=SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA07!$E:$E;AGGREGAT(14;6;ZEILE([Datenbasis_FA.xlsm]FA07!$E:$E)/([Datenbasis_FA.xlsm]FA07!$E:$E=B3);1)):INDEX([Datenbasis_FA.xlsm]FA07!$E:$E;AGGREGAT(14;6;ZEILE([Datenbasis_FA.xlsm]FA07!$E$1:$E$65536)/([Datenbasis_FA.xlsm]FA07!$E$1:$E$65536=B3);C3));B3;INDEX(B:B;AGGREGAT(14;6;ZEILE([Datenbasis_FA.xlsm]FA07!$E:$E)/([Datenbasis_FA.xlsm]FA07!$E:$E=B3);1)):INDEX(B:B;AGGREGAT(14;6;ZEILE([Datenbasis_FA.xlsm]FA07!$E:$E)/([Datenbasis_FA.xlsm]FA07!$E:$E=B3);C3)))
mit dem Suchbegriff in B3 und der Anzahl in C3
Fehler gefunden, mehrere Spalten als Summe_Bereich sind nicht zulässig, man muss die Summe aus jeder Spalte bilden und die einzelnen Summen dann summieren.
Danke an alle.
Hi,
Zitat:mehrere Spalten als Summe_Bereich sind nicht zulässig
wer erzählt denn sowas?????
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | C | D | E | F |
| 22 | x | 1 | 1 | 4 |
| 23 | | 1 | 1 | |
| 24 | x | 0 | 0 | |
| 25 | | 1 | 1 | |
| 26 | x | 1 | 1 | |
| 27 | | 0 | 0 | |
| 28 | x | 0 | 1 | |
| 29 | | 1 | 0 | |
| 30 | x | 1 | 1 | |
| 31 | | 1 | 1 | |
| 32 | | 1 | 0 | |
| 33 | | 0 | 0 | |
| 34 | x | 1 | 0 | |
| Zelle | Formel |
| F22 | =SUMMEWENN(C22:C34;"x";D22:E34) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Nur ist das Ergebnis dann nicht korrekt, weil nur eine Spalte ausgewertet wird!
Wenn die Bereiche gleich groß sind, geht es auch über mehrere Spalten:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | C | D | E | F | G |
| 22 | x | | 1 | 1 | 7 |
| 23 | | x | 1 | 1 | |
| 24 | x | | 0 | 0 | |
| 25 | | x | 1 | 1 | |
| 26 | x | | 1 | 1 | |
| 27 | | x | 0 | 0 | |
| 28 | x | | 0 | 1 | |
| 29 | | x | 1 | 0 | |
| 30 | x | | 1 | 1 | |
| 31 | | x | 1 | 1 | |
| 32 | | | 1 | 0 | |
| 33 | | | 0 | 0 | |
| 34 | x | | 1 | 0 | |
| Zelle | Formel |
| G22 | =SUMMEWENN(C22:D34;"x";E22:F34) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Ansonsten wäre SUMMENPRODUKT die ALternative:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| | C | D | E | F |
| 22 | x | 1 | 1 | 8 |
| 23 | | 1 | 1 | |
| 24 | x | 0 | 0 | |
| 25 | | 1 | 1 | |
| 26 | x | 1 | 1 | |
| 27 | | 0 | 0 | |
| 28 | x | 0 | 1 | |
| 29 | | 1 | 0 | |
| 30 | x | 1 | 1 | |
| 31 | | 1 | 1 | |
| 32 | | 1 | 0 | |
| 33 | | 0 | 0 | |
| 34 | x | 1 | 0 | |
| Zelle | Formel |
| F22 | =SUMMENPRODUKT((C22:C34="x")*D22:E34) |
| Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
(15.11.2017, 11:54)BoskoBiati schrieb: [ -> ]Nur ist das Ergebnis dann nicht korrekt, weil nur eine Spalte ausgewertet wird!
Wenn ich die Formel
Code:
=SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!F:F;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!F:F;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))+
SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!G:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!G:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))
zu
Code:
=SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!F:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!F:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))
ändere, spuckt Excel #BEZUG! raus.
Hi,
klar, weil Du die Formel nicht verstanden hast:
Code:
=SUMMEWENN(INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!E:E;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1));B3;
INDEX([Datenbasis_FA.xlsm]FA04!F:F;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););60)):
INDEX([Datenbasis_FA.xlsm]FA04!G:G;KGRÖSSTE(INDEX(([Datenbasis_FA.xlsm]FA04!$E:$E=B3)*ZEILE($A:$A););1)))
Ich steige mal wieder ein ... :05:
(14.11.2017, 11:18)GMG-CC schrieb: [ -> ]Alternative ohne (mehr oder weniger fehleranfällige) Formel und mit wenigen Mausklicks: Power Query.
Wie funktioniert das genau mit Power Query?