Clever-Excel-Forum

Hallo,
bin ganz neu hier im Forum.
Ich möchte gerne eine Excel-Tabelle als Bild oder ähnliches speichern, aber ohne dieses in Zwischenspeicher oder Bildbearbeitungsprogramme einzufügen.
Bisheriger Weg ging über`s Paint, das würde ich gerne weglassen.
Ich kann in dem Kabelkonstruktionsprogramm, in welches das Bild eingefügt werden soll (E3) nur Bilder importieren, die vorher richtig als Bild gespeichert wurden. (also aus keinem Zwischenspeicher)

Gibt es da einen Weg oder läuft es weiterhin auf`s Paint hinaus?

Liebe Grüße
Sandra

Moin Sandra!
Sowas funktioniert über einen temporären Umweg über ein Diagramm.
Siehe z.B. hier:
http://www.herber.de/forum/archiv/456to4...chern.html

Gruß Ralf

Code:
Sub M_snb()

    With Sheets(1).UsedRange

        .CopyPicture

        With Sheets(1).ChartObjects.Add(5, 5, .Width, .Height).Chart

            .Paste

            .Export ThisWorkbook.path & "\" & sheets(1).name & ".gif", "GIF"

            .Parent.Delete

        End With

    End With

End Sub

Ich habe snb's Code mal abgewandelt:

1. soll er aus der aktuellen Tabelle heraus funktionieren, nicht aus dem 1. Blatt
2. werden 3 Formate geschrieben. Vergleiche sie (z.B. in Qualität, Dateigröße oder Zielvoraussetzung) und kommentiere die verworfenen aus.

Hinweis: getestet mit xl2010

Code:
Sub M_snb()

    With ActiveSheet.UsedRange

        .CopyPicture

        With ActiveSheet.ChartObjects.Add(5, 5, .Width, .Height).Chart

            .Paste

            .Export ThisWorkbook.Path & "\" & ActiveSheet.Name & ".gif", "GIF" '160 383

            .Export ThisWorkbook.Path & "\" & ActiveSheet.Name & ".png", "PNG" '213 478

            .Export ThisWorkbook.Path & "\" & ActiveSheet.Name & ".jpg", "JPG" '347 862

            .Parent.Delete

        End With

    End With

End Sub

Die 1. Zahlen dahinter geben die Datei-Größe einer guten halben DIN A4-Seite, Gitternetzlinien, normale Schrift auf weißem Hintergrund bei 100% Zoom wieder,

die 2. Zahlen bei 200% Zoom (falls die Wiedergabe in einem Schriftstück das qualitativ erfordert).

Danke erstmal,
ich geb das mal an einen Kollegen weiter, der das in den Code schreibt und dann probieren wir das mal.

Danke!

sandra112

RPP63

snb

lupo1

sandra112