Läuft! Ein großes Dankeschön nochmal für Eure Hilfe, besonders an Lupo1 :28:!
Wo lernt man das in diesem Umfang? Doch nicht bei der VHS oder aus Büchern? Ich würde das auch gerne so können, hab aber wenig Zeit, 3 Kinder und eigentlich hab ich genug andere Sachen um die Ohren... schade, ist echt interessant.
Das meiste Wissen für in Foren gestellte Fragen ist Mathe bis zur 6. oder 8. Klasse.
Das excelspezifische von VBA kann man ganz gut mit dem Rekorder lernen, wenn man BASIC schon kann.
Ansonsten ist Excel natürlich relativ mächtig. Die wichtigsten Funktionen (reichen zu 90% aus) für den Normalgebrauch sind:
SUMME
SUMMENPRODUKT
SUMMEWENN(S)
ZÄHLENWENN(S)
VERGLEICH
VERWEIS
INDEX
WAHL
ZEILE
SPALTE
REST
ABS
KÜRZEN
RUNDEN
ANZAHL(2)
WENNFEHLER
WENN
MTRANS
Und ...
LINKS()
RECHTS()
TEIL()
TEXT()
AGGREGAT()
Hi,
.. und
SVERWEIS
WVERWEIS
und sicherlich noch ein paar mehr. :32:
Moin!
Ich bleibe mal beim Off Topic:
Lupo1 nennt WAHL(), shift-del hat es sogar in der Signatur als "Super-Funktion".
Da ich es höchstens mal zu Testzwecken gebraucht habe:
Hat einer mal ein sinnvolles Beispiel, was man nicht auch mit Index(), Vergleich() oder (vom Prinzip des Nächstkleineren) mit Verweis() abbilden kann?
Gruß Ralf
Ralf,
WAHL() steht in meiner Signatur weil es Bezüge zurück geben kann. Damit lässt es sich innerhalb von Funktionen verwenden, die nur Bezüge aber keine Matrizen akzeptieren.
Quasi ein Wenn x=1 dann Bezug1, Wenn x=2 dann Bezug2, etc.
Selbstverständlich lässt sich das ebenfalls mit der Bezugsvariante von INDEX() bewerkstelligen. Wobei diese - wie ich mal gelesen habe - das nur innerhalb eines Tabellenblattes schafft.
Moin Detlef!
Ja, die Bezugsvariante ist ein Argument, weil leichter umsetzbar und für jemanden, der später eine verschachtelte Formel analysieren will, besser verständlich.
Ich bleibe wohl doch eher bei der INDEX-Variante mit ZEILE/SPALTE als Variable.
Danke für die Antwort!
Gruß Ralf
Ralf,
was die Funktion noch bemerkenswert macht ist dass sie verschiedene Datentypen zurück geben kann.
Code:
=WAHL(A1;14;G1*H1+L1;"Hilfe!";NV();WAHR;C1:E1)
Zahl, Formelergebnis, Text, Fehlerwert, Boolean, Bezug.
WAHL ist eine Hammerfunktion. Als wichtigste Eigenschaft: Binär addierbare Bedingungen, zu deren Addition völlig verschiedene Berechnungen WENN-frei ausgegeben werden können. Das kann man mit REST total thrillen. WAHL ist Ausweg zu meiner tendenziellen WENN-Abneigung.
WENN ist im wesentlichen nur sinnvoll für Matrixfunktionen, in denen es ohne nicht geht (z.B. bedingtes MIN oder MIN-MAX-Umgehung im SUMMENPRODUKT, siehe unten). Nur deshalb taucht es noch in meiner Liste auf. Aber auch dort wird ein großes Spektrum mittlerweile von AGGREGAT abgeschöpft.
Als weiteres hat WENN die Eigenschaft, dass man die bedeutsameren Bedingungen nach außen legt, und die selteneren nach innen. Damit kann man in manchen Fällen gut verästelt prüfen. Ist mir aber selten untergekommen. Bei WAHL fällt das leichter - und ist (oft) übersichtlicher und (immer) kürzer.
Für den letzteren Aspekt (Verästelung) kann man WENN mit WENNS kombinieren. WENNS allein erlaubt jedoch nur EINE Hierarchie.
Hier noch das MIN im SUMMENPRODUKT-{SUMME}-Beispiel:
Von den Reihen A1:A20 und B1:B20 sollen die 20 kleineren Werte jeder Zeile summiert werden. Das geht mit MIN nicht, wo, wenn es denn ginge, nur 2 Bereiche genannt werden müssten, nämlich jeder der beiden 1-mal!
5) =SUMMENPRODUKT(A1:A20-(A1:A20>B1:B20)*(A1:A20-B1:B20)) macht es zwar ohne WENN, aber nur mit 5-maliger Nennung der Bereiche (statt idealerweise 2-malig).
4) {=SUMME(WENN(A1:A20>B1:B20;B1:B20;A1:A20))} schafft es mit WENN auf 4 Nennungen.
3) {=SUMME(A1:A20-WENNFEHLER(EXP(LN(A1:A20-B1:B20));))} schafft es mit WENNFEHLER auf 3 Nennungen.
2) =SUMMENPRODUKT(TEILERGEBNIS(5;BEREICH.VERSCHIEBEN(A1:B1;ZEILE(A1:A20)-1;))) schafft es sogar auf 2 Nennungen (unten sogar auf "0,75").
Mir ist eine Minimierung der Anzahl der Argumente immer wichtig, denn Argumente können manchmal sehr lang ausfallen, z.B. durch Berechnung! Dann werden Hilfszellen seltener nötig, je weniger man solche Argumente einsetzen muss:
5) =SUMMENPRODUKT(INDEX(A:A;X1):INDEX(A:A;X2)-(INDEX(A:A;X1):INDEX(A:A;X2)>INDEX(B:B;X1):INDEX(B:B;X2))*(INDEX(A:A;X1):INDEX(A:A;X2)-INDEX(B:B;X1):INDEX(B:B;X2)))
4) {=SUMME(WENN(INDEX(A:A;X1):INDEX(A:A;X2)>INDEX(B:B;X1):INDEX(B:B;X2);INDEX(B:B;X1):INDEX(B:B;X2);INDEX(A:A;X1):INDEX(A:A;X2)))}
3) {=SUMME(INDEX(A:A;X1):INDEX(A:A;X2)-WENNFEHLER(EXP(LN(INDEX(A:A;X1):INDEX(A:A;X2)-INDEX(B:B;X1):INDEX(B:B;X2)));))}
2) =SUMMENPRODUKT(TEILERGEBNIS(5;BEREICH.VERSCHIEBEN(A1;ZEILE(A1:INDEX(A:A;X2-X1+1))-1;;;2))) oder
2) =SUMMENPRODUKT(TEILERGEBNIS(5;BEREICH.VERSCHIEBEN(A1;ZEILE(INDIREKT(X1&":"&X2))-1;;;2)))
Die Formel mit den wenigsten Nennungen ist nun die kürzeste. Die TEILERGEBNIS-Variante ermöglicht als einzige auch ein echtes MIN, mit nämlich mehr als 2 Vergleichsreihen, um den Preis der Volatilität!
(29.07.2017, 10:22)lupo1 schrieb: [ -> ]2) =SUMMENPRODUKT(TEILERGEBNIS(5;BEREICH.VERSCHIEBEN(A1:B1;ZEILE(A1:A20)-1;))) schafft es sogar auf 2 Nennungen (unten sogar auf "0,75").
Ich wollte das mal mit AGGREGAT() versuchen:
Code:
=SUMMENPRODUKT(AGGREGAT(15;6;BEREICH.VERSCHIEBEN(A1:B1;ZEILE(A1:A20)-1;;;);1))
Statt eines Ergebnisses kam dann dies:
Excel schrieb:Für Excel waren beim Berechnen einer oder mehrere dieser Formeln nicht genügend Ressourcen vorhanden. Daher können diese Formeln nicht ausgewertet werden.
Whaaaaaaaaaaaat?!
Ich habe sogar den Rechner neu gestartet. Immer wieder die selbe Fehlermeldung.
Passiert das auch bei euch?