Hallo,
Ich suche eine Formel um aus einer Zelle einen bestimmten Wert auszulesen.
Dabei hat die einen bestimmten Aufbau:
Heizkörperhöhe/Heizkörpertiefe/Nabenanzahl
z.B. 525/80/24
oder 1025/D16/20
Aus diesen Werten benötige ich immer die Nabenanzahl. Also immer den letzten Wert nach dem 2. "/"
Mit dem Wert will ich dann die Heizkörperlänge ausrechnen.
Daher ist meine Frage ob es eine Formel gibt mit der ich die Zahl nach dem 2. "/" auslesen kann.
Freundliche Grüße
Philipp
Hola,
z.B. als Matrixformel (mit Strg-Shift-Enter abschließen):
Code:
=RECHTS(A1;VERGLEICH("/*";RECHTS(A1;SPALTE(1:1));0)-1)
Gruß,
steve1da
Vermutlich reicht
=--RECHTS(WECHSELN(A2;"/";" ");2)
da die Anzahlen ja weit unter 100 sind. Falls doch höher:
=--RECHTS(WECHSELN(A2;"/";" ");3)
Achtung: Bei der zweiten Formel sind 2 Leerzeichen innerhalb der "". Die Forumssoftware macht (möglicherweise, hier bei mir nicht!) nur 1 daraus!
(18.07.2017, 13:09)steve1da schrieb: [ -> ]Hola,
z.B. als Matrixformel (mit Strg-Shift-Enter abschließen):
Code:
=RECHTS(A1;VERGLEICH("/*";RECHTS(A1;SPALTE(1:1));0)-1)
Gruß,
steve1da
Vielen dank steve1da :)
Die Formel funktioniert super!
Es bleibt anzumerken, dass die Formel sich wegen SPALTE(1:1) 16384mal versucht!
Hallo, ohne Matrixformelabschluss..:
Arbeitsblatt mit dem Namen 'Tabelle2' |
| F | G | H | I |
2 | 525/80/24 | | | 24 |
3 | 1025/D16/20 | | | 20 |
Zelle | Formel |
I2 | =--ERSETZEN(F2;1;SUCHEN("#";WECHSELN(F2;"/";"#";2));"") |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Hallo lupo1, es bleibt anzumerken, dass deine zweite Formel bei mir nicht funktioniert...
so geht's bei mir..:
Code:
=--WECHSELN(RECHTS(WECHSELN(F2;"/";" ");3);ZEICHEN(160);"")
Hallo Jockel, dann merke ich hiermit an, es möglicherweise nochmals zu probieren ;) Bei mir geht es (xl2010), mit
.../2
.../23
.../235
Hallo lupo1... is ja kurios... gerade ging's (noch) nicht und jetzt... aber mein Vorschlag geht auch noch weiter, wenn es nottäte..:
Arbeitsblatt mit dem Namen 'Tabelle2' |
| F | G | H | I | J |
2 | 525/80/24 | 24 | 24 | 24 | 24 |
3 | 1025/D16/20 | 20 | 20 | 20 | 20 |
4 | 1025/D16/666 | 666 | 666 | 66 | 666 |
5 | 1025/D16/6671 | 6671 | 6671 | 71 | 671 |
Zelle | Formel |
G2 | =--ERSETZEN(F2;1;SUCHEN("#";WECHSELN(F2;"/";"#";2));"") |
H2 | {=RECHTS(F2;VERGLEICH("/*";RECHTS(F2;SPALTE(1:1));0)-1)} |
I2 | =--RECHTS(WECHSELN(F2;"/";" ");2) |
J2 | =--RECHTS(WECHSELN(F2;"/";" ");3) |
Achtung, Matrixformel enthalten! |
Die geschweiften Klammern{} werden nicht eingegeben. |
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine. |
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg |
Für Sicherheitsfanatiker geht auch
=--RECHTS(WECHSELN(F2;"/";" ");15) (mit 14 Leerzeichen zwischen den "")