Hallo Community,
ich möchte aus einer Preisliste (Tabellenblatt 1) Produkte auswählen und diese Produkte sollen auf einer Einkaufsliste (Tabellenblatt 2) wieder auftauchen. Hinter jedem Produkt ist hinterlegt, welche Rabattstufe angezogen werden soll. Die Rabattstufen (Tabellenblatt 3) können individuell angepasst werden.
Hier die Bespiele wie es aussehen soll. Immer wen bei Anzahl was eingetragen wird, soll der Artikel auf der Einkaufsliste auftauchen.
[
attachment=11891]
Da ich vermute, dass ein VBA-Script notwendig ist, wende ich mich an Euch. Ich hab keinen Plan :s
Hi Günter,
ich kann die Excel-Datei hier reinstellen, aber da ist ja nix hinterlegt, auser Text. Ich hab alles händisch eingetragen.
[
attachment=11894]
Gruß dev5fr
Hi,
die Tabelle einzustellen hatte den Sinn, dass ich diese nicht nach einem Abbild nachbauen musste. Zudem kann man aus einem Bild keine Inhaltskopien erstellen. Hier mal mein Vorschlag:
Im Blatt "Preisliste" eine Hilfsspalte einfügen, die du einfach ausblenden kannst; dann stört sie nicht
Preisliste | A | B | C | D | E | F | G |
| 1 | Artikelnummer | EAN | Bezeichnung | Anzahl | Listenpreis | Rabattstufe | HS (ausbl) |
| 2 | AMM-T-000 | 9991356234123 | Tisch | 1 | 1.638,00 | A | 2 |
| 3 | AMM-T-500 | 9991356234124 | Option: Ausziehtisch | | 410,00 | B | |
| 4 | AMM-T-600 | 9991356234125 | Option: Besteckschublade | 2 | 190,00 | D | 4 |
| 5 | AMM-T-700 | 9991356234125 | Sessel | | 350,00 | D | |
| 6 | | | | | | | |
| 7 | | | | | | | |
| 8 | | | | | | | |
| 9 | | | | | | | |
| 10 | | | | | | | |
| 11 | | | | | | | |
| 12 | | | | | | | |
| 13 | | | | | | | |
| 14 | | | | | | | |
| 15 | | | | | | | |
| 16 | | | | | | | |
| 17 | | | | | | | |
| 18 | | | | | | | |
| 19 | | | | | | | |
| 20 | | | | | | | |
| Formeln der Tabelle |
| Zelle | Formel | | G2 | =WENN(D2<>"";ZEILE();"") |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Im Blatt "Einkaufsliste" benötigst du ebenfalls eine Hilfsspalte (wieder ausblenden) Die Formeln habe ich alle für Bereiche bis Zeile 20 geschrieben. Die SVERWEIS-Formeln Sp. C bis Sp. F trägst du in C2 ein und ziehst sie nach rechts und nach unten.
Einkaufsliste | A | B | C | D | E | F | G |
| 1 | Artikelnummer | EAN | Bezeichnung | Anzahl | VK | Rabattstufe | EK |
| 2 | AMM-T-000 | 9991356234123 | Tisch | 1 | 1.638,00 € | A | 982,80 € |
| 3 | AMM-T-600 | 9991356234125 | Option: Besteckschublade | 2 | 190,00 € | D | 171,00 € |
| 4 | | | | | | | |
| 5 | | | | | | | |
| 6 | | | | | | | |
| 7 | | | | | | | |
| 8 | | | | | | | |
| 9 | | | | | | | |
| 10 | | | | | | | |
| 11 | | | | | | | |
| 12 | | | | | | | |
| 13 | | | | | | | |
| 14 | | | | | | | |
| 15 | | | | | | | |
| 16 | | | | | | | |
| 17 | | | | | | | |
| 18 | | | | | | | |
| 19 | | | | | | | |
| 20 | | | | | | | |
| Formeln der Tabelle |
| Zelle | Formel | | A2 | =WENNFEHLER(INDEX(Preisliste!$A$1:$A$20;KKLEINSTE(Preisliste!$G$1:$G$20;ZEILE(A1)));"") | | B2 | =WENNFEHLER(INDEX(Preisliste!$B$1:$B$20;KKLEINSTE(Preisliste!$G$1:$G$20;ZEILE(B1)));"") | | C2 | =WENNFEHLER(SVERWEIS($B2;Preisliste!$B$1:$F$20;SPALTE(B1);0);"") | | D2 | =WENNFEHLER(SVERWEIS($B2;Preisliste!$B$1:$F$20;SPALTE(C1);0);"") | | E2 | =WENNFEHLER(SVERWEIS($B2;Preisliste!$B$1:$F$20;SPALTE(D1);0);"") | | F2 | =WENNFEHLER(SVERWEIS($B2;Preisliste!$B$1:$F$20;SPALTE(E1);0);"") | | G2 | =WENNFEHLER($E2-($E2*SVERWEIS(F2;Rabattstufen!$A$2:$B$12;2;0));"") |
|
Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Das Rabattstufenblatt kannst du später komplett ausblenden.
Dies sind übrigens keine Bildchen, sondern Tabellenausschnitte, die du rauskopieren und mit den nötigen Formeln versehen kannst.
Tante Edit flüstert mir gerade zu:
Im Blatt "Einkaufsliste" brauchst du doch keine Hilfsspalte!!! Du musst in der EK-Spalte nur die Formel abändern:
Code:
=WENNFEHLER($E2-($E2*SVERWEIS(Preisliste!F2;Rabattstufen!$A$2:$B$12;2;0));"")
Hi Günter,
sehr cool. Das probier ich gleich mal aus.
Vielen Dank!
Gruß dev5fr
Hallo Günter,
vielen Dank, dass klappt super :35:
Gruß dev5fr
Hallo, hier mein Vorschlag..:
| Arbeitsblatt mit dem Namen 'Preisliste' |
| | A | B | C | D | E | F |
| 1 | Artikelnummer | EAN | Bezeichnung | Anzahl | Listenpreis | Rabattstufe |
| 2 | AMM-T-000 | 9991356234123 | Tisch | 1 | 1.638,00 | A |
| 3 | AMM-T-500 | 9991356234124 | Option: Ausziehtisch | | 410,00 | B |
| 4 | AMM-T-600 | 9991356234125 | Option: Besteckschublade | 2 | 190,00 | D |
| 5 | AMM-T-700 | 9991356234125 | Sessel | | 350,00 | C |
| Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg |
| Arbeitsblatt mit dem Namen 'Einkaufsliste' |
| | A | B | C | D | E | F |
| 1 | Artikelnummer | EAN | Bezeichnung | Anzahl | VK | EK |
| 2 | AMM-T-000 | 9991356234123 | Tisch | 1 | 1638,00 | 982,80 |
| 3 | AMM-T-600 | 9991356234125 | Option: Besteckschublade | 2 | 190,00 | 171,00 |
| 4 | | | | | | |
| 5 | | | | | | |
| 6 | | | | | | |
| 7 | | | | | | |
| Zelle | Formel |
| A2 | =WENNFEHLER(INDEX(Preisliste!$A$2:A20;AGGREGAT(15;6;ZEILE(Preisliste!$A$2:A20)-1/(Preisliste!$D$2:D20<>"");ZEILE(A1)));"") |
| B2 | =WENN($A2="";"";SVERWEIS($A2;Preisliste!$A$1:G20;SPALTE(B$1);0)) |
| C2 | =WENN($A2="";"";SVERWEIS($A2;Preisliste!$A$1:H20;SPALTE(C$1);0)) |
| D2 | =WENN($A2="";"";SVERWEIS($A2;Preisliste!$A$1:I20;SPALTE(D$1);0)) |
| E2 | =WENN($A2="";"";SVERWEIS($A2;Preisliste!$A$1:J20;SPALTE(E$1);0)) |
| F2 | =WENN($A2="";"";E2*(1-SVERWEIS(SVERWEIS($A2;Preisliste!$A$1:K20;SPALTE(F$1);0);Rabattstufen!A:B;2;0))) |
| Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg |
Hey,
vielen Dank! Werde ich heute Nachmittag auf jeden Fall ausprobieren.
Gruß dev5fr
Funktioniert auch. Aktualisiert sogar ein kleines Bißchen schneller. Vielen Dank!