=zählenwenns

[NickL]

Hallo liebe Gemeinschaft,

ich habe mal wieder eine Situation an der ich verzweifel. Zunächst habe ich versucht Tipps aus der Vergangenheit von euch anzuwenden aber irgendwie passen die nicht ganz zu meiner Situation.

Anbei sende ich euch eine selbsterlkärende Darstellung. Ich möchte für den Monat zählen wie viele "Kontrollen und Prüfungen" es gab. Am besten auch zum entsprechenden Jahr passend, in diesem Fall 2018.

Vielen Dank und einen schönen Samstagabend wünsche ich!

Nick

[Peter]

Hallo,

ich würde das mit einer Pivottabelle machen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H
7	Anzahl von Datum		Wert
8	Jahre	Datum	Kontrolle und Pruefung	Systemcheck	Gesamtergebnis
9	2018	Jul	2	1	3
10		Sep	1	1	2
11		Okt	2	1	3
12	2018 Ergebnis		5	3	8
13	Gesamtergebnis		5	3	8

Das einzige was du an deinem Tabellenaufbau ändern musst: In A1 und B1 gehört eine Überschrift.

Markiere eine Zelle der Datentabelle - Einfügen - Pivottable und folge dem Assistenten.

Ziehe das Feld Datum in das Zeilenfeld und in das Wertefeld. Das Feld Wert (Spalte B) ziehst du in das Spaltenfeld.

Markiere in der PT ein Datum - rechte Maus - Gruppieren - Monat und Jahr auswählen.

Und wenn du wirklich nur einen Wert sehen willst könnte man das auch so machen, dass der Wert in das Filterfeld gezogen wird und du einfach nach dem gewünschten Wert filterst:

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F
5	Wert	Kontrolle und Pruefung
6
7	Anzahl von Datum
8	Jahre	Datum	Ergebnis
9	2018	Jul	2
10		Sep	1
11		Okt	2
12	2018 Ergebnis		5
13	Gesamtergebnis		5

Ist das eine Option?

[neopa]

Hallo Nick,

es ist jedoch auch mit ZÄHLENWENNS() möglich. In Deiner Datei mit Deiner Datenstruktur und Deinen Datenformaten für das jeweils aktuelle Jahr in E2:

Code:

=ZÄHLENWENNS(A:A;">="&("1-"&D2)+0;A:A;"<="&MONATSENDE(("1-"&D2)+0;0);B:B;"Kontrolle und Pruefung")

und Formel nach unten kopieren.

[BoskoBiati]

Hi,

wenn die Begriffe nur in einer Konstellation vorkommen, ginge auch das:

Code:

=ZÄHLENWENNS(A:A;">="&--("1-"&D2)+0;A:A;"<="&MONATSENDE(--("1-"&D2)+0;0);B:B;"Kont*")

[WillWissen]

Hi Nick,

eine weitere Möglichkeit wäre SUMMENPRODUKT()

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E
2	Juli	2
3	September	1
4	Oktober	2

Zelle	Formel
E2	=SUMMENPRODUKT((MONAT($A$2:$A$10)=MONAT(D2))*(JAHR(A2:A10)=JAHR(D2))*(($B$2:$B$10)="Kontrolle und Pruefung"))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Dazu musst du die Daten als z.B. 1.6.18 eingeben und MMMM formatieren.

[Jockel]

Hallo wenn wir im Jahr bleiben müssen wir gar nicht zaubern..:

=SUMMENPRODUKT((TEXT($A$2:$A$9;"MMMM")=D2)*1;($B$2:$B$9="Kontrolle und Pruefung")*1)

und wenn doch Jahresübergreifend kommt es auf das Kriterium an. Aber da braucht's auch nicht den "Brummer" von WillWissen...

[Jockel]

Hi,

wenn die Begriffe nur in einer Konstellation vorkommen, ginge auch das:

Code:

=ZÄHLENWENNS(A:A;">="&--("1-"&D2)+0;A:A;"<="&MONATSENDE(--("1-"&D2)+0;0);B:B;"Kont*")

Hallo Edgar, in der Formel braucht's keine "--" und keine "+0" - deshalb "reicht" wenn deine Annahme zutreffen würde

Code:

=ZÄHLENWENNS(A:A;">="&"1-"&D2;A:A;"<="&MONATSENDE("1-"&D2;0);B:B;"Kont*")

[Jockel]

Hallo,

ich würde das mit einer Pivottabelle machen:
...
Das einzige was du an deinem Tabellenaufbau ändern musst: In A1 und B1 gehört eine Überschrift.
....
Ist das eine Option?

Hallo Peter, selbst das in Zeiten von Power Query und PowerPivot nicht nötig - aber immer sinnvoll...!!!!

[NickL]

Vielen Dank euch allen. Diesmal schließe ich mich Jockel an und nehme die =summenprodukt - Formel. Bin wie immer begeistert und sehr sehr dankbar!!!!

[neopa]

Hallo Nick,

es ist natürlich immer Deine Entscheidung zu welcher Lösungsformel Du Dich entscheidest. In dem Fall hast Du Dich für eine SUMMENPRODUKT()-Formel entschieden, möglicherweise weil diese für Dich vertrauter bzw. einfacher nachvollziehbar ist. In Deinem Beispiel auch ausreichend und gut. Doch trotzdem dazu meinerseits folgende Hinweise und Anmerkungen:
Wenn ZÄHLENWENN() bzw. ZÄHLENWENNS() oder auch SUMMEWENN() bzw. SUMMEWENNS()-Formeln einsetzbar sind, haben diese folgende Vorteile: sie werten schneller aus und können auch über den gesamten Zeilen-/Spaltenbereich genauso schnell auswerten. Dies ermöglicht es, bei der Formelkonstruktion sich nicht unbedingt Gedanken über die Definition den Auswertungsbereich machen zu müssen. D.h. es können bei derartig Formeln im Nachgang beliebig viele Datensätze hinzukommen, ohne dass diese Formeln nachträglich angepasst werden müssen.

Über letzteres muss man sich jedoch bei SUMMENPRODUKT()-Formeln (natürlich nicht nur bei Formeln mit dieser Funktion sodern auch anderen Nicht-WENNs-Formeln) immer im Vorfeld im klaren sein. Denn bei derartige Formeln sollte man immer nur über den max notwendigen bzw. den max. zu erwartenden Datenbereich auswerten lassen. Sonst könnte sich die Auswertungszeiten sehr verlangsamen.  Um jedoch ein nachträgliches Anpassen derartige Formel trotzdem zu vermeiden, sollte man dann wenigstens die Datentabellen zuvor mittels "Als Tabelle formatieren" wandeln. Ist Dir diese Funktionalität und deren Vorteile bekannt?  Damit kann in der Formel der Auswertungsbereich durch dessen "Feldnamen" ersetzt werden. Dann passt sich die Formel  automatisch an deren jeweiligen Auswertungsbereich automatisch und somit entfällt zumindest dieser Nachteil. Bei größeren auszuwertenden  Datenmengen und oder vielen Formeln, sollte man zumindest erwägen, doch die sogenannten -WENNs()-Formeln einzusetzen.