zählenwenn, wenn eine wenn-bedinung erfüllt ist

[karstenexcel]

Hallo,

ich habe einen urlaubsplan, wo urlaub mit u und krank mit k eingegeben wird.
ich möchte jetzt auf einem tabellenblatt das ganz gezählt haben für jeden monat

So gesehen wäre ja da die Lösung:=zählenwenn(Tabellenblatt1!(Zellen die den Monat betreffen);"U")  für krank das ganz dann mit k
Jetzt passiert es ja, dass neue Mitarbeiter kommen und der plan sich verschiebt, dann stimmt aber die zusammenfassung nicht mehr.

Kann mir vllt jemand verraten, wie ich evtll sagen kann, dass Excel auf Tabellenblatt 1 den MA sucht und dann in dem passendem bereich halt die u´s zählt bzw k´s

MFG

Karsten

[WillWissen]

Hi,

zeig mal den Aufbau deiner Datei.  Etwa 10 Datensätze sind ausreichend; sensible Daten bitte anonymisieren. Keine Bilder!! So geht's:  http://www.clever-excel-forum.de/thread-326.html

[karstenexcel]

hoffe das geht so

[BoskoBiati]

Hi,

auch wenn der Tabellenaufbau nicht so geschickt ist:

Code:

=ZÄHLENWENN(INDEX(Tabelle1!$N$5:$AR$10;VERGLEICH(A3;Tabelle1!$A$5:$A$10;0););"u")

Überall ein richtiges Datum, dann reicht eine Formel:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E	F	G	H	I	J
1	Name				Genommen 2018			Kranktage	Januar
2									Urlaub	Krank
3	MA 1				0			25	0	4
4	Ma 2				0			0	0	0
5	MA 3				4			0	4	0
6	MA 4				0			0	0	0
7	MA 5				5			0	3	0
8	MA 6				11			0	8	0

Zelle	Format	Wert
I1	MMMM	01.01.2018
J1	MMMM

Zelle	Formel
I3	=ZÄHLENWENN(INDEX(Tabelle1!$G$5:$BX$10;VERGLEICH($A3;Tabelle1!$A$5:$A$10;0);VERGLEICH(INDEX($1:$1;SPALTE()-(REST(SPALTE();2)=0));Tabelle1!$G$4:$BX$4;0)):INDEX(Tabelle1!$G$5:$BX$10;VERGLEICH($A3;Tabelle1!$A$5:$A$10;0);VERGLEICH(MONATSENDE(INDEX($1:$1;SPALTE()-(REST(SPALTE();2)=0));0);Tabelle1!$G$4:$BX$4;0));LINKS(I$2;1))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[karstenexcel]

muss man mit leben, wenn einem sowas vorgesetzt wird =D

die formel funktioniert wunderbar, ich danke für die schnelle antwort

[BoskoBiati]

Hi,

muss man mit leben, wenn einem sowas vorgesetzt wird

Nein! Verbesserungen muß man nur gut verkaufen!

[karstenexcel]

die tabelle wird für viele dinge verwendet, da ist die datums angabe leider so gebunden^^
habe einiges versucht und meine vorgesetzten bevorzugen diese ansicht auch=D

naja egal, die formel funktioniert soweit und damit ist alles gut. danke nochmals!

[Dieter63]

Hallo

oder  so  HilfsSpalte  B   da ist  die  ZeilenNr  vom  MA  drin
und  Zählenwenn mit  Indirekt

B3 = VERGLEICH($A3;Tabelle1!$A$5:$A$20;0)+4

I3= ZÄHLENWENN(INDIREKT("Tabelle1!N"&B3&":AQ"&B3);"U")